I assembled one of the adafruit SD shields to use on my Arduino Mega board.
http://www.ladyada.net/make/logshield/sd.html
Example below (not mine):
I think my soldering job is pretty decent and I can't find a problem with the traces. Unfortunately I don't have an oscilliscope yet, which I really should get.
I'm having some difficulty understanding the SPI connection to the unit.
At first, I assumed that the shield would work cause I thought these shields were compatible.
I think compatible just means that it will connect up with the board, but the SPI pins won't match.
I can communicate with the board over USB, and it says it can't read the card.
It's probably not a card issue, cause I've used a couple, including a 16MB card that was specifically FAT-16 formatted.
From what I gather (which could be quite far off), is that I should use the ICSP header to connect up the SPI pins.
I can't determine which is pin1 on the ICSP header on the SD shield from any docs, to match them up. Now that I'm typing this I guess I should do a continuity test to figure it out.
Should I have not soldered on the header for pins 10,11,12,13? Cause then I would be bridging pins 10-13 with pins 50-53? If so, it would seem odd to design a board that way. Again, I'm likely misunderstanding something here.
By connecting the ICSP header on the SD shield, am I somehow bypassing pins 10-13, so that there isn't a bridge occurring?
Another thing is I've added this to the SPI.h header to match the SPI pins for the Mega:
http://www.arduino.cc/cgi-bin/yabb2/YaBB.pl?num=1276117813
#if defined(__AVR_ATmega168__) || defined(__AVR_ATmega328P__)
#define SCK_PIN 13
#define MISO_PIN 12
#define MOSI_PIN 11
#define SS_PIN 10
#endif
#if defined(__AVR_ATmega128__) || defined(__AVR_ATmega1280__)
#define SCK_PIN 52
#define MISO_PIN 50
#define MOSI_PIN 51
#define SS_PIN 53
#endif
Thanks for providing any clarity. I've been trying to read everything I can find on here and elsewhere.
edit: I realized I should of shown the code I was using:
/*
SD card test
This example shows how use the utility libraries on which the'
SD library is based in order to get info about your SD card.
Very useful for testing a card when you're not sure whether its working or not.
The circuit:
* SD card attached to SPI bus as follows:
** MOSI - pin 11 on Arduino Uno/Duemilanove/Diecimila
** MISO - pin 12 on Arduino Uno/Duemilanove/Diecimila
** CLK - pin 13 on Arduino Uno/Duemilanove/Diecimila
** CS - depends on your SD card shield or module
created 28 Mar 2011
by Limor Fried
*/
// include the SD library:
#include <SD.h>
// set up variables using the SD utility library functions:
Sd2Card card;
SdVolume volume;
SdFile root;
// change this to match your SD shield or module;
// Arduino Ethernet shield: pin 4
// Adafruit SD shields and modules: pin 10
// Sparkfun SD shield: pin 8
const int chipSelect = 10;
void setup()
{
Serial.begin(9600);
Serial.print("\nInitializing SD card...");
// On the Ethernet Shield, CS is pin 4. It's set as an output by default.
// Note that even if it's not used as the CS pin, the hardware SS pin
// (10 on most Arduino boards, 53 on the Mega) must be left as an output
// or the SD library functions will not work.
//pinMode(10, OUTPUT); // change this to 53 on a mega
pinMode(53, OUTPUT);
// we'll use the initialization code from the utility libraries
// since we're just testing if the card is working!
// if (!card.init(SPI_HALF_SPEED, chipSelect)) {
if (!card.init(SPI_QUARTER_SPEED, chipSelect)) {
Serial.println("initialization failed. Things to check:");
Serial.println("* is a card is inserted?");
Serial.println("* Is your wiring correct?");
Serial.println("* did you change the chipSelect pin to match your shield or module?");
return;
} else {
Serial.println("Wiring is correct and a card is present.");
}
// print the type of card
Serial.print("\nCard type: ");
switch(card.type()) {
case SD_CARD_TYPE_SD1:
Serial.println("SD1");
break;
case SD_CARD_TYPE_SD2:
Serial.println("SD2");
break;
case SD_CARD_TYPE_SDHC:
Serial.println("SDHC");
break;
default:
Serial.println("Unknown");
}
// Now we will try to open the 'volume'/'partition' - it should be FAT16 or FAT32
if (!volume.init(card)) {
Serial.println("Could not find FAT16/FAT32 partition.\nMake sure you've formatted the card");
return;
}
// print the type and size of the first FAT-type volume
uint32_t volumesize;
Serial.print("\nVolume type is FAT");
Serial.println(volume.fatType(), DEC);
Serial.println();
volumesize = volume.blocksPerCluster(); // clusters are collections of blocks
volumesize *= volume.clusterCount(); // we'll have a lot of clusters
volumesize *= 512; // SD card blocks are always 512 bytes
Serial.print("Volume size (bytes): ");
Serial.println(volumesize);
Serial.print("Volume size (Kbytes): ");
volumesize /= 1024;
Serial.println(volumesize);
Serial.print("Volume size (Mbytes): ");
volumesize /= 1024;
Serial.println(volumesize);
Serial.println("\nFiles found on the card (name, date and size in bytes): ");
root.openRoot(volume);
// list all files in the card with date and size
root.ls(LS_R | LS_DATE | LS_SIZE);
}
void loop(void) {
}