How to slow down 360 servo

Using Arduino Motors, Mechanics, Power and CNC
1

Hi Guys,
i've got 360 servo AR-3606HB.
How can i slow it down? i tried with analogWrite,servo.write, servo.writeMicroseconds and servo.slowmove, all of this commands not working.
If I attach servo, it starting to spin really slowly...
Can i even controll speed of this servo?
Thank You in advance for all answers,

2

Use this test sketch to see if you can find a microsecond value that will make the servo stand still, then in setup():

servo.writeMicroseconds(standStillValue);
servo.attach(servoPin);

Test sketch

/*
 Try this test sketch with the Servo library to see how your
 servo responds to different settings, type a position from
 544 to 2400 in the top of serial monitor and hit [ENTER],
 start at 1472 and work your way toward zero (544) 50 micros at
 a time, then toward 2400. 
*/
#include <Servo.h>
Servo servo;

void setup() {
  // initialize serial:
  Serial.begin(9600); //set serial monitor baud rate to match
  servo.writeMicroseconds(1472);
  servo.attach(9);
  prntIt();
}

void loop() {
  // if there's any serial available, read it:
  while (Serial.available() > 0) {

    // look for the next valid integer in the incoming serial stream:
    int pos = Serial.parseInt();
    pos = constrain(pos, 400, 2400);
    servo.writeMicroseconds(pos);
    prntIt();
  }
}
void prntIt()
{
  Serial.print("  degrees = "); 
  Serial.print(servo.read());
  Serial.print("\t");
  Serial.print("microseconds =  ");
  Serial.println(servo.readMicroseconds());
}
3

Woaw.... Thank You! in writeMicro(1475) it's standing still and in 1470 it'ssloooooowly spinning
Thanks!