Well yes you are asking a lot.
I have written this to read from the pot and print out the value when it is recalled.
You need two buttons, one to tell the system to store the pot value and the other to tell it to recall it.
Disclaimer:- This code compiles but I have not tested it.
// Sketch to read a pot on A0 and store the value in EEPROM
// when button1 is pressed. When buttonRecall is pressed the value is recoverd from the EEPROM and
// printed out on the serial port
// Buttons wired between input pin and ground
#include <EEPROM.h>
#define button1 2 // button to store the pot value
#define buttonRecall 3 // button to recall the pot value
#define pot1Input 0 // analog input for pot 1
int pot1Value, lastButton1, recallValue1, lastButtonRecall;
void setup(){
pinMode(button1, INPUT);
digitalWrite(button1, HIGH); // turn on the internal pull up resistor
pinMode(buttonRecall, INPUT);
digitalWrite(buttonRecall, HIGH); // turn on the internal pull up resistor
Serial.begin(9600);
// initilise button variables
lastButtonRecall = digitalRead(buttonRecall);
lastButton1 = digitalRead(button1);
}
void loop(){
// get the value of the buttons
int button1Value = digitalRead(button1);
int buttonRecallVlaue = digitalRead(buttonRecall);
if(button1Value == LOW && lastButton1 == HIGH) { // button pressed for the first time
pot1Value = analogRead(pot1Input); // get the value on the pot
// use the first two bytes in the EEPROM to store the 10 bit value from the pot
EEPROM.write(0, pot1Value >> 8); // store the most significant byte
EEPROM.write(1, pot1Value & 0xff); // store the least significant byte
delay(20); // debounce dealy
}
if(buttonRecallVlaue == LOW && lastButtonRecall == HIGH) { // button pressed for the first time
recallValue1 = EEPROM.read(0) << 8; // get the most significant byte
recallValue1 |= EEPROM.read(1); // merge it with the least significant byte
delay(20); // debounce dealy
// now do something with the recalled value
// in this case just print it
Serial.print("Recalled value is ");
Serial.println(recallValue1);
}
// save for next time round the loop
lastButtonRecall = buttonRecallVlaue;
lastButton1 = button1Value;
}
However, the difficult part in your project is presenting a pot value to the output. This vitally depends on what the output is being connected to and what voltages there are on that device.
This link shows you the basics:-