Show Posts
Pages: [1]
1  International / Deutsch / Wie DmxSimple Timer ändern? on: November 20, 2012, 03:56:17 pm
Hallo,
auf meinem Arduino Mega 2560 sitzen zwei shields:
-  IR-Shield: http://www.linksprite.com/product/showproduct.php?lang=en&id=64
                  mit der Ken Shirriff Blog library: http://www.arcfn.com/2009/08/multi-protocol-infrared-remote-library.html
-  DMX-Shield: http://code.google.com/p/tinkerit/wiki/DmxSimple

Nun scheint es so, als ob die beiden sich gegenseitig blockieren. Hardwaretechnisch alles gelöst, aber ich glaube beide greifen auf den TIMER 2 in den Libs zu..
Denn wenn ich irrecv.enableIRIn() auskommentiere sendet das DMX Signal wieder.

Nun zu meiner Frage:
1. Könnte ich mit meiner Vermutung richtig liegen?
Oder hat jemand einen anderen Vorschlag? (bin kein großer Programmierer und im Mikrocontrollerbereich erst recht nicht :-/)
2. Kann ich die lib vom DMX so ändern, dass sie auf einen anderen, freien TIMER vom Arduino Mega 2560 zugreift?
Code:
/**
 * DmxSimple - A simple interface to DMX.
 *
 * Copyright (c) 2008-2009 Peter Knight, Tinker.it! All rights reserved.
 */
#include <avr/io.h>
#include <avr/interrupt.h>
#include <util/delay.h>
#include "pins_arduino.h"

#include "Arduino.h"
#include "DmxSimple.h"

/** dmxBuffer contains a software copy of all the DMX channels.
  */
volatile uint8_t dmxBuffer[DMX_SIZE];
static uint16_t dmxMax = 16; /* Default to sending the first 16 channels */
static uint8_t dmxStarted = 0;
static uint16_t dmxState = 0;

static volatile uint8_t *dmxPort;
static uint8_t dmxBit = 0;
static uint8_t dmxPin = 6; // Defaults to output on pin 3 to support Tinker.it! DMX shield

void dmxBegin();
void dmxEnd();
void dmxSendByte(volatile uint8_t);
void dmxWrite(int,uint8_t);
void dmxMaxChannel(int);

/* TIMER2 has a different register mapping on the ATmega8.
 * The modern chips (168, 328P, 1280) use identical mappings.
 */
#if defined(__AVR_ATmega168__) || defined(__AVR_ATmega2560__) || defined(__AVR_ATmega168P__) || defined(__AVR_ATmega328P__) || defined(__AVR_ATmega1280__)
#define TIMER2_INTERRUPT_ENABLE() TIMSK2 |= _BV(TOIE2)
#define TIMER2_INTERRUPT_DISABLE() TIMSK2 &= ~_BV(TOIE2)
#elif defined(__AVR_ATmega8__)
#define TIMER2_INTERRUPT_ENABLE() TIMSK |= _BV(TOIE2)
#define TIMER2_INTERRUPT_DISABLE() TIMSK &= ~_BV(TOIE2)
#else
#define TIMER2_INTERRUPT_ENABLE()
#define TIMER2_INTERRUPT_DISABLE()
/* Produce an appropriate message to aid error reporting on nonstandard
 * platforms such as Teensy.
 */
#warning "DmxSimple does not support this CPU"
#endif


/** Initialise the DMX engine
 */
void dmxBegin()
{
  dmxStarted = 1;

  // Set up port pointers for interrupt routine
  dmxPort = portOutputRegister(digitalPinToPort(dmxPin));
  dmxBit = digitalPinToBitMask(dmxPin);

  // Set DMX pin to output
  pinMode(dmxPin,OUTPUT);

  // Initialise DMX frame interrupt
  //
  // Presume Arduino has already set Timer2 to 64 prescaler,
  // Phase correct PWM mode
  // So the overflow triggers every 64*510 clock cycles
  // Which is 510 DMX bit periods at 16MHz,
  //          255 DMX bit periods at 8MHz,
  //          637 DMX bit periods at 20MHz
  TIMER2_INTERRUPT_ENABLE();
}

/** Stop the DMX engine
 * Turns off the DMX interrupt routine
 */
void dmxEnd()
{
  TIMER2_INTERRUPT_DISABLE();
  dmxStarted = 0;
  dmxMax = 0;
}

/** Transmit a complete DMX byte
 * We have no serial port for DMX, so everything is timed using an exact
 * number of instruction cycles.
 *
 * Really suggest you don't touch this function.
 */
void dmxSendByte(volatile uint8_t value)
{
  uint8_t bitCount, delCount;
  __asm__ volatile (
    "cli\n"
    "ld __tmp_reg__,%a[dmxPort]\n"
    "and __tmp_reg__,%[outMask]\n"
    "st %a[dmxPort],__tmp_reg__\n"
    "ldi %[bitCount],11\n" // 11 bit intervals per transmitted byte
    "rjmp bitLoop%=\n"     // Delay 2 clock cycles.
  "bitLoop%=:\n"\
    "ldi %[delCount],%[delCountVal]\n"
  "delLoop%=:\n"
    "nop\n"
    "dec %[delCount]\n"
    "brne delLoop%=\n"
    "ld __tmp_reg__,%a[dmxPort]\n"
    "and __tmp_reg__,%[outMask]\n"
    "sec\n"
    "ror %[value]\n"
    "brcc sendzero%=\n"
    "or __tmp_reg__,%[outBit]\n"
  "sendzero%=:\n"
    "st %a[dmxPort],__tmp_reg__\n"
    "dec %[bitCount]\n"
    "brne bitLoop%=\n"
    "sei\n"
    :
      [bitCount] "=&d" (bitCount),
      [delCount] "=&d" (delCount)
    :
      [dmxPort] "e" (dmxPort),
      [outMask] "r" (~dmxBit),
      [outBit] "r" (dmxBit),
      [delCountVal] "M" (F_CPU/1000000-3),
      [value] "r" (value)
  );
}

/** DmxSimple interrupt routine
 * Transmit a chunk of DMX signal every timer overflow event.
 *
 * The full DMX transmission takes too long, but some aspects of DMX timing
 * are flexible. This routine chunks the DMX signal, only sending as much as
 * it's time budget will allow.
 *
 * This interrupt routine runs with interrupts enabled most of the time.
 * With extremely heavy interrupt loads, it could conceivably interrupt its
 * own routine, so the TIMER2 interrupt is disabled for the duration of
 * the service routine.
 */
ISR(TIMER2_OVF_vect,ISR_NOBLOCK) {

  // Prevent this interrupt running recursively
  TIMER2_INTERRUPT_DISABLE();

  uint16_t bitsLeft = F_CPU / 31372; // DMX Bit periods per timer tick
  bitsLeft >>=2; // 25% CPU usage
  while (1) {
    if (dmxState == 0) {
      // Next thing to send is reset pulse and start code
      // which takes 35 bit periods
      uint8_t i;
      if (bitsLeft < 35) break;
      bitsLeft-=35;
      *dmxPort &= ~dmxBit;
      for (i=0; i<11; i++) _delay_us(8);
      *dmxPort |= dmxBit;
      _delay_us(8);
      dmxSendByte(0);
    } else {
      // Now send a channel which takes 11 bit periods
      if (bitsLeft < 11) break;
      bitsLeft-=11;
      dmxSendByte(dmxBuffer[dmxState-1]);
    }
    // Successfully completed that stage - move state machine forward
    dmxState++;
    if (dmxState > dmxMax) {
      dmxState = 0; // Send next frame
      break;
    }
  }
  
  // Enable interrupts for the next transmission chunk
  TIMER2_INTERRUPT_ENABLE();
}

void dmxWrite(int channel, uint8_t value) {
  if (!dmxStarted) dmxBegin();
  if ((channel > 0) && (channel <= DMX_SIZE)) {
    if (value<0) value=0;
    if (value>255) value=255;
    dmxMax = max((unsigned)channel, dmxMax);
    dmxBuffer[channel-1] = value;
  }
}

void dmxMaxChannel(int channel) {
  if (channel <=0) {
    // End DMX transmission
    dmxEnd();
    dmxMax = 0;
  } else {
    dmxMax = min(channel, DMX_SIZE);
    if (!dmxStarted) dmxBegin();
  }
}


/* C++ wrapper */


/** Set output pin
 * @param pin Output digital pin to use
 */
void DmxSimpleClass::usePin(uint8_t pin) {
  dmxPin = pin;
  if (dmxStarted && (pin != dmxPin)) {
    dmxEnd();
    dmxBegin();
  }
}

/** Set DMX maximum channel
 * @param channel The highest DMX channel to use
 */
void DmxSimpleClass::maxChannel(int channel) {
  dmxMaxChannel(channel);
}

/** Write to a DMX channel
 * @param address DMX address in the range 1 - 512
 */
void DmxSimpleClass::write(int address, uint8_t value)
{
dmxWrite(address, value);
}
DmxSimpleClass DmxSimple;

Ist das sehr aufwendig? Ich kenne mich mit Interrupts, Timern und Countern bis lang gar nicht aus.

Vielen Dank für die Hilfe
Grüße
Roman
2  International / Deutsch / Re: IR- Send / Receive Problem on: November 18, 2012, 01:16:25 pm
Ich verwende diese Shields
http://www.linksprite.com/product/showproduct.php?lang=en&id=64
und möchte eigentlich ungern etwas abzwicken :-/

Aber wenn ich den Programmteil
Code:
/* SEND START */
                               for (int i = 0; i < 3; i++) { 
                                               irsend.sendSony(0x0FF, 12); 
                                               Serial.println("---Send: START---");
                                               delay(100); 
                               }
auskommentiere funktioniert das Receive wieder, falls das weiter hilft.

LG Auron
3  International / Deutsch / IR- Send / Receive Problem on: November 18, 2012, 09:07:35 am
Hallo,
ich möchte eine IR-Kommunikation zwischen zwei Arduino Boards erzeugen und verwende die Lib vom ken shirriff Blog.
Wenn ich nun zwei kleine Testprogramme auf die Boards lade (eins für Send und eines für Receive) funktioniert das Ganze problemlos (Auch in beide Richtungen).
Verwende gerade den Sony Code.

Jetzt aber zum eigentlichen Problem, das mir etwas Kopfzerbrechen bereitet und ich hoffe ihr könnt mir weiterhelfen:
Nachdem ich nun mit dem einen Board gesendet habe "irsend.sendSony(0x0FF,12)" , kann es daraufhin keinerlei Werte mehr empfangen und geht nicht mehr in die "if (irrecv.decode(&results))" Schleife rein. Wenn ich vorher nichts sende funktioniert aber alles.

Kann es sein, dass die Send-Funktion die Receive-Funktion in irgendeiner Art und Weise blockiert? Oder hat jemand schon einmal von diesem Problem gehört? Im Netz habe ich ein paar Posts zu der Frage gefunden, jedoch nie eine Antwort darauf.
Das andere Board sendet per sendSony den 0x0FE

Hier dann noch mein Code:

Code:
#include <IRremote.h>

/*---------------------*/
/* Uno Algorithmus */
/*---------------------*/

// 0x0FF = START
// 0x0FE = START ACCEPTED
// 0x0FD = END

/* PINs */
int RECV_PIN = 11;  // receive
int taster_PIN = 7; // Start Taster

/* Variables */
IRrecv irrecv(RECV_PIN); 
decode_results results; 
IRsend irsend;
int message = 0;
boolean startAccepted = false;  // warte auf Accept vom anderen Board

void setup() {
                Serial.begin(9600);
                pinMode(taster_PIN, INPUT);
                irrecv.enableIRIn(); 
}

void loop() {
                digitalWrite(taster_PIN, LOW);  // taster auf aus
 
                /* PRESS TASTER */
                if (digitalRead(taster_PIN) == HIGH) {  // start wenn taster gedrückt
                               Serial.println("Taster pressed");
   
                               /* SEND START */
                               for (int i = 0; i < 3; i++) { 
                                               irsend.sendSony(0x0FF, 12); 
                                               Serial.println("---Send: START---");
                                               delay(100); 
                               }
   
                               /* RECEIVE START ACCEPTED */
                               while(1) {
                                               Serial.println("1");   // hier gehts noch
                                               if (irrecv.decode(&results)) {   
                                                               Serial.println("2");   // hier geht er nicht mehr rein..
                                                               message = (results.value); 
                                                               Serial.print(message);
                                                               Serial.print(": ");
                                                               if (message==0x0FE) {
                                                                            Serial.println("---Received: START ACCEPTED---");
                                                                            irrecv.resume(); 
                                                                            startAccepted = true;
                                                                            break;
                                                               }
                                                               irrecv.resume(); 
                                             } // if
                           } // while
               
                          /* start Measuring */
                          if (startAccepted == true) {
                                     Serial.println("Passt");
                          }
             } // taster
} // loop()


Ich hoffe ihr könnt mir weiterhelfen... Vielen Dank! :)
Grüße Auron88
Pages: [1]