In the interests of working out how inaccurate the faster conversion would be, I set up a test measuring various voltages with the 125 kHz ADC clock and the 250 kHz clock. The results are:
Two samples per voltage from 0 to 5V in steps of 1V. There only seems to be a difference of 1 unit maximum.
// Example of taking ADC readings at different ADC clock frequencies
// Author: Nick Gammon
// Date: 13 July 2012
#include <avr/sleep.h>
const byte adcPin = 0;
const byte switchPin = 8;
volatile int adcReading;
volatile boolean adcDone;
boolean adcStarted;
boolean slow;
unsigned long startTime;
volatile unsigned long finish;
void setup ()
{
Serial.begin (115200);
// set the analog reference (high two bits of ADMUX) and select the
// channel (low 4 bits). this also sets ADLAR (left-adjust result)
// to 0 (the default).
ADMUX = _BV (REFS0) | (adcPin & 0x07);
pinMode (switchPin, INPUT);
digitalWrite (switchPin, HIGH);
} // end of setup
// ADC complete ISR
ISR (ADC_vect)
{
byte low, high;
finish = micros ();
// we have to read ADCL first; doing so locks both ADCL
// and ADCH until ADCH is read. reading ADCL second would
// cause the results of each conversion to be discarded,
// as ADCL and ADCH would be locked when it completed.
low = ADCL;
high = ADCH;
adcReading = (high << 8) | low;
adcDone = true;
} // end of ADC_vect
void loop ()
{
// if last reading finished, process it
if (adcDone)
{
adcStarted = false;
ADCSRA &= ~ _BV (ADIE); // no more interrupts for now
// do something with the reading, for example, print it
Serial.println (adcReading);
float volts = (float) adcReading / 1024.0 * 5.0;
Serial.print ("Volts: ");
Serial.println (volts, 2);
Serial.print ("Time taken: ");
Serial.println (finish - startTime, DEC);
delay (500);
if (!slow)
Serial.println ();
adcDone = false;
}
// if we aren't taking a reading, start a new one
if (!adcStarted)
{
if (slow)
{
slow = false;
Serial.print ("Fast: ");
delay (100); // let that print
ADCSRA &= ~ _BV (ADPS0); // 250 kHz clock
}
else
{
// no switch pressed? do nothing
if (digitalRead (switchPin) != LOW)
return;
slow = true;
Serial.print ("Slow: ");
delay (100); // let that print
ADCSRA |= _BV (ADPS0); // 125 kHz clock
} // not just done slow
// do a few reads to prime the damned thing
for (byte i = 0; i < 5; i++)
analogRead (adcPin);
adcStarted = true;
startTime = micros ();
// start the conversion
ADCSRA |= _BV (ADSC) | _BV (ADIE) | _BV (ADIF);
// set_sleep_mode (SLEEP_MODE_ADC); // sleep during sample
// sleep_mode ();
} // not taking reading
// do other stuff here
} // end of loop
I had to take the sleep out because it also stopped the micros() clock. I wanted the clock there to be certain I was in fact doing the faster ADC conversion.
