String compound operator question

I'm learning to use SD for data logging, so I'm looking at the Datalogger sketch from the built-in examples. I'm using a (clone) Ethernet shield with microSD socket on a Mega (clone). The sketch is modified to work with the Mega by changing pin 10 to 53, and I'm using Arduino 1.0. The sketch is also at http://arduino.cc/en/Tutorial/Datalogger

The problem is that the sketch seems to get stuck when running, the output looks something like this:

Initializing SD card...card initialized.
371,312,286
309,298,
[hangs]

Changing one line in the sketch, from:

    dataString += String(sensor);

to

    dataString = dataString + String(sensor);

works. What's the difference? Do compound operators not work with String objects?

Thanks. :blush:

Do compound operators not work with String objects?

They do. The String class is a resource hog, though. I'd guess that you are right at the limit of not having enough memory.

Personally, I'd ditch the String class. There is nothing that it can do that the native char array and string functions can not do, while consuming far less memory and code space.

PaulS:

Do compound operators not work with String objects?

They do. The String class is a resource hog, though. I'd guess that you are right at the limit of not having enough memory.

Thanks for replying. Well, I realize the String class is a resource hog, but I'm curious why it doesn't work in this case. Surely the Mega has enough memory for a simple string in an example sketch? Besides, changing the compound operator to the regular concat operator works.

Surely the Mega has enough memory for a simple string in an example sketch?

I could write an example for which that would not be true. I won't show you that example, either.

Sorry, this is the sketch in question.

/*
  SD card datalogger
 
 This example shows how to log data from three analog sensors 
 to an SD card using the SD library.
    
 The circuit:
 * analog sensors on analog ins 0, 1, and 2
 * SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4
 
 created  24 Nov 2010
 updated 2 Dec 2010
 by Tom Igoe
 
 This example code is in the public domain.
     
 */

#include <SD.h>

// On the Ethernet Shield, CS is pin 4. Note that even if it's not
// used as the CS pin, the hardware CS pin (10 on most Arduino boards,
// 53 on the Mega) must be left as an output or the SD library
// functions will not work.
const int chipSelect = 4;

void setup()
{
  Serial.begin(9600);
  Serial.print("Initializing SD card...");
  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  pinMode(53, OUTPUT);
  
  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    return;
  }
  Serial.println("card initialized.");
}

void loop()
{
  // make a string for assembling the data to log:
  String dataString = "";

  // read three sensors and append to the string:
  for (int analogPin = 0; analogPin < 3; analogPin++) {
    int sensor = analogRead(analogPin);
    dataString += String(sensor);
    if (analogPin < 2) {
      dataString += ","; 
    }
  }

  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.txt", FILE_WRITE);

  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  }  
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  } 
}
    dataString += String(sensor);

There is no need to create a temporary String to wrap the int before concatenating it. Doing so consumes more resources that necessary.

PaulS:

    dataString += String(sensor);

There is no need to create a temporary String to wrap the int before concatenating it. Doing so consumes more resources that necessary.

Okay, I guess the examples aren't perfect. Will try to reduce resource usage in my own programs.

Thanks again for your help.