Problemas con librerias SD.h y SIM900.h

Hola a todos!

Tengo un problema, estoy trabajando en un proyecto de la U y necesito enviar datos a través de un shield GSM/GPRS y también almacenarlos en una micro SD. El problema es que cuando activo las librerías de SD.h y SIM900.h al mismo tiempo el programa no trabaja bien. Actualmente tengo la IDE de Arduino 1.0.

Aquí les dejo un ejemplo:

test (2.45 KB)

¿Podrías ser un poco más específico? ¿Qué es lo que no hace bien? ¿Cómo debería hacerlo? Cuanta más información des, mejor ayuda recibirás...y más rápido

La librería SD.h viene con el IDE de Arduino, pero la otra no, ¿podrías poner un link para saber si es la misma que tenemos/utilizamos otros foreros?

Para poner el código que utilizas puedes utilizar la etiqueta [ code ] (icono # en la barra superior), no es necesario adjuntarlo como archivo

PD: ¿Era necesario poner una encuesta?

Sorry por lo de la encuesta.... soy muy nuevo en esto...

Voy a adjuntar las librerías que he usado.

El programa debería inicializar, la SD, el sensor de presión, y la conexion Serial y Wire.... el asunto es que no lo hace...
Alguien me ha dicho que es un problema con la SRAM pero no se....

#include <SD.h>
#include <Wire.h>
#include "SIM900.h"
//#include <SoftwareSerial.h>
#include "sms.h"
#include<stdlib.h>
SMSGSM sms;

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting
const int chipSelect = 8;

boolean started=false;
// Calibration values
int ac1;
int ac2;
int ac3;
int b1;
int b2;
int mb;
int mc;
int md;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;

float temperature;
float pressure;
float atm;
float altitude;
float RH;

char data[100];//="\t\n";

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5; 

void setup(){
  
  Serial.begin(9600);
  bmp085Calibration();
  Wire.begin();
  iniciarSD();
  started=startCell();
  //delay(2000);
  //delay(2000);
  Serial.println(F("Starting in.."));
  /*Serial.println("1...");
  delay(1000);
  Serial.println("2...");  
  delay(1000);
  Serial.println("3...");  
  delay(1000);
  Serial.println("Go!");*/
  temperature=0;
  pressure=0;
  atm=0;
  altitude=0;
  RH=0;
}

void loop()
{
  
  temperature = bmp085GetTemperature(bmp085ReadUT()); //MUST be called first
  pressure = bmp085GetPressure(bmp085ReadUP());
  atm = pressure / 101325; // "standard atmosphere"
  altitude = calcAltitude(pressure); //Uncompensated caculation - in Meters 
  RH = calcRH();
  recordData(temperature,pressure,atm,altitude,RH);
  convertFloat(temperature,pressure,altitude,atm,RH);
  //Serial.println("******************");
  Serial.println(data);
  //Serial.println("******************");
  sendSMS();
  memset(data,0,sizeof(data)); //limpiamos el buffer
  delay(2000); //wait a second and get values again.
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program

void convertFloat(float temperature, float pressure, float altitude, float atm, float RH)
{
  char temp[10],press[10],alti[10],at[10],R[10];
  dtostrf(temperature,0,2,temp);
  dtostrf(pressure,0,2,press);
  dtostrf(altitude,0,2,alti);
  dtostrf(atm,0,2,at);
  dtostrf(RH,0,2,R);
  //if(banData==0)
  strcat(data,"R2D2-OpenSonde:\nTemp: ");
  strcat(data,temp);
  strcat(data," C\nPresion: ");
  strcat(data,press);
  strcat(data," hPa\nAltitud: ");
  strcat(data,alti);
  strcat(data," m\nAtm: ");
  strcat(data,at);
  strcat(data,"\nRH: ");
  strcat(data,R);
  strcat(data," %");
}

boolean startCell()
{
  boolean started=false;
  
  Serial.println(F("Starting cell phone."));
  
   if (gsm.begin(2400)){
    Serial.println(F("\nstatus=READY"));
    started=true;  
    }
    else Serial.println(F("\nstatus=IDLE"));
   
   return started;
} 

void sendSMS()
{
  
  if(started){
    //Enable this two lines ifst you want to send an SMS.
    if (sms.SendSMS("85861381", data))
          Serial.println(F("\nSMS sent OK"));
    
  }
}

void iniciarSD()
{
  Serial.println(F("Initializing SD card..."));
  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  pinMode(10, OUTPUT);
  
  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println(F("Card failed, or not present"));
    // don't do anything more:
    return;
  }
  Serial.println(F("card initialized."));
}

void recordData(float temperature,float pressure,float atm,float altitude,float RH)
{
 File dataFile = SD.open("datalog5.dat", FILE_WRITE);
  if (dataFile) {
    
    //dataString=(String)temperature;
    dataFile.print(temperature);
    dataFile.print(",");
    dataFile.print(pressure);
    dataFile.print(",");
    dataFile.print(atm);
    dataFile.print(",");
    dataFile.println(altitude);
    dataFile.print(",");
    dataFile.println(RH);   
    dataFile.close();
    // print to the serial port too:
    //Serial.println(dataString);
  }
  // if the file isn't open, pop up an error:
  else {
    Serial.println(F("error opening datalog.txt"));
  }    
}

void bmp085Calibration()
{
  Serial.println(F("Calibrating pressure sensor"));
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
  Serial.println(F("Calibration is complete"));
}

// Calculate temperature in deg C
float bmp085GetTemperature(unsigned int ut){
  long x1, x2;

  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  float temp = ((b5 + 8)>>4);
  temp = temp /10;

  return temp;
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up){
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;

  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;

  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;

  long temp = p;
  return temp;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;

  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();

  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT(){
  unsigned int ut;

  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();

  // Wait at least 4.5ms
  delay(5);

  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP(){

  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;

  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();

  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));

  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  msb = bmp085Read(0xF6);
  lsb = bmp085Read(0xF7);
  xlsb = bmp085Read(0xF8);

  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

  return up;
}

float calcAltitude(float pressure){

  float A = pressure/101325;
  float B = 1/5.25588;
  float C = pow(A,B);
  C = 1 - C;
  C = C /0.0000225577;

  return C;
}

float calcRH()
{
  //float RH = 0;
  float voltValue=((4.95*analogRead(A0))/1023);
  return (voltValue-0.958)/0.0307;
  //Serial.print(voltValue);
}

GSM_GPRS.tar.gz (33.6 KB)

SD.tar.gz (43.8 KB)

test (2.45 KB)

Este es el hardware que tengo, dos sensores, sensor de presión BMP085 (Barometric Pressure Sensor - BMP085 Breakout - SEN-09694 - SparkFun Electronics), y sensor de humedad (SparkFun Humidity Sensor Breakout - HIH-4030 - SEN-09569 - SparkFun Electronics), que tienen también un escudo de GSM / GPRS (http://www.crcibernetica.com/sim900-gsm-gprs-shield-for-arduino/) y los R3 Arduino UNO. Aun me falta agregar un GPS. Otra cosa recuerden que estoy usando el IDE de Arduino 1.0

Muy buenas,

en mi caso tengo un Arduino UNO R3 con IDE 1.0.1, cuando utilizo las 3 librerías a la vez (SD, Wire y SoftwareSerial) el programa no me funciona bien, si utilizo por ejemplo (SD y Wire) me funciona sin problemas, si uso Wire y SoftwareSerial tambien funciona sin problemas, pero las 3 librerías a la vez no.

Saludos.