Pages: [1]   Go Down
Author Topic: How to use SD library over SPI for logging SPI sensors?  (Read 916 times)
0 Members and 1 Guest are viewing this topic.
Offline Offline
Jr. Member
**
Karma: 0
Posts: 50
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Hi all,

i want to use the SD lib for logging the values coming from my ADXL345 accelerometer. The problem is that the SD lib uses SPI.setDataMode(SPI_MODE0) and the sensors requieres SPI_MODE3. Thus my sensors don't work when the SD library is connected.

Does anyone have experience on this topic? The tutorial by Jeremy is great but he uses analog sensors....

thanks in advacne !

my code:

Code:
//Add the SPI library so we can communicate with the ADXL345 sensor
#include <SPI.h>
#include <SD.h>

//Assign the Chip Select signal to pin 10.
int CS=10;
int chip_SD=3;

//This is a list of some of the registers available on the ADXL345.
//To learn more about these and the rest of the registers on the ADXL345, read the datasheet!
char POWER_CTL = 0x2D; //Power Control Register
char DATA_FORMAT = 0x31;
char DATAX0 = 0x32; //X-Axis Data 0
char DATAX1 = 0x33; //X-Axis Data 1
char DATAY0 = 0x34; //Y-Axis Data 0
char DATAY1 = 0x35; //Y-Axis Data 1
char DATAZ0 = 0x36; //Z-Axis Data 0
char DATAZ1 = 0x37; //Z-Axis Data 1

//This buffer will hold values read from the ADXL345 registers.
unsigned char values[10];

//These variables will be used to hold the x,y and z axis accelerometer values.
int x,y,z;

float xg, yg, zg;

void setup(){
  //Initiate an SPI communication instance.
  SPI.begin();
  //Configure the SPI connection for the ADXL345.
  SPI.setDataMode(SPI_MODE3);
  //Create a serial connection to display the data on the terminal.
  Serial.begin(9600);

  //Set up the Chip Select pin to be an output from the Arduino.
  pinMode(CS, OUTPUT);
  //Before communication starts, the Chip Select pin needs to be set high.
  digitalWrite(CS, HIGH);

  //Put the ADXL345 into +/- 4G range by writing the value 0x01 to the DATA_FORMAT register.
  writeRegister(CS, DATA_FORMAT, 0x01);
  //Put the ADXL345 into Measurement Mode by writing 0x08 to the POWER_CTL register.
  writeRegister(CS, POWER_CTL, 0x08);  //Measurement mode

  Serial.print("Initializing SD card...");
  // make sure that the default chip select pin is set to
  // output, even if you don't use it:
  pinMode(53, OUTPUT);

  // see if the card is present and can be initialized:
  if (!SD.begin(chip_SD)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    //return;
  }
  else{ 
    Serial.println("card initialized.");
  }


}

void loop(){
  //Reading 6 bytes of data starting at register DATAX0 will retrieve the x,y and z acceleration values from the ADXL345.
  //The results of the read operation will get stored to the values[] buffer.
  readRegister(CS, DATAX0, 6, values);


  //The ADXL345 gives 10-bit acceleration values, but they are stored as bytes (8-bits). To get the full value, two bytes must be combi
  //-ed for each axis.
    //The X value is stored in values[0] and values[1].
  x = ((int)values[1]<<8)|(int)values[0];
  //The Y value is stored in values[2] and values[3].
  y = ((int)values[3]<<8)|(int)values[2];
  //The Z value is stored in values[4] and values[5].
  z = ((int)values[5]<<8)|(int)values[4];

  xg = x * 0.0078;
  yg = y * 0.0078;
  zg = z * 0.0078;
  //Print the results to the terminal.

  Serial.print("acc 1,   G value (xyz): ");

  Serial.print(xg, 2);
  Serial.print("\t");
  Serial.print(yg, 2);
  Serial.print("\t");
  Serial.println(zg, 2);

  Serial.print("acc 1, raw value (xyz): ");
  Serial.print(x, DEC);
  Serial.print("\t");
  Serial.print(y, DEC);
  Serial.print("\t");
  Serial.println(z, DEC);

  Serial.println("");
 
  String str = "this is data";
  print_to_file(str);

  delay(2000);
}

//This function will write a value to a register on the ADXL345.
//Parameters:
//  char registerAddress - The register to write a value to
//  char value - The value to be written to the specified register.
void writeRegister(int pin, char registerAddress, char value){
  //Set Chip Select pin low to signal the beginning of an SPI packet.
  digitalWrite(pin, LOW);
  //Transfer the register address over SPI.
  SPI.transfer(registerAddress);
  //Transfer the desired register value over SPI.
  SPI.transfer(value);
  //Set the Chip Select pin high to signal the end of an SPI packet.
  digitalWrite(pin, HIGH);
}

//This function will read a certain number of registers starting from a specified address and store their values in a buffer.
//Parameters:
//  char registerAddress - The register addresse to start the read sequence from.
//  int numBytes - The number of registers that should be read.
//  char * values - A pointer to a buffer where the results of the operation should be stored.
void readRegister(int pin, char registerAddress, int numBytes,unsigned char * values){
  //Since we're performing a read operation, the most significant bit of the register address should be set.
  char address = 0x80 | registerAddress;
  //If we're doing a multi-byte read, bit 6 needs to be set as well.
  if(numBytes > 1)address = address | 0x40;
  //Set the Chip select pin low to start an SPI packet.
  digitalWrite(pin, LOW);
  //Transfer the starting register address that needs to be read.
  SPI.transfer(address);
  //Continue to read registers until we've read the number specified, storing the results to the input buffer.
  for(int i=0; i<numBytes; i++){
    values[i] = SPI.transfer(0x00);
  }
  //Set the Chips Select pin high to end the SPI packet.
  digitalWrite(pin, HIGH);
}

void print_to_file(String dataString){
  //open the file
  File dataFile = SD.open("datalog.txt", FILE_WRITE);

  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  } 
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  }
}
Logged

0
Online Online
Edison Member
*
Karma: 67
Posts: 1660
Arduino rocks
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

The Arduino SPI library doesn't work well for sharing the SPI bus among/between devices.

The old version of SdFat used as the base SD.h also doesn't share the SPI bus well.

The problem is that all SPI options must be set each time you access an SPI device.

I am the author of SdFat and have modified newer versions of SdFat to set all SPI options each time SD chip select is made low.

The SPI library should be modified to take into account the fact that each SPI device require its SPI options to be set before transfering data.
Logged

Offline Offline
Jr. Member
**
Karma: 0
Posts: 50
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Thanks for the quick reply, and your efforts put into the lib!

I downloaded the fat32 lib from google code but i can't find any examples doing this.

I thought of changing the datamode throughout the program (every time i want to write to SD i temporarily set datamode to 0) but no luck so far.

SO do i have to conclude that this comnination is at all not possible?

If so i would have to control my sensor through a multiplexer, that would be less efficient.Doable, but rather i would do it differently.

Thank you,

Jorrit
Logged

0
Online Online
Edison Member
*
Karma: 67
Posts: 1660
Arduino rocks
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

You don't need to do anything with SdFat if you downloaded sdfatlib20111205.zip from http://code.google.com/p/sdfatlib/downloads/list.

SdFat handles setting the correct SPI mode internally with this code for selecting the SD:
Code:
/**
 * Initialize hardware SPI
 * Set SCK rate to F_CPU/pow(2, 1 + spiRate) for spiRate [0,6]
 */
static void spiInit(uint8_t spiRate) {
  // See avr processor documentation
  SPCR = (1 << SPE) | (1 << MSTR) | (spiRate >> 1);
  SPSR = spiRate & 1 || spiRate == 6 ? 0 : 1 << SPI2X;
}
void Sd2Card::chipSelectLow() {
#ifndef SOFTWARE_SPI
  spiInit(spiRate_);
#endif  // SOFTWARE_SPI
  digitalWrite(chipSelectPin_, LOW);
}
 

The only option is the SPI speed which is set in the init call
Code:
 if (!sd.init(SPI_HALF_SPEED, CHIP_SELECT)) sd.initErrorHalt();

You need to provide similar code for your sensor to set the correct SPI mode/speed when you access it.

Set the SPI mode for your device after these lines:
Code:
void writeRegister(int pin, char registerAddress, char value){
  //Set Chip Select pin low to signal the beginning of an SPI packet.
  digitalWrite(pin, LOW);

Edit:
Have you verified that the SD is wired correctly by running a program like the SdFat QuickStart example?

To try QuickStart insert code at the begining of setup() to set chip select for your device high like this:
Code:
void setup() {
  pinMode(YOUR_DEVICE_CS_PIN, OUTPUT);
  digitalWrite(YOUR_DEVICE_CS_PIN, HIGH);
  // rest of QuickStart setup code here
« Last Edit: June 08, 2012, 10:24:20 am by fat16lib » Logged

Offline Offline
Jr. Member
**
Karma: 0
Posts: 50
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Hi,

thanks for your the new library, I thought of accessing my sensors through an analog connection with a multiplexer.

In the future I will definitely use this, but i'm OK for now.
Thanks again!
Logged

Pages: [1]   Go Up
Jump to: