* MP3 Shield * - Rogue Robotics rMP3

@jennyc: The problem is that you need to use a more recent version of NewSoftSerial. There are two ways to get a newer version:

Try one of those, and see how it goes.

(it looks like you were using the "SerialBase" version of NewSoftSerial - I know it's confusing - It'll be straightened out soon enough).

b

With 0022, serial base class is included as standard so you do not need the (stream) versions.

I think I was using the NewSoftSerial library. I downloaded it, and pasted it into the /library/ folder at my arduino location. Is that all I had to do?

I have also since tried it without the stream versions, and still the same error.

I have been told that I may have to check the instantiation? I'm not sure what this is, as I only saw it online in relation to the ump3 device.

When attaching my uno to the rmp3, am I correct in just lining up all the pins and attaching? The activity light flashes for a brief moment on the rmp3, then just goes off, and Windows makes the "hardware plugged in" sound, then the removed sound, while the uno is just loop playing the blink programme that I loaded onto it.

@jennyc: Make sure you delete any other versions of NewSoftSerial from your /libraries/ folder (I assume that is what you meant - if not, you need to use that folder instead). Then use this version of NewSoftSerial:

http://code.google.com/p/rogue-code/downloads/detail?name=NewSoftSerial10c-withMegaAndStream.zip

The start-up sounds right. Activity LED should flash briefly, then turn off. Just make sure that the controller board (Uno) is not connected to the computer when you attach the rMP3. After attaching, plug the rig into your computer.

b

Hooray,

I finally have got it compiled using version 11 of the new software serial. I exported it to my arduino, but cant hear anything. Not sure why, I have the name of the song correct, and its location on the SD card. I think It may be a connection issue between the uno board and the rmp3

heh... I just posted some info above. Glad you got it working!

Can you post the code you're using, or is it one of the examples?

b

I am just using this:

#include <SoftwareSerial.h>

#include <RogueMP3.h>
 
SoftwareSerial rmp3_serial(6, 7);
RogueMP3 rmp3(rmp3_serial);
 
void setup()
{
  Serial.begin(9600);
  rmp3_serial.begin(9600);
 
  rmp3.sync();
 
  rmp3.playfile("/gold.mp3");
}
 
void loop()
{
}

Which seems to be on the rmp3 now, just nothing coming out of the headphones. I still have it plugged into my laptop for power just now.

The serial leds on the uno don't seem to be flashing either. I assume that with that code, the mp3 should just play on loop?

I have the mp3 called gold.mp3 on the root and in a subfoler called /mp3/gold.mp3 on the card. I renamed the file to gold.mp3, so i guess it is called gold.mp3.mp3, and tried it without the extra extension, and still no joy?

Try this code, and start the Serial Monitor after you upload:

#include <SoftwareSerial.h>

#include <RogueMP3.h>

SoftwareSerial rmp3_serial(6, 7);
RogueMP3 rmp3(rmp3_serial);

void setup()
{
  Serial.begin(9600);
  rmp3_serial.begin(9600);

  Serial.println("Starting rMP3");

  rmp3.sync();

  Serial.println("rMP3 Ready");

  rmp3.playfile("/gold.mp3");

  Serial.println("File playing");
}

void loop()
{
}

Let me know what you see in the Serial Monitor.

b

It just hangs at starting mp3. I am correct in having all the pins from the uno jumped to the rmp3? Doing this wont interfere with the two boards talking?

Thank you

Does your rMP3 setup look like this:

or do you have an rMP3 without pins?

b

Very similar. I couldn't get mine with the pins, so I have used my own. But I think I have got the same set up with them

With the usb from the uno going to my laptop.

Try this sketch, and tell me what you see in the Serial Monitor:

// Autobaud detect for rMP3/uMP3/uMMC
// Copyright 2011 Brett Hagman
// Rogue Robotics
// http://www.roguerobotics.com/

#include <SoftwareSerial.h>

SoftwareSerial rmp3_serial(6, 7);


int16_t read_timeout(uint32_t timeout)
{
  uint32_t start = millis();

  while ((millis() - start) < timeout)
  {
    if (rmp3_serial.available())
      return (uint8_t) rmp3_serial.read();
  }

  return -1;
}


boolean testbps(uint32_t bps)
{
  rmp3_serial.begin(bps);
  rmp3_serial.write(0x1b);  // send ESC
  if (read_timeout(100) == '>')
    return true;
  else
    return false;
}


void setup(void)
{
  uint32_t bps[] = { 2400, 4800, 9600, 19200, 38400, 57600, 115200 };
  uint8_t i;

  Serial.begin(9600);

  Serial.println("Started");

  for (i = 0; i < sizeof(bps)/sizeof(uint32_t); i++)
  {
    Serial.print("Trying: ");
    Serial.print(bps[i], DEC);
    if (testbps(bps[i]))
    {
      Serial.println(" YES!");
      break;
    }
    else
    {
      Serial.println(" No");
    }
  }

  // now set new bps
  
  // rmp3_serial.print("ST D 4\r");
}

void loop(void)
{
}

b

Returns "no" for all of them 2400-115200

Double check pins 6 and 7 at the rMP3 - make sure they are soldered well. Resolder them, if need be, and try again.

b

Is it just those to pins that need to be soldered down? Or am I ok to have all of them soldered to the same pin on the uno board?

I don't have access to my soldering iron at the moment, will be back with it tomorrow. I will double check 6&7 ?and the rest? of the pins, and will let you know how it works from there.

Thank you for your help

Jenny

No problem!

Yeah, just need to make sure 5V, Ground (GND), and pins 6 and 7 are well soldered. Those are the only pins that are used. If you have the pins soldered, it's just as good - just more work. :slight_smile:

b

Turns out that was the problem.

Its working now. =D Thank you very much.

Away off to read about using the getspectrumanalyser() to get the rmp3 giving the arduino a value, so that an output can be created depending on the value. That sound about right?

Thanks again

Hi

edit::

Sorry, I have just looked back and seen that I pasted the wrong code, I just pasted yours, oops.

I was using your code as a base for mine.

I think I have got to a point where it should be analysing the code, but I am not sure as to what each part of your original code actually does. I have tried to edit it with the code to play from the folder /mp3/ and the audio is not playing, but have had a version where it did only play my song gold.mp3.

From what I can tell from your code, mine should now be analysing for 3 different bands, and sending it back to the arduino. My problem is now, I am not sure how to change this from the lcd output, to just have a different arduino output turned "on" when each frequency returned.

#include <SoftwareSerial.h>
#include <RogueMP3.h>
#include <RogueSD.h>

SoftwareSerial rmp3_s(6, 7);
 
RogueMP3 rmp3(rmp3_s);
RogueSD filecommands(rmp3_s);
 
uint16_t bandfreqs[] = {  120,  2000,  20000 };
 
uint16_t numfiles = 0;
 
#define MP3PATH "/mp3/"
// you need to put the two double quotes ("") in the middle below,
// because the Arduino IDE looks for unclosed comments.
#define MP3FILTER "/mp3/""*.mp3"


void doFREQSpec(void)
{
  // prepare for up to 3 bands
  uint8_t v[3];
 
  rmp3.getspectrumanalyzer(v);
 
}

void setup(void)
{
  Serial.begin(9600);
  Serial.println("Started");
  Serial.println("Starting sync");
  rmp3.sync();
  filecommands.sync();
  Serial.println("Done sync");
  
}


void playTrack(void)
{
  char mp3path[128];
 
// ...
 
  rmp3.playfile(mp3path);
 
  rmp3.setspectrumanalyzer(bandfreqs, 10);
 
  Serial.println("Playing");
}

void loop(void)
{
  
}

Currently my code is stuck on the syncing. I will keep trying to get this working with the folder, but as a failsafe, I have it working with a single track.

Is there a specific part of the documentation that I can read, or a direction you can point me in on how to translate this back to an arduino output?

Thanks

Jenny

@jennyc: Here is an example I wrote. In my case, I am using a LEDHead with LEDs to display output.

#include <RogueMP3.h>
#include <NewSoftSerial.h>

NewSoftSerial rmp3_s(6, 7);

RogueMP3 rmp3(rmp3_s);

#define numberOfBands 3
uint16_t bandfreqs[] = { 120, 2000, 20000 };
//uint8_t outputPin[] = { 2, 3, 4 };
uint8_t outputPin[] = { 29, 30, 31 };

#define THRESHOLD 12

#define songname "/001.mp3"


void checkFrequencies(void)
{
  // prepare for up to 23 bands
  uint8_t v[23];

  rmp3.getspectrumanalyzer(v);

  for (uint8_t i=0; i<numberOfBands; i++)
  {
    if (v[i] > THRESHOLD)
      digitalWrite(outputPin[i], HIGH);
    else
      digitalWrite(outputPin[i], LOW);
  }
}


void setup(void)
{
  Serial.begin(9600);
  Serial.println("Started");

  rmp3_s.begin(9600);

  for (uint8_t i = 0; i < numberOfBands; i++)
    pinMode(outputPin[i], OUTPUT);

  Serial.println("Starting sync");
  rmp3.sync();
  Serial.println("Done sync");
}


void playTrack(void)
{
  Serial.println("Playing Track");
 
  rmp3.playfile(songname);

  rmp3.setspectrumanalyzer(bandfreqs, numberOfBands);
}

int8_t isPlaying(void)
{
  return (rmp3.getplaybackstatus() == 'P' ? 1 : 0);
}


void loop(void)
{
  if (!isPlaying())
    playTrack();

  checkFrequencies();
}

You'll definitely have to have different thresholds for each band, since they will have different responses.

b