Arduino WiFi Shield UDP Support

Thanks again for your help.
Your suggestion was already implemented in my code (I'm not THAT noob )

here goes my code

#include <WiFi.h>
#include <WiFiUdp.h>
#include <SPI.h>


char ssid[] = "customNet";   // SSID of your network
char pass[] = "customPassword";  // password of your  Network 
int status = WL_IDLE_STATUS;     // the Wifi radio's status

IPAddress receiverIP(192, 168, 1, 212); // IP of udp packets receiver
unsigned int receiverPort = 9100;      // port to listen on receiver machine 

WiFiUDP Udp;

int firstSensorPin = A0; //define sensor pin
int secondSensorPin = A1;
int thirdSensorPin = A2;
int forthSensorPin = A3;

int firstSensorValue;
int secondSensorValue;
int thirdSensorValue;
int forthSensorValue;

void setup() {
 
  Serial.begin (9600);
  
 // attempt to connect to Wifi network:
  while ( status != WL_CONNECTED) { 
    Serial.print("Attempting to connect to WPA SSID: ");
    Serial.println(ssid);
    status = WiFi.begin(ssid, pass);      // Connect to WPA/WPA2 network:    
    delay(5000);      // wait 5 seconds for connection:
  }
  delay (2000);

  Serial.print("You're connected to the network");
  printCurrentNet();  
  Udp.begin(receiverPort);
}



void loop() {
  
  firstSensorValue = analogRead(firstSensorPin);
  secondSensorValue = analogRead (secondSensorPin);
  thirdSensorValue = analogRead (thirdSensorPin);
  forthSensorValue = analogRead (forthSensorPin);
  
  byte valueInBytes[8] = {lowByte(firstSensorValue), highByte(firstSensorValue), 
                          lowByte(secondSensorValue), highByte(secondSensorValue), 
                          lowByte(thirdSensorValue), highByte(thirdSensorValue), 
                          lowByte(forthSensorValue), highByte(forthSensorValue)
                         }; //convert it to byte array
  
  Udp.beginPacket(receiverIP, receiverPort); //start udp packet
  Udp.write(valueInBytes, 8); //write sensor data to udp packet
  Udp.endPacket(); // end packet

  delay(10000);
  
}




void printCurrentNet() {
  // print the SSID:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print the MAC address of the router you're attached to:
  byte bssid[6];
  WiFi.BSSID(bssid);    
  Serial.print("BSSID: ");
  Serial.print(bssid[5],HEX);
  Serial.print(":");
  Serial.print(bssid[4],HEX);
  Serial.print(":");
  Serial.print(bssid[3],HEX);
  Serial.print(":");
  Serial.print(bssid[2],HEX);
  Serial.print(":");
  Serial.print(bssid[1],HEX);
  Serial.print(":");
  Serial.println(bssid[0],HEX);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.println(rssi);

  // print the encryption type:
  byte encryption = WiFi.encryptionType();
  Serial.print("Encryption Type:");
  Serial.println(encryption,HEX);
  Serial.println();
  
  // print your WiFi shield's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);
}