Pages: [1]   Go Down
Author Topic: Uhrzeit NTP Client erweitern + als Class schreiben??  (Read 1310 times)
0 Members and 1 Guest are viewing this topic.
Offline Offline
Newbie
*
Karma: 0
Posts: 6
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Hallo,

ich beschäftige mich erst seit kurzem mit dem Arduino und damit mit C. Wir haben in der Schule ein großes Projekt in einzelne Gruppen gegliedert und dann an einzelne Schülergruppen aufgeteilt, deshalb wurde von meinem Lehrer gefordert alle "teil Programme" als Class oder Function zu schreiben um sie möglichst einfach in das main Programm einzubinden.

Nun wie im Subject beschrieben habe ich als einen Teil die Aufgabe die Uhrzeit und das Datum als NTP Client zu empfangen.
Im Arduino gibt es unter Examples das Beispiel UdpNtpClient damit empfange ich auch die Uhrzeit.
Frage 1: Kann ich diese um das Datum erweitern? Wenn ja, wie?


Nun wollte ich mir es so einfach machen wie möglich und dieses Beispiel etwas umschreiben und damit eine Class erstellen.
Habe mir so gedacht ich packe das alles in eine Methode, welche ich einfach update nennen wollte. In dieser Methode schreibe ich mir dann Stunde, Minute, Sekunde etc. in eine Variable.
Dann nutze ich andere Methoden um einfach die Variable zu bekommen.

Jetzt stoße ich aber auf folgendes Problem. Im Example ist unter dem Main Programm eine Funktion programmiert welche ich einfach nicht in die .cpp Datei oder .h Datei reinbekomme. Bekomme immer Fehler in der Ausgabe.

Code:
// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(IPAddress& address)
{
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:  
  Udp.beginPacket(address, 123); //NTP requests are to port 123
  Udp.write(packetBuffer,NTP_PACKET_SIZE);
  Udp.endPacket();
}
Frage 2: Warum kann ich diese Funktion nicht einfach in meine Class kopieren? Wie kann ich es besser/anders machen?


Ich danke im vorraus.

mfg
« Last Edit: April 14, 2012, 11:17:20 am by uwefed » Logged

0
Offline Offline
Faraday Member
**
Karma: 23
Posts: 3470
20 LEDs are enough
View Profile
WWW
 Bigger Bigger  Smaller Smaller  Reset Reset

Bei Fragen mit code bitte auch code tags verwenden damit man das vernünftig lesen kann.

Weiterhin wäre es nett wenn Du keine hellseherischen Fähigkeiten unterstellst. Wie sehen die Fehler aus die Du bekommst? Kopier die doch bitte rein.

Ausserdem finde ich es schräg ohne Not auf globale Variablen oder member Variablen zu gehen wenn man die Werte auch einfach direkt zurückgeben kann. Es ist auch schräg, dass Du eine Funktion mit "unsigned long" Rückgabewert deklarierst und dann kein return drin vorkommt.
« Last Edit: April 13, 2012, 04:39:27 pm by Udo Klein » Logged

Check out my experiments http://blog.blinkenlight.net

Offline Offline
Newbie
*
Karma: 0
Posts: 6
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Ok sorry, ich versuch es mal etwas Detailierter darzustellen.

In der Arduino Software Version 1.0 gibt es unter Examples das UdpNtpClient Beispiel, welches so aussieht:

Code:
/*

 Udp NTP Client
 
 Get the time from a Network Time Protocol (NTP) time server
 Demonstrates use of UDP sendPacket and ReceivePacket
 For more on NTP time servers and the messages needed to communicate with them,
 see http://en.wikipedia.org/wiki/Network_Time_Protocol
 
 created 4 Sep 2010
 by Michael Margolis
 modified 17 Sep 2010
 by Tom Igoe
 
 This code is in the public domain.

 */

#include <SPI.h>        
#include <Ethernet.h>
#include <EthernetUdp.h>

// Enter a MAC address for your controller below.
// Newer Ethernet shields have a MAC address printed on a sticker on the shield
byte mac[] = {  
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };

unsigned int localPort = 8888;      // local port to listen for UDP packets

IPAddress timeServer(192, 43, 244, 18); // time.nist.gov NTP server

const int NTP_PACKET_SIZE= 48; // NTP time stamp is in the first 48 bytes of the message

byte packetBuffer[ NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

// A UDP instance to let us send and receive packets over UDP
EthernetUDP Udp;

void setup()
{
  Serial.begin(9600);

  // start Ethernet and UDP
  if (Ethernet.begin(mac) == 0) {
    Serial.println("Failed to configure Ethernet using DHCP");
    // no point in carrying on, so do nothing forevermore:
    for(;;)
      ;
  }
  Udp.begin(localPort);
}

void loop()
{
  sendNTPpacket(timeServer); // send an NTP packet to a time server

    // wait to see if a reply is available
  delay(1000);  
  if ( Udp.parsePacket() ) {  
    // We've received a packet, read the data from it
    Udp.read(packetBuffer,NTP_PACKET_SIZE);  // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);  
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord;  
    Serial.print("Seconds since Jan 1 1900 = " );
    Serial.println(secsSince1900);              

    // now convert NTP time into everyday time:
    Serial.print("Unix time = ");
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;    
    // subtract seventy years:
    unsigned long epoch = secsSince1900 - seventyYears;  
    // print Unix time:
    Serial.println(epoch);                              


    // print the hour, minute and second:
    Serial.print("The UTC time is ");       // UTC is the time at Greenwich Meridian (GMT)
    Serial.print((epoch  % 86400L) / 3600); // print the hour (86400 equals secs per day)
    Serial.print(':');  
    if ( ((epoch % 3600) / 60) < 10 ) {
      // In the first 10 minutes of each hour, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.print((epoch  % 3600) / 60); // print the minute (3600 equals secs per minute)
    Serial.print(':');
    if ( (epoch % 60) < 10 ) {
      // In the first 10 seconds of each minute, we'll want a leading '0'
      Serial.print('0');
    }
    Serial.println(epoch %60); // print the second
  }
  // wait ten seconds before asking for the time again
  delay(10000);
}

// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(IPAddress& address)
{
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:  
  Udp.beginPacket(address, 123); //NTP requests are to port 123
  Udp.write(packetBuffer,NTP_PACKET_SIZE);
  Udp.endPacket();
}





Dieses Beispiel liefert mir zur Zeit Stunde, Minute und Sekunde. Sehr gut.
- Ich hätte gern,soweit möglich, auch den Tag, Monat und das Jahr.

Desweiteren besteht die Anforderung von unserem Lehrer es in eine Funktion oder Klasse zu schreiben damit es einfach per Include und wenigen Zeilen in ein "Hauptprogramm" eingebunden werden kann.
Hier bekomme ich fehler, welche ich nicht in den Griff bekomme.

Ich habe den Code aus dem Beispiel oben kopiert, umgeschrieben und in Methoden gepackt um eine Klasse zu erstellen.

Meine Header Datei.

Code:
#ifndef _Zeitserver_H
#define _Zeitserver_H

#include <SPI.h>        
#include <Ethernet.h>
#include <EthernetUdp.h>
#include <WString.h>

class Zeitserver
{

private:

bool update; // Mithilfe dieser Variable wird die aktuelle Uhrzeit vom Zeitserver geholt.
bool sommerwinter; // Mithilfe dieser Variable wird zwischen Sommer- und Winterzeit unterschieden
bool fehler; // Es ist ein Fehler aufgetreten.
unsigned long stunde;
unsigned long minute;
unsigned long sekunde;
unsigned long sekundenseit1900;
unsigned long unixtime;



public:

unsigned long getstunde();
unsigned long getminute();
unsigned long getsekunde();
bool getsommerwinter();

    void setsommerwinter(bool);
void setupdate();




};  
#endif  
Logged

Offline Offline
Newbie
*
Karma: 0
Posts: 6
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Dann meine .cpp Datei

Code:


#include "Zeitserver.h"
#include <stdio.h>
#include <string.h>
#include <inttypes.h>
#include "Arduino.h"
#include <SPI.h>         
#include <Ethernet.h>
#include <EthernetUdp.h>
#include <WString.h>

// In der .h Datei sind die Deklarationen der Klasse vorhaden. Es ist kein ausführbarer Code vorhanden.

// In der .cpp Datei werden die Methoden mit ausführbaren Code programmiert.

// SD_lesen_schreiben.cpp


//get Methoden



unsigned long Zeitserver::getstunde()
{
return stunde;
}

unsigned long Zeitserver::getminute()
{
return minute;
}

unsigned long Zeitserver::getsekunde()
{
return sekunde;
}

bool Zeitserver::getsommerwinter()
{
return sommerwinter;
}



//set Methoden


void Zeitserver::setsommerwinter(bool Wert)
{
sommerwinter=Wert;
}

void Zeitserver::setupdate()
{
// Füge die Mac Addresse deines Controlers ein.
// auf den neuen Arduinos ist eine Mac-Adresse aufgedruckt
byte mac[] = {  0x90, 0xA2, 0xDA, 0x00, 0x9E, 0xFE };


//byte gateway[] = { 10,40,0,1 }; // Wird nur benötigt wenn DHCP nicht möglich ist.
//byte ip [] = { 10,40,1,74 };
unsigned int localPort = 8888; // lokaler port der auf UDP Protokolle lauscht

IPAddress timeServer(62, 206, 250,163); // IP Addresse (62.206.250.163) des Zeitservers  Forum für Zeitmessung, Berlin

const int NTP_PACKET_SIZE= 48; // NTP Zeit Stempel ist in den ersten 48 bytes der Nachricht, deshalb begrenze auf 48 bytes.

byte packetBuffer[ NTP_PACKET_SIZE]; //Zwischenspeicher der ankommende und gehende Packete zwischenspeichert

EthernetUDP Udp; // Eine UDP Instanz die uns ein Empfangspacket über UDP senden lässt
  if (Ethernet.begin(mac) == 0) // Starte Netzwerkverbindung
  {
    fehler=true; // Netzwerkverbindung konnte nich hergestellt werden setze Variable "fehler" true.
  }
  else
  {
    fehler=false; // Netzwerkverbindung wurde hergestellt, alles ok.
  }


  Udp.begin(localPort);

  sendNTPpacket(timeServer); // Fordere das NTP Packet des Zeitserver´s an
  delay(1000); // Warte um zu sehen ob eine Antwort erfolgt.
  if ( Udp.parsePacket() ) // Ein Paket wurde empfangen , lies die Daten heraus
  {   
    Udp.read(packetBuffer,NTP_PACKET_SIZE); // Daten werden in den Zwischenspeicher geschrieben

    // Der Zeitstempel startet beim 40. Byte des empfangenen Pakets und ist vier Bytes groß
    // oder zwei Worte lang. Extrahiere erst die beiden Worte.

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]); 
    //  Wandle die 4 byte (zwei Worte) in einen langen Integer
    //  Das ist die NTP Zeit(seconds seit dem 1.Januar 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord; 
    sekundenseit1900=secsSince1900;
             

    // jetzt Konvertiere die NTP Zeit in die Tageszeit
    // UnixZeit startete am 1 Jan 1970 . In Sekunden, sind das 2208988800 Sekunden:
    const unsigned long seventyYears = 2208988800UL;     
    // extrahiere 70 Jahre heraus:
    unsigned long epoch = secsSince1900 - seventyYears; 
    // Speicher Unix Zeit:
    unixtime=epoch;                               


    // Berechne die Stunde , Minute und Sekunde:
stunde=((epoch  % 86400L) / 3600); // Berechne die Stunde (86400 äquivalent sekunden am Tag)
    minute=((epoch  % 3600) / 60); // Berechne die Minute (3600 sekunden pro Stunde)
    sekunde=(epoch %60); // Berechne die Sekunde
  }


  //  Sende eine NTP Anfrage an den Zeit server mit der angegebenen Addresse 
unsigned long sendNTPpacket(IPAddress& address)
{
  // Setze alle Bytes im Zwischenspeicher auf  0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialisierungseinheiten die zum formen der NTP Anfrage gebraucht werden
  // (siehe die URL oben für Details des Packets )
  packetBuffer[0] = 0b11100011; // LI, Version, Mode
  packetBuffer[1] = 0; // Schicht, oder Typ der Uhr
  packetBuffer[2] = 6; // Abfrage Interval
  packetBuffer[3] = 0xEC; // gucke auf die Uhr Präzision
  // 8 bytes von 0 für die Gesamtfehlereinschätzung
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // alle NTP Felder haben die Werte jetzt gegeben
  //  Du kannst ein Packet senden um den Zeitstempel zu hinterfragen     
  Udp.beginPacket(address, 123); // eine NTP anfrage an den Port 123
  Udp.write(packetBuffer,NTP_PACKET_SIZE);
  Udp.endPacket();
}


}


So und zu guter letzt das Beispiel welches ich in den Arduino laufen lassen will.

Code:
////////////////////////////////////////////////////////////////////// Include Anfang ////////////////////////////////////////////////////////////////////////////////////////


#include <SPI.h>         
#include <Ethernet.h>
#include <EthernetUdp.h>
#include <Zeitserver.h>

////////////////////////////////////////////////////////////////////// Include Ende    ////////////////////////////////////////////////////////////////////////////////////////







//////////////////////////////////////////////////////////// Initialisierung/Deklarierung Objekte / Klassen Anfang /////////////////////////////////////////////////////////////////////

Zeitserver Zeit;

//////////////////////////////////////////////////////////// Initialisierung/Deklarierung Objekte / Klassen Ende  /////////////////////////////////////////////////////////////////////






////////////////////////////////////////////////////////////////////// Beginne Setup //////////////////////////////////////////////////////////////////////////////////

void setup ()
{
  Zeit.setsommerwinter(true);
  Zeit.setupdate();
  unsigned long stunde=Zeit.getstunde();
  unsigned long minute=Zeit.getminute();
  unsigned long sekunde=Zeit.getsekunde();
  boolean fehler=Zeit.getfehler();

 
 
  Serial.begin(9600);
  if(fehler==true)
  {
   Serial.println("Es konnte keine Netzwerkverbindung hergestellt werden.");
  }
  else
  {
  Serial.println(stunde);
  Serial.println(minute);
  Serial.println(sekunde);
  }
}


Dieser Fehler wird in der Arduino Software ausgespuckt':
C:\Users\Admin\Zeitserver.cpp: In member function 'void Zeitserver::setupdate()':
C:\Users\Admin\Zeitserver.cpp:155: error: a function-definition is not allowed here before '{' token



Ich hoffe ich habe nichts vergessen.

Danke
Logged

Offline Offline
Jr. Member
**
Karma: 0
Posts: 92
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Du hast vergessen, die Methode setupdate() mit einer geschweiften Klammer abzuschließen.

Rudi
Logged

Offline Offline
Newbie
*
Karma: 0
Posts: 6
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Hallo,

habe den Code jetzt 5mal durchgeguckt finde jedoch zu jeder öffnenden geschweiften Klammer auch eine schließende, habe ich vielleicht eine an der falschen stelle? Habe mal versucht die Methode vor der unsigned long sendNTPpacket... zu schließen bekomme dann jedoch, logischer weise viele Fehler wegen fehlenden Deklarationen.

Logged

Offline Offline
Jr. Member
**
Karma: 0
Posts: 92
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Hallo,

vielleicht habe ja ich Tomaten auf den Augen, aber ich hätte jetzt vermutet, dass

Code:
 if ( Udp.parsePacket() ) // Ein Paket wurde empfangen , lies die Daten heraus
  {    
    Udp.read(packetBuffer,NTP_PACKET_SIZE); // Daten werden in den Zwischenspeicher geschrieben

    // Der Zeitstempel startet beim 40. Byte des empfangenen Pakets und ist vier Bytes groß
    // oder zwei Worte lang. Extrahiere erst die beiden Worte.

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);  
    //  Wandle die 4 byte (zwei Worte) in einen langen Integer
    //  Das ist die NTP Zeit(seconds seit dem 1.Januar 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord;  
    sekundenseit1900=secsSince1900;
            

    // jetzt Konvertiere die NTP Zeit in die Tageszeit
    // UnixZeit startete am 1 Jan 1970 . In Sekunden, sind das 2208988800 Sekunden:
    const unsigned long seventyYears = 2208988800UL;    
    // extrahiere 70 Jahre heraus:
    unsigned long epoch = secsSince1900 - seventyYears;  
    // Speicher Unix Zeit:
    unixtime=epoch;                              


    // Berechne die Stunde , Minute und Sekunde:
stunde=((epoch  % 86400L) / 3600); // Berechne die Stunde (86400 äquivalent sekunden am Tag)
    minute=((epoch  % 3600) / 60); // Berechne die Minute (3600 sekunden pro Stunde)
    sekunde=(epoch %60); // Berechne die Sekunde
  }

die letzte Klammer zur if-Bedingung gehört. Wo ist dann aber die Klammer zur Abschluss der Methode?
Meiner Meinung nach muss da vor sendNTPpacket noch eine geschweifte Klammer hin.

Oder hast du den Sourcecode inzwischen geändert?
« Last Edit: April 16, 2012, 09:34:46 am by rz259 » Logged

0
Offline Offline
Faraday Member
**
Karma: 23
Posts: 3470
20 LEDs are enough
View Profile
WWW
 Bigger Bigger  Smaller Smaller  Reset Reset

Meiner Meinung fragt man sowas nicht im Forum. Stattdessen nimmt man einen Editor der zu jeder Klammer das entsprechende Gegenstück anzeigen kann. Dann stellen sich solche Fragen nicht mehr lange.
Logged

Check out my experiments http://blog.blinkenlight.net

Offline Offline
Newbie
*
Karma: 0
Posts: 6
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Hallo,

nach der if Bedingung folgt noch die besagte Problem Funtkion und dannach schließe ich die Methode ab.

Kann ich das so nicht machen? Habe schon versucht die Funktion mit in die Header zu schreiben, klappt jedoch auch nicht.

Danke
Logged

Offline Offline
Newbie
*
Karma: 0
Posts: 6
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Hallo,

ich habe es geschafft danke leute. Bin nochmal ins grübbeln gekommen mit dieser Funktion in Methode Geschichte. Bin dann auf die Idee gekommen dafür eine eigene Methode zu schreiben sprich:


Code:
const int NTP_PACKET_SIZE= 48; // NTP Zeit Stempel ist in den ersten 48 bytes der Nachricht, deshalb begrenze auf 48 bytes.

byte packetBuffer[ NTP_PACKET_SIZE]; //Zwischenspeicher der ankommende und gehende Packete zwischenspeichert

EthernetUDP Udp; // Eine UDP Instanz die uns ein Empfangspacket über UDP senden lässt
unsigned long Zeitserver::sendNTPpacket(IPAddress& address)
{
  // Setze alle Bytes im Zwischenspeicher auf  0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialisierungseinheiten die zum formen der NTP Anfrage gebraucht werden
  // (siehe die URL oben für Details des Packets )
  packetBuffer[0] = 0b11100011; // LI, Version, Mode
  packetBuffer[1] = 0; // Schicht, oder Typ der Uhr
  packetBuffer[2] = 6; // Abfrage Interval
  packetBuffer[3] = 0xEC; // gucke auf die Uhr Präzision
  // 8 bytes von 0 für die Gesamtfehlereinschätzung
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // alle NTP Felder haben die Werte jetzt gegeben
  //  Du kannst ein Packet senden um den Zeitstempel zu hinterfragen     
  Udp.beginPacket(address, 123); // eine NTP anfrage an den Port 123
  Udp.write(packetBuffer,NTP_PACKET_SIZE);
  Udp.endPacket();
}

Damit funktioniert es! Danke euch leute!
Logged

Pages: [1]   Go Up
Jump to: