Go Down

Topic: NTP time off by 2 seconds? (Read 185 times) previous topic - next topic

karhyv

I made an Fishino clock (Fishino is an Arduino clone with WIFI and RTC built in; see fishino.it). It works basically fine but the time is off by 2...3 seconds (see the image: the larger Raspbery Pi (RPI) clock in the background is accurate to the second).

The Fishino code is pretty standard "example code", it contains very little my own coding: see attached "Fish2_code.txt".

I wonder where the lag comes from. The RPI syncs from NTP and it manages to stay accurate (based on radio controlled clocks and time signal on FM radio). There is a one second delay in the UDP code, though. Maybe that contributes to the lag?

   // send an NTP packet to a time server
   Serial << F("Sending UDP request...");
   sendNTPpacket(timeServer);
   Serial << "OK\n";
   
   
   // wait to see if a reply is available
   delay(1000);

I saw a post where someone had dealt with this same problem simply by adding two seconds to the time. That seems rather arbitrary and crude.

SurferTim

#1
Jan 12, 2018, 09:03 pm Last Edit: Jan 12, 2018, 09:04 pm by SurferTim
I use this. It doesn't use the one second delay. I left a bunch of serial debug stuff in it. Maybe you can see if this is better.
Code: [Select]
/*

 Udp NTP Client
 
 Get the time from a Network Time Protocol (NTP) time server
 Demonstrates use of UDP sendPacket and ReceivePacket
 For more on NTP time servers and the messages needed to communicate with them,
 see http://en.wikipedia.org/wiki/Network_Time_Protocol
 
 created 4 Sep 2010
 by Michael Margolis
 modified 17 Sep 2010
 by Tom Igoe
 
 This code is in the public domain.

 */
#include <SPI.h>         
#include <Ethernet.h>
#include <EthernetUdp.h>

// Enter a MAC address for your controller below.
// Newer Ethernet shields have a MAC address printed on a sticker on the shield
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };

IPAddress ip(192,168,1,4);
IPAddress gateway(192,168,1,1);
IPAddress subnet(255,255,255,0);

unsigned int localPort = 8888;      // local port to listen for UDP packets

IPAddress timeServer(108,61,73,243);

const int NTP_PACKET_SIZE= 48; // NTP time stamp is in the first 48 bytes of the message

byte packetBuffer[ NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

// A UDP instance to let us send and receive packets over UDP
EthernetUDP Udp;

char weekday[7][4] = {"THU","FRI","SAT","SUN","MON","TUE","WED"};
unsigned long currentTime,NTPTime,minuteTime;
unsigned long NTPDelay = 600000UL,minuteDelay = 60000UL;
void setup()
{
  Serial.begin(115200);

  digitalWrite(4,HIGH);
 
  // start Ethernet and UDP
  Ethernet.begin(mac,ip,gateway,gateway,subnet);
 
//  if(!Ethernet.begin(mac)) Serial.println("failed");
  Serial.println(Ethernet.localIP());

  delay(2000);
 
  Udp.begin(localPort);

  currentTime=millis();
  NTPTime = currentTime - NTPDelay;
  delay(1000);
 
  Serial.println("Ready");

}


void loop()
{
  currentTime = millis();
 
  if(currentTime - NTPTime > NTPDelay) {
    Serial.println(F("\r\nSending request"));
    sendNTPpacket(timeServer); // send an NTP packet to a time server
    NTPTime = currentTime;
  }

  getNTPpacket();

  if(currentTime - minuteTime > minuteDelay) {
    Serial.print(F("*"));
    minuteTime = currentTime;
  }
 
}

// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(IPAddress& address)
{
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:    
  Udp.beginPacket(address, 123); //NTP requests are to port 123
  Udp.write(packetBuffer,NTP_PACKET_SIZE);
  Udp.endPacket();
}

void getNTPpacket() {
  if ( Udp.parsePacket() ) { 
    if(Udp.remoteIP() == timeServer) {
      Serial.println(F("IP OK"));
    }
    else {
      Serial.println(F("IP Bad"));
      return;
    }
    // We've received a packet, read the data from it
    Udp.read(packetBuffer,NTP_PACKET_SIZE);  // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]); 
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
/*
    Serial.print(packetBuffer[40],DEC);
    Serial.print(" ");
    Serial.print(packetBuffer[41],DEC);
    Serial.print(" ");
    Serial.print(packetBuffer[42],DEC);
    Serial.print(" ");
    Serial.println(packetBuffer[43],DEC);
   
    Serial.print("HIGH ");
    Serial.print(highWord,DEC);
    Serial.print("  LOW ");
    Serial.println(lowWord,DEC);
*/   
    unsigned long secsSince1900 = highWord << 16 | lowWord; 
//    Serial.print("Seconds since Jan 1 1900 = " );
//    Serial.println(secsSince1900);               

    // now convert NTP time into everyday time:
//    Serial.print("Unix time = ");
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;     
    // subtract seventy years:
    unsigned long epoch = secsSince1900 - seventyYears; 
    // print Unix time:
//    Serial.println(epoch);                               

    unsigned long dayCount = epoch / 86400UL;
//    Serial.print("DayCount = ");
//    Serial.println(dayCount);

    Serial.print("Day of week = ");
    Serial.println(weekday[dayCount%7UL]);   

    // print the hour, minute and second:
    Serial.print("The UTC time is ");       // UTC is the time at Greenwich Meridian (GMT)
    Serial.print((epoch  % 86400L) / 3600); // print the hour (86400 equals secs per day)
    Serial.print(':'); 
    if ( ((epoch % 3600) / 60) < 10 ) {
      // In the first 10 minutes of each hour, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.print((epoch  % 3600) / 60); // print the minute (3600 equals secs per minute)
    Serial.print(':');
    if ( (epoch % 60) < 10 ) {
      // In the first 10 seconds of each minute, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.println(epoch %60); // print the second
  } 
}

karhyv

Thanks for the tip, SurferTim. I tried to eliminate the delay function but, interestingly, the same 2 second lag remains. I suppose it is an intrinsic property of the UDP library. I resorted to adding 2 seconds to the Unix time: unixtime()+2. Simple and it works!  :)

SurferTim

Are you using the same NTP server as the RPi? I occasionally use my RPi as a NTP server. As I recall, the newer RPi OS requires you to install NTP. Earlier versions included it.

Go Up