Here are the results from lay with my set of Lidl outlets:
/*
SilverCrest 91210 RCS AAA3680 - A IP20
Below code will transmit on and off signals to SilverCrest 91210 Remote Electrical Sockets
Based on code from http://forum.arduino.cc/index.php?topic=202556.msg1492685#msg1492685
Modifed by Poopi, Tested on Teensy 2.0++
Sequence had two distinct sub sequences -
1. 4x with short sync and short '1's
2. 4x with long sync and longer '1's
Codes were cycled - 4 different codes per each plug but you can choose any of these codes - I used all to mimic original RCU
Seems that 4 last bits are a PLUG identifier and first 4 bits are a remote identifier
Remaining 16 bits seems to be common for all plugs ( Plug C have reverted On/Off sequences sic! )
All codes captured from original RCU usin logic analyzer
Below setup as two Button Pins (each button pin 1 is sent to arduino pins 5 and 8 and pin 4 sent to ground)
Button 1 sends the signal
Button 2 cycles through the functions (A, B, C, D and Master)
433Mhz Transmitter set up on pins 27 and 24
Pin 27 - transmit
Pin 24 - VCC of the transmitter
LED on pin 6 flashes while sending signal
*/
#define DEBUG
/*Setup*/
#define BUTTON_PIN1 26
#define BUTTON_PIN2 25
#define RF_DATA_PIN 27
#define RF_ENABLE_PIN 24
#define BLINK_LED_PIN 6
#define MAX_CODE_CYCLES 4
#define SHORT_DELAY 380
#define NORMAL_DELAY 500
#define SIGNAL_DELAY 1500
#define SYNC_DELAY 2650
#define EXTRASHORT_DELAY 3000
#define EXTRA_DELAY 10000
enum {
PLUG_A = 0,
PLUG_B,
PLUG_C,
PLUG_D,
PLUG_MASTER,
PLUG_LAST
};
unsigned long signals[PLUG_LAST][2][MAX_CODE_CYCLES] = {
{ /*A*/
{0b010000110001000000110000, 0b010001011000011101000000, 0b010000010111111001110000, 0b010010110101111110110000},
{0b010011010100101000100000, 0b010001100010110000010000, 0b010000001110110110010000, 0b010010101111000110100000}
},
{ /*B*/
{0b010000110001000000110100, 0b010001011000011101000100, 0b010000010111111001110100, 0b010010110101111110110100},
{0b010011010100101000100100, 0b010001100010110000010100, 0b010000001110110110010100, 0b010010101111000110100100}
},
{ /*C*/
{0b010011010100101000101100, 0b010001100010110000011100, 0b010000001110110110011100, 0b010010101111000110101100},
{0b010000110001000000111100, 0b010001011000011101001100, 0b010000010111111001111100, 0b010010110101111110111100}
},
{ /*D*/
{0b010000110001000000110010, 0b010001011000011101000010, 0b010000010111111001110010, 0b010010110101111110110010},
{0b010011010100101000100010, 0b010001100010110000010010, 0b010000001110110110010010, 0b010010101111000110100010}
},
{ /*MASTER*/
{0b010000110001000000111010, 0b010001011000011101001010, 0b010000010111111001111010, 0b010010110101111110111010},
{0b010011010100101000101010, 0b010001100010110000011010, 0b010000001110110110011010, 0b010010101111000110101010}
},
};
boolean onOff;
unsigned char plug;
unsigned char swap;
void setup() {
pinMode(BLINK_LED_PIN, OUTPUT);
pinMode(RF_DATA_PIN, OUTPUT);
pinMode(RF_ENABLE_PIN, OUTPUT);
digitalWrite(RF_ENABLE_PIN,LOW);
pinMode(BUTTON_PIN1, INPUT_PULLUP);
pinMode(BUTTON_PIN2, INPUT_PULLUP);
pinMode(13, OUTPUT);
Serial.begin(9600);
Serial.println("Ready");
onOff = 1;
swap = 0;
plug = PLUG_C;
}
void loop() {
if (digitalRead(BUTTON_PIN2) == LOW) {
plug++;
plug%=PLUG_LAST;
Serial.print("PLUG_");
Serial.print(plug == PLUG_MASTER?'M':(char)('A'+plug));
Serial.println(" activated");
delay(1000);
}
if (digitalRead(BUTTON_PIN1) == LOW) {
digitalWrite(BLINK_LED_PIN,HIGH);
ActivatePlug(plug,onOff);
digitalWrite(BLINK_LED_PIN,LOW);
onOff = !onOff;
delay(500);
}
}
void sendSync(){
digitalWrite(RF_DATA_PIN, HIGH);
delayMicroseconds(SHORT_DELAY);
digitalWrite(RF_DATA_PIN, LOW);
delayMicroseconds(SYNC_DELAY - SHORT_DELAY);
}
void sendValue(boolean value, unsigned int base_delay){
unsigned long d = value? SIGNAL_DELAY - base_delay : base_delay;
digitalWrite(RF_DATA_PIN, HIGH);
delayMicroseconds(d);
digitalWrite(RF_DATA_PIN, LOW);
delayMicroseconds(SIGNAL_DELAY - d);
}
void longSync(){
digitalWrite(RF_DATA_PIN, HIGH);
delayMicroseconds(EXTRASHORT_DELAY);
digitalWrite(RF_DATA_PIN, LOW);
delayMicroseconds(EXTRA_DELAY - EXTRASHORT_DELAY);
}
void ActivatePlug(unsigned char PlugNo, boolean On) {
if( PlugNo < PLUG_LAST ) {
digitalWrite(RF_DATA_PIN,LOW);
digitalWrite(RF_ENABLE_PIN,HIGH);
delayMicroseconds(1000);
unsigned long signal = signals[PlugNo][On][swap];
swap++;
swap%=MAX_CODE_CYCLES;
#ifdef DEBUG
Serial.print("PLUG_");
Serial.print(plug == PLUG_MASTER?'M':(char)('A'+plug));
Serial.print(" ");
Serial.println(onOff?"On":"Off");
Serial.println(signal, BIN);
#endif
for (unsigned char i=0; i<4; i++) { // repeat 1st signal sequence 4 times
sendSync();
for (unsigned char k=0; k<24; k++) { //as 24 long and short signals, this loop sends each one and if it is long, it takes it away from total delay so that there is a short between it and the next signal and viceversa
sendValue(bitRead(signal, 23-k),SHORT_DELAY);
}
}
for (unsigned char i=0; i<4; i++) { // repeat 2nd signal sequence 4 times with NORMAL DELAY
longSync();
for (unsigned char k=0; k<24; k++) {
sendValue(bitRead(signal, 23-k),NORMAL_DELAY);
}
}
digitalWrite(RF_ENABLE_PIN,LOW);
}
}
