Show Posts
Pages: [1]
1  Using Arduino / Project Guidance / Re: notifying doorbell and then some more with pushingbox on: June 21, 2012, 03:08:08 am
HI Brad,
I didn't test it yet but it should work

Just try this (with givin the DEVID2 value):

Code:
////
//
// General code from http://www.pushingbox.com for Arduino + Ethernet Shield (official)
//
////

#include <SPI.h>
#include <Ethernet.h>

  /////////////////
 // MODIFY HERE //
/////////////////
byte mac[] = { 0x00, 0xAA, 0xBB, 0xCC, 0xDE, 0x19 };   // Be sure this address is unique in your network

//Your secret DevID from PushingBox.com. You can use multiple DevID  on multiple Pin if you want
#define DEVID1 "vCD1F3635179D6F4"        //Scenario : "The mailbox is open"
#define DEVID2 "vXXXXXXXXXXXXXXX"

//Numeric Pin where you connect your switch
#define pinDevid1 3  // Example : the mailbox switch is connect to the Pin 3
#define pinDevid2 4

// Debug mode
#define DEBUG true
  ///////
 //End//
///////

char serverName[] = "api.pushingbox.com";
boolean pinDevid1State = false;
boolean pinDevid2State = false;

// Initialize the Ethernet client library
// with the IP address and port of the server
// that you want to connect to (port 80 is default for HTTP):
EthernetClient client;

void setup() {
  Serial.begin(9600);
  pinMode(pinDevid1, INPUT);
  pinMode(pinDevid2, INPUT);
  
  // start the Ethernet connection:
  if (Ethernet.begin(mac) == 0) {
    Serial.println("Failed to configure Ethernet using DHCP");
    // no point in carrying on, so do nothing forevermore:
    while(true);
  }
  else{
    Serial.println("Ethernet ready");
  }
  // give the Ethernet shield a second to initialize:
  delay(1000);
}

void loop()
{
      ////
      // Listening for the pinDevid1 state
      ////
      if (digitalRead(pinDevid1) == HIGH && pinDevid1State == false) // switch on pinDevid1 is ON
      {
        if(DEBUG){Serial.println("pinDevid1 is HIGH");}
        pinDevid1State = true;
        //Sending request to PushingBox when the pin is HIGHT
        sendToPushingBox(DEVID1);
      }
       if (digitalRead(pinDevid1) == LOW && pinDevid1State == true) // switch on pinDevid1 is OFF
      {
        if(DEBUG){Serial.println("pinDevid1 is LOW");}
        pinDevid1State = false;
        //Sending request to PushingBox when the pin is LOW
        //sendToPushingBox(DEVID1);
      }
 
 
      ////
      // Listening for the pinDevid2 state
      ////
      if (digitalRead(pinDevid2) == HIGH && pinDevid2State == false) // switch on pinDevid2 is ON
      {
        if(DEBUG){Serial.println("pinDevid2 is HIGH");}
        pinDevid2State = true;
        //Sending request to PushingBox when the pin is HIGHT
        sendToPushingBox(DEVID2);
      }
       if (digitalRead(pinDevid2) == LOW && pinDevid2State == true) // switch on pinDevid2 is OFF
      {
        if(DEBUG){Serial.println("pinDevid2 is LOW");}
        pinDevid2State = false;
        //Sending request to PushingBox when the pin is LOW
        //sendToPushingBox(DEVID2);
      }
}


//Function for sending the request to PushingBox
void sendToPushingBox(String devid){
    if(DEBUG){Serial.println("connecting...");}

  if (client.connect(serverName, 80)) {
    if(DEBUG){Serial.println("connected");}

    if(DEBUG){Serial.println("sendind request");}
    client.print("GET /pushingbox?devid=");
    client.print(devid);
    client.println(" HTTP/1.1");
    client.print("Host: ");
    client.println(serverName);
    client.println("User-Agent: Arduino");
    client.println();
  }
  else {
    if(DEBUG){Serial.println("connection failed");}
  }
  
  // if there are incoming bytes available
  // from the server, read them and print them:
  if(DEBUG){
    if (client.available()) {
    char c = client.read();
    Serial.print(c);
    }
  }

    if(DEBUG){Serial.println();}
    if(DEBUG){Serial.println("disconnecting.");}
    client.stop();
}
2  Topics / Home Automation and Networked Objects / Hacked Doorbell send Push notification on: April 23, 2012, 10:02:22 am
Hi, I wrote a tutorial on how to hack your doorbell to send notification like push, mail or tweet using an Arduino+Ethernet.
Here is a demonstration:


All the details are on MakeProjects :
http://makeprojects.com/Project/Notifying-Doorbell/2165/1
3  Using Arduino / Networking, Protocols, and Devices / Re: other ways of sending a SMS or push to an iPhone on: March 18, 2012, 10:17:39 am
You should try PushingBox (www.pushingbox.com)
It manage your notifications (mail, Push for iPhone/Android/WinowsPhone, tweet...)
There is an Arduino source code on the API page
Pages: [1]