I was only thinking of using the GPS temporarily to measure the accuracy of your board. Here is my standard sketch that measures pulse length (the whole thing) on pin8 and outputs the number of microseconds since the last capture. The first reading output is noise, but all other output will be very precisely measured by the hardware. No software can introduce any jitter in the measurement since the ICF is completely done in hardware.
#include "Arduino.h"
volatile unsigned t1captured = 0;
volatile unsigned t1capval = 0;
volatile unsigned t1ovfcnt = 0;
volatile unsigned long t1time;
volatile unsigned long t1last = 0;
#define BUFFER_SIZE 32
volatile unsigned long int buffer[BUFFER_SIZE];
volatile int head = 0;
volatile int tail = 0;
void setup() {
Serial.begin(9600);
TCCR1A = 0x0; // put timer1 in normal mode
TCCR1B = 0x2; // change prescaler to divide clock by 8
// clear any pending capture or overflow interrupts
TIFR1 = (1<<ICF1) | (1<<TOV1);
// Enable input capture and overflow interrupts
TIMSK1 |= (1<<ICIE1) | (1<<TOIE1);
pinMode(8, INPUT); // This is where to feed the signal in
}
void loop() {
if(head != tail) {
head = (head + 1) % BUFFER_SIZE;
Serial.println(buffer[head]);
}
}
ISR(TIMER1_OVF_vect) {
t1ovfcnt++; // keep track of overflows
}
ISR(TIMER1_CAPT_vect) {
unsigned long t1temp;
// combine overflow count with capture value to create 32 bit count
// calculate how long it has been since the last capture
// stick the result in the global variable t1time in 1uS precision
t1capval = ICR1;
t1temp = ((unsigned long)t1ovfcnt << 16) | t1capval;
t1time = (t1temp - t1last) >> 1; // convert to full uS
t1last = t1temp;
tail = (tail + 1) % BUFFER_SIZE;
buffer[tail] = t1time;
}