Probleme mit Programmcode für Türschloßprojekt

Hallo,

ich habe eine Frage zu einem Code für ein Türschlossprojekt. Es handelt sich um diesen Code:

#include <MyAnalogKeyPad.h>
#include <LiquidCrystal.h>
#define analogPinKeyPad 0 // Definition des analogen Pins
#define RS 12 // Register Select
#define E 11 // Enable
#define D4 5 // Datenleitung 4
#define D5 4 // Datenleitung 5
#define D6 3 // Datenleitung 6
#define D7 2 // Datenleitung 7
#define COLS 16 // Anzahl der Spalten
#define ROWS 2 // Anzahl der Zeilen
int CODE = 9200; // Die generierte Zahl, Anzahl der Versuche
char Eingabe[5]; // max. 5 stellige Zahl generieren
byte stelle;

MyAnalogKeyPad myOwnKeyPad (analogPinKeyPad); // KeyPad Instanziieren
LiquidCrystal lcd ( RS,E,D4,D5,D6,D7); // LCD Instanziieren

void setup(){
myOwnKeyPad.setDebounceTime(500); // Prellzeit auf 500ms setzen
lcd.begin(COLS, ROWS); // Anzahl der Spalten und Zeilen
startSequence(); // Aufruf der Startsequenz
}

void loop(){
char myKey = myOwnKeyPad.readKey(); // Abfragen des gedrückten Tasters
if (myKey != KEY_NOT_PRESSED){ // Abfragen ob irgendein Taster gedrückt ist
Eingabe[stelle] = myKey;
stelle++;
lcd.print(myKey); // Taste im LCD anzeigen
}
if (stelle == int(log10(CODE))+1){
int a = atoi(Eingabe);
if ( a == CODE){
lcd.clear(); // LCD Anzeige löschen
lcd.print("Code zugelassen"); // Ausgabe an das LCD Display
delay(2000); // 2 Sekunden warten
stelle = 0;
startSequence(); // Startsequenz aufrufen
}
else if( a != CODE){
lcd.setCursor(0,1); // Cursor in die 1. Zeile positionieren
lcd.print("Code verweigert"); // Ausgabe an das LCD Display
lcd.setCursor(0,0);
}
else{
lcd.setCursor(0,1); // Cursor in die 2. Zeile positionieren
lcd.print("Code verweigert"); // Ausgabe an das LCD Display
lcd.setCursor(0,0);
}
lcd.setCursor(2,0); // Cursor an die 3. Stelle in der 1. Zeile positionieren

stelle = 0;
}
}

void startSequence(){
lcd.clear(); // Display Anzeige löschen
lcd.print("TEST FUER"); // Ausgabe an das LCD Display
lcd.setCursor(0,1); // Cursor in die 2. Zeile positionieren
lcd.print(" AUSBILDUNG");
delay(2000); // 4 Sekunden warten
lcd.clear(); // LCD Anzeige löschen
}

Die Library für das Keypad liefert mir folgende Werte zurück je nachdem welche Taste gedrückt ist:

nichts gedrückt - KEY_NOT_PRESSED
0 - KEY_0
1 - KEY_1
2 - KEY_2
3 - KEY_3
4 - KEY_4
5 - KEY_5
6 - KEY_6
7 - KEY_7
8 - KEY_8
9 - KEY_9

- KEY_hash

    • KEY_star

Wie man nun mit den eingelesenen Werten arbeitet, bzw. sie mit dem vorgegebenen Kennwort zu vergleichen ist mir soweit eigentlich schon gelungen (zumindest einigermaßen). Jetzt möchte ich das wenn die Eingabe: #100 ist das man in eine bestimmte andere Menüebene kommt. Die Ebene erstellen und so klappt auch alles. Ich habe nur an folgender Stelle ein Problem:

Wie kann ich die beiden Zeichen: # , * einlesen? Wenn ich zum Beispiel oben in dem Programmcode meinen CODE von der aktuellen Zahl 9200 zum Beispiel in #100 ändere kommt eine Fehlermeldung. Ich kenn mich mit der Materie noch nicht richtig aus deshalb kann ich mir nicht so richtig helfen. Ich vermute es hat was mit dem Datentyp der Variablen CODE zu tun. Wenn ja welchen Datentyp müsste ich nehmen?

Gruß,

Tobias

CODE ist ein int, und es ist auch nicht vorgesehen, dies zu ändern. ( Ohne alles über den Haufen zu werfen)

und * sind eher als Begrenzungszeichen zu sehen

hmm, schonmal danke aber ich hab das nicht ganz verstanden.
Wenn ich auf dem KeyPad die Tasten # und * drücke bekomme ich die auch so auf dem LCD Display angezeigt. Nun muss es doch möglich sein eine Variable zu deklarieren die anstatt der CODE Variable 9200 eben #100 als Wert hat. Und dann auf die selbe Art wie bei der CODE Abfrage sagen wenn die Eingabe ( myKey) #100 ist dann mache das....... Geht das nicht ohne viel Aufwand?

Gruß

Geht das nicht ohne viel Aufwand?

Na ja, schon, aber von deinem Beispiel-Code bleibt nicht viel übrig.

Die gedrückten Tasten findest du in char myKey und char Eingabe[5];

Um Sachen wie

  if (stelle == int(log10(CODE))+1) {

wäre es nicht schade, meiner Meinung nach...

danke für die Antwort. Was meinst du mit "wäre es nicht schade meiner Meinung nach" ? Hmm dann wirft das halt meine Pläne durcheinander bzw. schränkt die Auswahl des Passwortes ein, aber wenn es sonst den ganzen Sketch umwirft muss ich es dann wohl lassen :wink:

Um Sachen wie
  if (stelle == int(log10(CODE))+1) {
wäre es nicht schade, meiner Meinung nach...

... weil die log10 Funktion, zumal wenn CODE nicht als const deklariert wurde, eine aufwändige float Operation ist, und das nur, um rauszukriegen, wie viele Stellen dein konstanter Schlüssel-Code hat.

Na ja konstant ist er ja nur erstmal in diesem Beispiel, aber trotzdem ...


Dass der eigentliche Code nur aus Ziffern besteht und * und # als Trennzeichen verwendet werden, würde mich nicht stören. Das erleichtert eher die Kommunikation bei Fehleingaben. ( So machen es zumindest andere Zahlenschlösser mit einer solchen Tastatur ).

Hey,
Danke für die Rückmeldung.

Mir ging es halt wegen den Sonderzeichen darum das man z.B. mit der Eingabe #100 in die Menüebene kommt, da das einlesen der Zeichen halt doch nicht so geht muss mann z.B. 1000 eintippen um in das Menü zu kommen. Dann fällt halt 1000 als mögliches Kennwort was man sich einstellen kann raus. So dachte ich halt. Aber da das ganze ein überschaubares Projekt ist gibt es nicht so viele Sonderkombinationen.

Gruß und danke für die Infos,

Tobi

Ob man grade einen Schlüssel eintippt oder ein Menü steuert, sollte doch dem Benutzer angezeigt werden, und also auch dem Programm klar sein, oder?

Ich verstehe wohl dein Problem nicht...
Ich würde z.B. als Ende des Schlüssels die '*' - Taste nehmen, danach bist du wieder im Menü - Modus,
z.B. mit den Funktionen 0 .. 9, oder # für neue Schlüsseleingabe

( Sollte ja auch alles auf deinem 16x2 Display darstellbar sein )

Ein reines "Türschloss-Projekt" hat ja auch kein großes Menu: Schlüssel eingeben, falls offen: Schliessen, Schlüssel ändern, Bestätigen.
Was noch ? ( mehrere Schlüssel ?)

Mich wundert, dass der Code überhaupt häuft.

 char myKey = myOwnKeyPad.readKey();

du definierst myKey als einzelnen char obwohl deine Funktion eine Zeichenkette liefert (KEY_X). Ich würde MyAnalogKeyPad.h so ändern, dass mir die Lib auch nur einen char zurückgibt.

obwohl deine Funktion eine Zeichenkette liefert (KEY_X).

Und welche Library verwendest du ?
Tobias' in
#include <MyAnalogKeyPad.h>
verwendete scheint immerhin zu kompilieren, auch wenn er nicht verrät was er da nimmt...

Und dass eine Funktion namens keyPressed() einen Buchstaben zurückliefert, ist doch recht sinnvoll, oder.

Ich verwende meine eigene Subroutine die liefert ein byte zurück:

0 -> 0
...
9 -> 9

  • -> 10

-> 11

nichts -> 12
Fehler -> 13

Ich vermute durch die Zuweisung gibt es einen Überlauf und in myKey wird nur das letzte Zeichen des Strings gespeichert. Das Funktioniert auch bei Key_0 bis Key_9. Nur bei # = KEY_hash steht dann in myKey ein h und bei * = KEY_star ein r. Dann funktioniert die Funktion atoi() aber nicht mehr. Das ganze ist keine saubere Lösung und dass es funktioniert ist ehr ein Zufall.

Nur bei # = KEY_hash steht dann in myKey ein h und bei * = KEY_star ein r.

???
Ich weiss nicht wo bei
[b]#define KEY_hash '#'  [/b]
der Buchstabe 'h' ( 0x68 ) vorkommt
???


Da es bei Tobias schon ziemlich funktionert, ist mir klar, dass sein keyPressed() bei der Taste 0 ein '0' liefert, usw.
Eingabe[4] bleibt immer 0, damit geht dann auch atoi(Eingabe). sobald man genau 4 Ziffern eingetippt hat.

Ich weiss nicht wo bei
[b]#define KEY_hash '#'  [/b]
der Buchstabe 'h' ( 0x68 ) vorkommt
???

Da es bei Tobias schon ziemlich funktionert, ist mir klar, dass sein keyPressed() bei der Taste 0 ein '0' liefert, usw.
Eingabe[4] bleibt immer 0, damit geht dann auch atoi(Eingabe). sobald man genau 4 Ziffern eingetippt hat.

ich weiß jetzt nicht wo du dass #define KEY_hash '#' her hast. Tobias93 hat das ganze so beschrieben: Taste - Rückgabewert

Die Library für das Keypad liefert mir folgende Werte zurück je nachdem welche Taste gedrückt ist:

nichts gedrückt - KEY_NOT_PRESSED
0 - KEY_0
1 - KEY_1
2 - KEY_2
3 - KEY_3
4 - KEY_4
5 - KEY_5
6 - KEY_6
7 - KEY_7
8 - KEY_8
9 - KEY_9

- KEY_hash

    • KEY_star

Ich persönlich versuche alles was mit strings zu tun hat in C zu vermeiden. Strings brauchen viel speicher und lassen sich unkomfortabel verarbeiten. Z.B hat Eingabe im Sketch eine Größe von 5 * 8 bit = 40 bit für 5 stellen. Mit einem long mit 32 bit kannst du einen 9-stelligen code eingeben.

Ich persönlich versuche alles was mit strings zu tun hat in C zu vermeiden

Genau, ich auch.

Daher war ich gar nicht auf die Idee gekommen, dass

...
9 - KEY_9

- KEY_hash

    • KEY_star

irgendwas mit Strings zu tun haben könnte. Hat's ja auch nicht :wink:

ich weiß jetzt nicht wo du das
#define KEY_hash '#'
her hast.

Geraten.
Ist auch eigentlich egal, jedenfalls im Beispielcode dieses Threads.
"KEY_hash" als string ist auf jeden Fall Unsinn. Und sicher nicht der Rückgabewert von keyPressed().

ok. Wie ich oben ganz am Anfang geschrieben habe: Ich bin Anfänger auf dem Gebiet, dass heißt so ziemlich 50% der letzten Posts sind für mich Böhmsche Dörfer :frowning:
Ich versuchs mal zu erklären. Der Sketch und die dafür benötigten Librarys habe ich mittels des Lehrbuchs: "Die elektronische Welt mit Arduino entdecken" geschrieben, dass heißt was da steht hab ich eingetippt und die Sktech Erklärung dazu habe ich versucht zu verstehen.

Ich versuche jetzt mal mein Problem genau wie möglich in Worte zu fassen:

Die Header Datei die für das Projekt angelegt wurde:

#ifndef MYKEYPAD_H
#define MYKEYPAD_H

#if ARDUINO < 100
#include <WProgram.h>
#else
#include <Arduino.h>
#endif

#define KEY_NOT_PRESSED '-'
#define KEY_1 '1'
#define KEY_2 '2'
#define KEY_3 '3'
#define KEY_4 '4'
#define KEY_5 '5'
#define KEY_6 '6'
#define KEY_7 '7'
#define KEY_8 '8'
#define KEY_9 '9'
#define KEY_0 '0'
#define KEY_star 'stern'
#define KEY_hash 'raute'

class MyAnalogKeyPad{
public:
MyAnalogKeyPad (byte analogPin); // Parametrisierter Konstruktor
void setDebounceTime(unsigned int debounceTime); // setzen der Prellzeit
void setThresholdValue(byte tv); // setzen der Threshold (Grenzwert)
char readKey(); // Ermitteln des gedrückten Tasters auf Keypad
private:
byte analogPin; // analoger Pin zur Messwertaufnahme
unsigned long debounceTime; // private Variable für die Prellzeit
long lastValue; // letzte Zeit der millis-Funktion
byte threshold; // Toleranzwert
};
#endif

nun poste ich die cpp Datei:

#include "MyAnalogKeyPad.h" // Parametrisierter Konstruktor

MyAnalogKeyPad::MyAnalogKeyPad(byte ap){
analogPin = ap; // Analog Pin für Messwertaufnahme
debounceTime= 300; // Initialwert für DebounceTime festlegen
threshold = 5; // Toleranzwert festlegen
}

void MyAnalogKeyPad::setDebounceTime(unsigned int time){ // Methode zum Setzen der Prellzeit
debounceTime = time;
}

void MyAnalogKeyPad::setThresholdValue(byte tv){ // Methode zum Setzen der Tolleranz
threshold = tv;
}

char MyAnalogKeyPad::readKey(){ // Methode zum Ermitteln des gedrückten Tasters auf dem Keypad
char key = KEY_NOT_PRESSED; // Initialwert von key ist "KEY_NOT_PRESSED" (nichts ist gedrückt)
byte aValue = analogRead(analogPin);
if((aValue > 0)&&(millis()- lastValue >= debounceTime)){
if((aValue > (176 - threshold))&&(aValue < (176 + threshold)))
key = KEY_1;
if((aValue > (163 - threshold))&&(aValue < (163 + threshold)))
key = KEY_2;
if((aValue > (149 - threshold))&&(aValue < (149 + threshold)))
key = KEY_3;
if((aValue > (136 - threshold))&&(aValue < (136 + threshold)))
key = KEY_4;
if((aValue > (122 - threshold))&&(aValue < (122 + threshold)))
key = KEY_5;
if((aValue > (108 - threshold))&&(aValue < (108 + threshold)))
key = KEY_6;
if((aValue > (94 - threshold))&&(aValue < (94 + threshold)))
key = KEY_7;
if((aValue > (79 - threshold))&&(aValue < (79 + threshold)))
key = KEY_8;
if((aValue > (64 - threshold))&&(aValue < (64 + threshold)))
key = KEY_9;
if((aValue > (48 - threshold))&&(aValue < (48 + threshold)))
key = KEY_star;
if((aValue > (32 - threshold))&&(aValue < (32 + threshold)))
key = KEY_0;
if((aValue > (15 - threshold))&&(aValue < (15 + threshold)))
key = KEY_hash;

lastValue = millis();
}
return key;
}

Der passende Sketch wurde ja schon zu Anfang gepostet.

Nun beschreibe ich euch mal meinen aktuellen Standpunkt:

Das Programm funktioniert in sofern das ich wenn die Zahlen 9200, also der in CODE gespeicherte Wert eingegeben wird ein I/O Port geschaltet wird... Tür geht auf.
Wenn die Falschen Zahlen eingegeben werden geht die Tür nicht auf. Die beiden Zeichen will ich mal rauslassen weil da läuft´s nicht so richtig wenn die eingetippt werden spielt der Sketch irgendwie die Reise nach Jerusalem :slight_smile:

Ok hab ich mir gedacht dann überbrückst du die beiden Schalter halt und dann hat sichs. Nun möchte ich aber das man mit der Kombination #100 oder *100 oder irgend einer Kombination mit den Zeichen in eine Menüeebene kommt um da z.B. das Kennwort zu ändern. Jetzt steh ich vor dem Problem das die Sonderzeichen ja nicht funktionieren... das is ja schonmal schlecht. Hab ich mir gedacht, komm egal, nimmste als Kombination die dich ins Menü bringt eben 0000, dann fällt die Kombination eben als mögliche Kennwortkombination weg.... bleiben ja immer noch genug.

Jetzt geb ich also 0000 ein und komme in das Menü - bis dahin klappts.
Nun lasse ich am Display anzeigen :
Auswahl:
1 = Code aendern

Jetzt will ich das ich wenn ich eine 1 eintippe (nur eine 1 nicht 0001) das ich dann in die Ebene zum Menü ändern komme. Tippe ich nun 1 ein, passiert nichts... Da bin ich aber glaube ich selbst auf das Problem gestoßen. Ich müsste ein Array anlegen was nur eine Zahl speichert und nicht [5] oder ? Whatever gebe ich nun halt 0001 ein bekomme ich angezeigt Coder verweigert und er springt wider an den Anfang. Das heißt er scheint nicht zu verstehen das er nun eine Ebene höher ist und die Eingaben hier nicht mit den Vorgaben der Ebene für die Codeeingabe verglichen werden sollen.

Könnt ihr mir hier eine Tipp geben wie man das Problem lösen kann, vielleicht auch mit Begründung, damit ich es verstehe?

Schonmal vielen Dank,

Tobias

Mach dir als erstes ein Struktogramm/PAP und überleg wie dein Programm funktionieren soll. Wenn du das geschafft hast kannst du dir über die Programmierung Gedanken machen. Das ist dann eine rein technische Frage. Dabei solltest du die Konventionen von C kennen und beachten. Ließ ein Tutorial und beschäftige dich nochmal damit was Datentypen sind. Dann überlegst du, ob du unbedingt mit char arbeiten möchtest, oder ob du einfach byte bzw. int Variablen benutzt. Mit letzteren kann man rechnen und Bitopperationen durchführen. Dann könnte man seinen code auch so einlesen:

myKey = myOwnKeyPad.readKey(); // Abfragen des gedrückten Tasters
if (myKey != X){ // X ist eine Zahl die kommt, wenn keine Taste gedrückt wurde
Eingabe = Eingabe*10+myKey;
}

... was Datentypen sind. Dann überlegst du, ob du unbedingt mit char arbeiten möchtest, oder ob du einfach byte bzw. int Variablen benutzt. Mit letzteren kann man rechnen und Bitopperationen durchführen

circuit99 hat Recht, nur oben erwähnter Satz ist evtl. missverständlich.
byte und char ist fast dasselbe, bis auf das Vorzeichen. Du meinst sicher den Unterschied zwischen

#define KEY_0 '0' // 0x30
#define KEY_0 0 // 0x00

Beides kann sowohl in byte wie auch in char Variablen verwendet werden.

Ersteres kann gleich angezeigt werden, das zweite ist leichter zum Rechnen. Der Unterschied ist aber minimal ( '0' dazuaddieren bzw. abziehen, oder auch bitweise ein/ausblenden)

int brauchst du nur für mehrstellige codes ( long wenns über 4 Stellen sein können ). Ein 8 bit Arduino arbeitet lieber mit bytes.


#define KEY_star 'stern'
#define KEY_hash 'raute'

ist sehr verwirrend. Schade, dass der Compiler das überhaupt zulässt.

#define KEY_star '*'    // ist übrigens kleiner als '0'

oder

#define KEY_star 10  // oder irgendein Wert > 9

Muss in jedem Fall bei der Berechnung abgefangen werden ( was z.Zt. fehlt und zu Tobias' "Reise nach Jerusalem" führt )

Es gibt 2 Punkte die ich nicht verstehe / bzw. nicht hinbekomme.

  1. Wie funktioniert das Einlesen. Wie speichere ich am besten die Eingabe ab, damit ich mit ihr dann auch weiter rechnen und arbeiten kann? Besonders im Bezug auf die Zeichen * und #

  2. Wie kann ich das Einlesen der Codes für die einzelnen Ebenen anpassen. Das heißt das er in der Startebene wo er auffordert den Code einzulesen, soll er ja nur bei Eingabe = CODE den Code akzeptieren. Gibt man z.B. #100 ein soll man in die Menüebene kommen. Alle anderen Eingaben werden als falsch erkannt. Ist man nun in der Menüebene und soll auch wider für irgendwelche Funktionen was eingeben soll er ja nun wider etwas einlesen, allerdings das nicht mit den Parametern aus der Startebene vergleichen. Das macht er aktuell. Gibt man z.B. 1000 für Code ändern ein zeigt er an CODE verweigert, das was er aber nur in der Startebene machen soll.

Ich finde zu den beiden Punkten keine Lösung bzw. bekomme es nicht hin.
Ich wäre dankbar für Lösungsvorschläge.
Gruß
Tobias93

Hallo,
ich kämpfe mich gerade durch ein ähnliche Problem (siehe String abfragen ?). In meinem Sketch habe dann auch 'atoi' ausprobiert, es wurde mir hier dann der Wert 35 (ascii für #) bzw. 42 (ascii für *) ausgegeben, also "421000" für "*1000", allerdings hat mich das ganze nicht richtig weitergebracht. :disappointed_relieved:

Versuchen wir mal, es einfach zu machen :wink:

Mit jedem Tastendruck liefert readKey() ein Zeichen zurück und hat sich schon um Prellen und kurze/lange Tastendrücke gekümmert, oder liefert bei Abfrage den Wert KEY_NOT_PRESSED, wenn kein neuer Tastendruck da war. Das ist doch schon das Schwierigste.

Für mich das zweitschwierigste war:

#define KEY_star 'stern'

und tatsächlich, Kinder, wenn euch meine Erklärung verwirrt, oder es zu grausam ist, macht schnell die Augen zu

(ich hab meinen Arduino geopfert und es ausprobiert):

#define KEY_STAR 'stern' // kein Syntaxfehler, ist ja nur der Präprozessor
  byte testkey = KEY_STAR;  // kein Syntaxfehler
  static char teststring[]= "---";
  teststring[1] = testkey;
  Serial.println(teststring);  // erzeugt  "-n-"

Genauso erzeugt
#define KEY_hash 'raute' im Endeffekt ein 'e'

Das ist jetzt wohl nur Tobias' Problem.


wie Arduinokiller einmal einen Stern als 42 kriegen kann ist mir klar. Merkwürdig ist mir, wie er aber aus "10" eine "4210" (statt z.B. "424948" , weil eine '1' hat den ASCII-wert 49 (0x31) genauso wie '' den Wert 42 hat.


Tobias kann natürlich die Library anpassen, da hatten wir schon 2 Varianten, eine zum einfach Rechnen, eine zum einfach Anzeigen.
Ab jetzt nehm ich mal an, wir bleiben beim Einfach Anzeigen und die Stern-Taste würde als '' im Display erscheinen, wenns ein 'n' ist wissen wir ja, warum. Rechnen (einen als Zahl agespeicherten CODE ermitteln und vergleichen) kann man mit '' genauso schlecht wie mit 'n'.
Ihr könnt die Augen wieder aufmachen

Ein Sclüsselcode bestht also nur aus Ziffern, die # und * Tasten sind was besonderes. Was, das kann man sich frei wählen.
Für's einfache Verständnis lassen wir so wie es jetzt ist: Schlüsselcode sind 4 Ziffern, nicht mehr und nicht weniger.

Wir wollen ausser einer Code-Eingabe auch in einen Funktions-Menü-Modus springen:
Nehmen wir doch dazu das * Zeichen.
Dann definieren wir noch das # Zeichen als Anfang einer Code Eingabe, das hilft auch, wenn man sich vertippt hat.
Bei variabel langen Schlüsseln brauchen wir noch ein Ende-Zeichen ( zB. den Stern ) aber lassen wir das erstmal.

#define EINGABE 0
#define MENU 1
byte mode = EINGABE;  // Voreinstellung

byte stelle = 0;
unsigned int CODE = 9367;
unsigned int Eingabe = 0; // gleich als Zahl umgerechnet

void loop(){
  char myKey = myOwnKeyPad.readKey();                    // Abfragen des gedrückten Tasters
  if (myKey != KEY_NOT_PRESSED){                         // Abfragen ob irgendein Taster gedrückt ist
     lcd.print(myKey);                                      // Taste im LCD anzeigen
     if ( mode == EINGABE)
       switch (myKey)  {
       case KEY_STAR:
         mode = MENU;
         break;
      case KEY_HASH:
         delay(200); // damit man das # Zeichen noch kurz sieht
         stelle = 0;    // alles auf Anfang
         Eingabe = 0;
         lcd.clear(); // ...
         break;
      default:  // alle anderen Tasten
         Eingabe = Eingabe*10 + myKey-'0' ;  // setzt voraus, dass diese
         stelle++;
         if ( stelle == 4) {
           if (Eingabe == CODE) {
               // usw. ( richtiger Code )
           } else {
               // falscher Code
           }
         }
         break;
     } // Ende switch
     else {   // Menu - Zweig
         if ( myKey == ...
         // wie kommen wir wieder zur Code - eingabe ???
     }
  }
}