Go Down

Topic: Problème avec un BMP05 et un arduino UNO ethernet (Read 1 time) previous topic - next topic

Hotfirenet

Bonjour à tous,
j'ai acheté sur eBay un capteur similaire à ce que adafruit a pu sortir: http://www.adafruit.com/products/391
donc j'utilise le code mis a disposition par adafruit, c'est d'ailleurs ce que conseille pas mal de topic sur le forum mais le problème c'est que je retrouve avec des valeurs que je n'attend pas du tout :
Code: [Select]

Temperature = -13421773.00 *C
Pressure = 234 Pa

Temperature = -13421773.00 *C
Pressure = 234 Pa

Temperature = -13421773.00 *C
Pressure = 234 Pa


Est ce qu'il y aurait une ame charitable pour m'aiguiller ?
merci par avance

skywodd

Bonjour,

Le capteur est câblé correctement ?
Ça m'as tout l'air d'être un capteur 3v3, donc faire très attention au câblage ;)

Il ne fournisse pas un schéma sur la page ebay ?
Des news, des tuto et plein de bonne chose sur http://skyduino.wordpress.com !

Hotfirenet

Hello skywood,
alors il y a tout un tas de trucs que je ne connais pas, et surtout c'est que le modèle que j'ai ne correspond pas tout a fait avec le descriptif.
j'ai mis en pièce jointe la photo du produit et celle qui était dans le zip.
Tu as surement raison je dois mal branché le circuit, et le module fonctionne apparemment en 3v et 5v.

Merci skywood

fdufnews

La charte du forum demande de limiter la taille des images à 800x600.

skywodd


alors il y a tout un tas de trucs que je ne connais pas, et surtout c'est que le modèle que j'ai ne correspond pas tout a fait avec le descriptif.

Ça à l'air d'être le même capteur pourtant, ou du moins un capteur compatible "broche à broche".


Tu as surement raison je dois mal branché le circuit, et le module fonctionne apparemment en 3v et 5v.

Il fonctionne en 5v apparemment vu qu'il ont mis un régulateur 3v3 sur la carte.
Comment as tu branché le capteur à ton arduino ?
Des news, des tuto et plein de bonne chose sur http://skyduino.wordpress.com !

Hotfirenet

De la même façon que sur adafruit.
Merci skywood

skywodd

Essaye des codes plus bas niveaux pour être sûr que ce n'est pas un problème de librairie :
http://bildr.org/2011/06/bmp085-arduino/
http://www.sparkfun.com/tutorial/Barometric/BMP085_Example_Code.pde

C'est bizarre le montage semble bon ...
Des news, des tuto et plein de bonne chose sur http://skyduino.wordpress.com !

Hotfirenet

Hello skywood,
j'ai modifier le code sparkfun car il utilisé du received au lieu de reader et send au lieu de read.
Code: [Select]
/* BMP085 Extended Example Code
  by: Jim Lindblom
  SparkFun Electronics
  date: 1/18/11
  license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/
 
  Get pressure and temperature from the BMP085 and calculate altitude.
  Serial.print it out at 9600 baud to serial monitor.

  Update (7/19/11): I've heard folks may be encountering issues
  with this code, who're running an Arduino at 8MHz. If you're
  using an Arduino Pro 3.3V/8MHz, or the like, you may need to
  increase some of the delays in the bmp085ReadUP and
  bmp085ReadUT functions.
*/

#include <Wire.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;

short temperature;
long pressure;

void setup()
{
  Serial.begin(9600);
  Wire.begin();
  bmp085Calibration();
}

void loop()
{
  temperature = bmp085GetTemperature(bmp085ReadUT());
  pressure = bmp085GetPressure(bmp085ReadUP());
  Serial.print("Temperature: ");
  Serial.print(temperature, DEC);
  Serial.println(" *0.1 deg C");
  Serial.print("Pressure: ");
  Serial.print(pressure, DEC);
  Serial.println(" Pa");
  Serial.println();
  delay(1000);
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
  long x1, x2;
 
  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  return ((b5 + 8)>>4); 
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;
 
  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
 
  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
 
  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;
   
  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;
 
  return p;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;
 
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
 
  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;
   
  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;
 
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
 
  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();
 
  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
  unsigned int ut;
 
  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();
 
  // Wait at least 4.5ms
  delay(5);
 
  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;
 
  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();
 
  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));
 
  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF6);
  Wire.endTransmission();
  Wire.requestFrom(BMP085_ADDRESS, 3);
 
  // Wait for data to become available
  while(Wire.available() < 3)
    ;
  msb = Wire.read();
  lsb = Wire.read();
  xlsb = Wire.read();
 
  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
 
  return up;
}


pour les 2 codes je me retrouve avec le moniteur série vide .. voir pj

Merci encore skywood

fdufnews

Le code donné comme exemple avec la librairie Adafruit fonctionne correctement. Je l'ai essayé sur un capteur que j'ai et il retourne les bonnes info de température et de pression.

Si tu récupères des données erronées il y a plusieurs possibilité:
1) Mauvaise interconnexion. Le capteur fonctionne en 3,3V. Ta carte dispose d'un régulateur 3,3V mais par contre il n'y a rien sur les entrées pour limiter la tension alors que l'arduino sort en 5V. Sur la carte que je possède il y a des adaptateurs en série (transistor FET) dans les lignes SDA et SCL pour protéger le BMP085.
2) les données de calibration ont été corrompues. Dans le BMP085 il y a une vingtaine d'octets qui contiennent des données de calibration qui sont programmées en usine. Elles servent à calculer la température et la pression réelle à partir des valeurs retournées par le capteur. Tu as pu les effacer/modifier en faisant une fausse manip.

Hotfirenet

Bonjour fdufnews,
je ne remet absolument pas en cause le code de adafruit mais plus un problème venant de ma part ou du circuit acheté.
j'ai peut être fait une fausse manip je ne sais pas, mais comment faire pour rétablir ou déjà dans un premier temps recueillir des infos ?

merci par avance

fdufnews


Bonjour fdufnews,
je ne remet absolument pas en cause le code de adafruit mais plus un problème venant de ma part ou du circuit acheté.
j'ai peut être fait une fausse manip je ne sais pas, mais comment faire pour rétablir ou déjà dans un premier temps recueillir des infos ?

merci par avance

D'où la deuxième partie de ma réponse ci-dessus.
Si le schéma que tu as publié correspond bien à ta carte, l'interface n'est pas adaptée aux signaux en 5V que délivre l'Arduino. Il faudrait utiliser un truc dans ce genre http://www.lextronic.fr/P4108-platine-de-conversion-de-niveau.html pour adapter les niveaux.

Pour le second point que j'ai soulevé je n'ai pas de solution. Il faudrait voir sur le site de BOSCH s'il y a moyen de refaire une calibration.


skywodd

Je n'arrive plus à retrouver l'article qui en parlait mais l'i2c est un bus à collecteur ouvert.
Donc normalement si il utilise des résistances de pull-up en 3v3 est uniquement celles ci le bus complet fonctionne en 3v3, donc sans avoir besoin de level-shifter.
Des news, des tuto et plein de bonne chose sur http://skyduino.wordpress.com !

Hotfirenet

ce qu'il y a de sur c'est que le produit est vendu pour fonctionner avec l'arduino,
le code fourni dans le zip correspond à celui trouvé sur sparkfun. je penche plus pour un soucis de code enfin bon je vais pas continuer a m'embêter et je prendre celui de adafruit.

fdufnews


Je n'arrive plus à retrouver l'article qui en parlait mais l'i2c est un bus à collecteur ouvert.
Donc normalement si il utilise des résistances de pull-up en 3v3 est uniquement celles ci le bus complet fonctionne en 3v3, donc sans avoir besoin de level-shifter.

Bien sur c'est un bus collecteur ouvert mais en entrée il faut que les niveaux soit compatibles TTL pour l'ATmega.

skywodd


Bien sur c'est un bus collecteur ouvert mais en entrée il faut que les niveaux soit compatibles TTL pour l'ATmega.

Pas forcément, 3v3 c'est largement au dessus de la tension de commutation VCC/2.
(faudrait vraiment que je retrouve cet article, mais plus je cherche moins je trouve ...)
Des news, des tuto et plein de bonne chose sur http://skyduino.wordpress.com !

Go Up