Pb Variomètre avec Attiny85+BMP085 en I²C

Bonjour,
Je vais essayer d'être le plus clair possible: je veux réaliser un variomètre (appareil de vol pour parapente).
J'ai trouvé un code (http://taturno.com/code/VariometroV2.pde).
Il fonctionne parfaitement sur mon arduino nano.
Mais comme je suis un peu chiant je veux le miniaturiser au maximum grâce à un Attiny85.
J'ai donc charger les librairies et documents utiles (TinyWireM,core HLT...).
Dans le code je remplace les élément de la librairie Wire par La TinyWireMaster.
Je change le pin du buzzer pour adapter aux pins du Tiny.....
Je charge le programme dans le Tiny, je le met sur ma breadboard, branchement et là :
.....RIEN.
Voilà Mon code:

#include <TinyWireM.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 3;  // Oversampling Setting

// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5; 
int Conta=0;
int sec=0;

float m1=0;
float m2=0;
int buzzPin = 1;
int intervallo=100;
int campioni=40;
int maxcampioni=50;
float alt[51];
float tim[51];
float beep;
float periodoBeep;

void setup(){
  TinyWireM.begin();
  bmp085Calibration();
  periodoBeep=500;
}

void loop()
{

  float media;
  float temperature = bmp085GetTemperature(bmp085ReadUT()); //MUST be called first
  float pressure = bmp085GetPressure(bmp085ReadUP());
  float atm = pressure / 101325; // "standard atmosphere"
  float altitude = calcAltitude(pressure); //Uncompensated caculation - in Meters 
  float tempo=millis();

  // Buffero i campioni nei vettori fifo di altezza e tempo
  for(int cc=1;cc<=maxcampioni;cc++){
    alt[(cc-1)]=alt[cc];
    tim[(cc-1)]=tim[cc];
  };
  alt[maxcampioni]=altitude;
  tim[maxcampioni]=tempo;
  
  // Effettuo l'interpolazione lineare (minimi quadrati) per determinare il 
  // tasso di varazione verticale
  float stime=tim[maxcampioni-campioni];
  float N1=0;
  float N2=0;
  float N3=0;
  float D1=0;
  float D2=0;
  for(int cc=(maxcampioni-campioni);cc<maxcampioni;cc++){
      N1+=(tim[cc]-stime)*alt[cc];
      N2+=(tim[cc]-stime);
      N3+=(alt[cc]);
      D1+=(tim[cc]-stime)*(tim[cc]-stime);
      D2+=(tim[cc]-stime);
  };
  float vario=0;
  vario=1000*((campioni*N1)-N2*N3)/(campioni*D1 - D2*D2);

  // Output audio 
  if (tempo>10000){      //Primi dieci secondi non beeppo
    if ((tempo-beep)>periodoBeep){
          beep=tempo;
         if (vario>.40 && vario<10 ){
            periodoBeep=300;
            tone(buzzPin,900+100*vario ,100);
          }
           if (vario<-2.5){
            periodoBeep=300;
            tone(buzzPin,500,200);
          }
    }
  } 

  delay(10);
    

}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature in deg C
float bmp085GetTemperature(unsigned int ut){
  long x1, x2;

  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  float temp = ((b5 + 8)>>4);
  temp = temp /10;

  return temp;
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up){
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;

  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;

  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;

  long temp = p;
  return temp;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;

  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(address);
  TinyWireM.endTransmission();

  TinyWireM.requestFrom(BMP085_ADDRESS, 1);
  while(!TinyWireM.available()) ;

  return TinyWireM.receive();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;

  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(address);
  TinyWireM.endTransmission();

  TinyWireM.requestFrom(BMP085_ADDRESS, 2);
  while(TinyWireM.available()<2);
  
  msb = TinyWireM.receive();
  lsb = TinyWireM.receive();

  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT(){
  unsigned int ut;

  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(0xF4);
  TinyWireM.send(0x2E);
  TinyWireM.endTransmission();

  // Wait at least 4.5ms
  delay(5);

  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP(){

  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;

  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(0xF4);
  TinyWireM.send(0x34 + (OSS<<6));
  TinyWireM.endTransmission();

  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));

  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  msb = bmp085Read(0xF6);
  lsb = bmp085Read(0xF7);
  xlsb = bmp085Read(0xF8);

  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

  return up;
}

void writeRegister(int deviceAddress, byte address, byte val) {
    TinyWireM.beginTransmission(deviceAddress); // start transmission to device 
    TinyWireM.send(address);       // send register address
    TinyWireM.send(val);         // send value to write
    TinyWireM.endTransmission();     // end transmission
}

int readRegister(int deviceAddress, byte address){

    int v;
    TinyWireM.beginTransmission(deviceAddress);
    TinyWireM.send(address); // register to read
    TinyWireM.endTransmission();

    TinyWireM.requestFrom(deviceAddress, 1); // read a byte

    while(!TinyWireM.available()) {
        // waiting
    }

    v = TinyWireM.receive();
    return v;
}

float calcAltitude(float pressure){

  float A = pressure/101325;
  float B = 1/5.25588;
  float C = pow(A,B);
  C = 1 - C;
  C = C /0.0000225577;

  return C;
}

Edit:Merci Christan_R pour l'astuce de la mise en page !!!

Si quelqun à une piste pour moi merci d'avance

La balise (#) permet d'insérer du code ``

Tu as balancé direct sur ton ATtiny ton code Arduino ?

C'est quand même osé considérant que tu n'as pas de sortie Serial, aucun moyen de debug.
Commence par simplifier
Repart d'un code de base qui essaye l'I2C avec un accès simple.
Utilise au minimum des LED pour debugguer ou une liaison série soft.

Quel environnement Tiny utilises tu ?

Salut,
Non bien sur j'ai pas envoyé cash le code sur l'ATTINY
j'ai changé la library Wire par la library TinyWireM pour la gestion de l'I²C.
Pour vérifier que la communication passe bien j'ai utilisé un LCD avec la library ShiftLCD ( mode 3 fils).
J'arrive à obtenir les données du capteur :Pression, Température.
Mais quand je veux faire marcher la partie sonore (je ne peux pas utiliser le lcd (manque de pin)donc pas possible de débug)
je branche mon buzzer et là ...Rien
J'ai testé la sortie du son sur le pin 1 (PWM et I/O) et pin 3 (I/O)...Rien

Pour résumer, qu'elles sont les combinaidons qui marche et celle qui ne marchent pas ?

  • tinywire + bmp05 + lcd = ok
    Et ?

Bonjour,

ce qui ne marche pas c'est Tiny+Bmp085+Buzzer

J'ai lu hier soir dans mes recherches qu'il y a des restriction vis à vis de la fonction tone() sur Tiny:
-Le core "Arduino-Tiny" supporterai cette fonction contrairement au core "HLT" (celui que j'utilise)
-La fonction tone() ne marcherai que pour des valeures supérieures à 50.

Je continue à fouiller. je vais tester ça quand j'aurai le temps.

Bon,

ne comprenant pas tout du code que j'utilisais à la base je suis repartis de l'exemple arduino pour le capteur BMP085 et j'ai tapé un peu de code. Mon écriture est surement un peu "lourde" mais elle à le mérite de fonctionner.
L'écriture et certaines variables restent à affiner. Pour ceux que ça interresse:

//Afficher Pression et température capteur BMP085
//Gestion par Attiny85
//LCD 16x2
//SDA pin 5 SCK pin 6


#include <TinyWireM.h>
#define BMP085_ADDRESS 0x77
const unsigned char OSS = 3;
int ac1;
int ac2; 
int ac3; 
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1; 
int b2;
int mb;
int mc;
int md;
long b5; 

short temperature;
long pressure;
   

long previousMillis = 0;        
long tempo = 1000;
long previousPressure = 0;
int vario = 0;

void setup()
{
  TinyWireM.begin();
  bmp085Calibration();   
}

void loop() {

  temperature = bmp085GetTemperature(bmp085ReadUT());
  pressure = bmp085GetPressure(bmp085ReadUP()); 
   
   unsigned long currentMillis = millis();
   long currentPressure = pressure;
   
   if(currentMillis - previousMillis > tempo) {
     int vario = previousPressure - currentPressure;


     if (vario <= -30 ){
       tone (1,500,700);        //si vario < 2,5 m/s
     }
     if (vario >=8 && vario<12) {
        tone (1,1000,500);       // si   0,5m/s < vario <1m.s
     }
     if (vario >=12 && vario<18) {
        tone (1,1100,100);
        delay (200);
        tone (1,1100,100);       // si   1m/s < vario <1,5m/s
     }
     if (vario >=18 && vario<24) {
        tone (1,1200,90);
        delay (200);
        tone (1,1200,90);
        delay (200);
        tone (1,1200,90);       // si   1,5m/s < vario <2m/s
     }

     if (vario >=18 && vario<24) {
        tone (1,1300,80);
        delay (150);
        tone (1,1300,80);
        delay (150);
        tone (1,1300,80);
        delay (150);
        tone (1,1300,80);       // si   2m/s < vario <3m/s
     }
     if (vario >=24 ) {

        tone (1,1400,70);
        delay (150);
        tone (1,1400,70);
        delay (150);
        tone (1,1400,70);
        delay (150);
        tone (1,1400,70);
        delay (150);
        tone (1,1400,70);       // si   vario > 3
     }
     
   previousMillis = currentMillis;
   previousPressure = currentPressure;
  }   
}

  void bmp085Calibration() {
    
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

short bmp085GetTemperature(unsigned int ut)
{
  long x1, x2;
  
  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  return ((b5 + 8)>>4);  
}

long bmp085GetPressure(unsigned long up)
{
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;
  
  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
  
  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
  
  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;
    
  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;
  
  return p;
}

char bmp085Read(unsigned char address)
{
  unsigned char data;
  
  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(address);
  TinyWireM.endTransmission();
  
  TinyWireM.requestFrom(BMP085_ADDRESS, 1);
  while(!TinyWireM.available())
    ;
    
  return TinyWireM.receive();
}

int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;
  
  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(address);
  TinyWireM.endTransmission();
  
  TinyWireM.requestFrom(BMP085_ADDRESS, 2);
  while(TinyWireM.available()<2)
    ;
  msb = TinyWireM.receive();
  lsb = TinyWireM.receive();
  
  return (int) msb<<8 | lsb;
}

unsigned int bmp085ReadUT()
{
  unsigned int ut;
  
  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(0xF4);
  TinyWireM.send(0x2E);
  TinyWireM.endTransmission();
  
  // Wait at least 4.5ms
  delay(20);
  
  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;
  
  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(0xF4);
  TinyWireM.send(0x34 + (OSS<<6));
  TinyWireM.endTransmission();
  
  // Wait for conversion, delay time dependent on OSS
  delay(20 + (3<<OSS));
  
  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  TinyWireM.beginTransmission(BMP085_ADDRESS);
  TinyWireM.send(0xF6);
  TinyWireM.endTransmission();
  TinyWireM.requestFrom(BMP085_ADDRESS, 3);
  
  // Wait for data to become available
  while(TinyWireM.available() < 3)
    ;
  msb = TinyWireM.receive();
  lsb = TinyWireM.receive();
  xlsb = TinyWireM.receive();
  
  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
  
  return up;
  
  
}

Il me reste à le tester en vol (la météo ne s'y prêtant pas en ce moment).

Bon vol !!!!