next topic »

[on:]

Hi,

I am new to arduino & trying to find out how to control relays by sending sms to my arduino platform. I am using naked SIM300 GSM module with Tx, Rx & GND pins. I am using InduinoX board (UNO Clone). Pin 4,5,6,7 are connected to 4 relays with common ground. I have a sample code...

Code:

#include <SoftwareSerial.h>
 

// EN: String buffer for the GPRS shield message
String msg = String("");
// EN: Set to 1 when the next GPRS shield message will contains the SMS message
int SmsContentFlag = 0;
//control pins of relay.
int relay_a=4;
int relay_b=5;
int relay_c=6;
int relay_d=7;

// EN: Code PIN of the SIM card (if applied)
//String SIM_PIN_CODE = String( "XXXX" );
 
void setup()
{
  Serial.begin(19200);                 // the GPRS baud rate
  // Initialize  PINs
  pinMode( 4, OUTPUT );
  pinMode( 5, OUTPUT );
  pinMode( 6, OUTPUT );
  pinMode( 7, OUTPUT );
  digitalWrite( 4, LOW );
  digitalWrite( 5, LOW );
  digitalWrite( 6, LOW );
  digitalWrite( 7, LOW );
 Serial.println( "AT+CMGF=1" );
 delay(200);
}
 
void loop()
{
    char SerialInByte;
    if(Serial.available())
    {      
        SerialInByte = (unsigned char)Serial.read();
       delay(5);
        
        // -------------------------------------------------------------------
        // EN: Program also listen to the GPRS shield message.
        // -------------------------------------------------------------------
       // EN: If the message ends with <CR> then process the message
        if( SerialInByte == 13 ){
          // EN: Store the char into the message buffer
          ProcessGprsMsg();
         }
         if( SerialInByte == 10 ){
            // EN: Skip Line feed
         }
         else {
           // EN: store the current character in the message string buffer
           msg += String(SerialInByte);
         }
     }  
}
// EN: Make action based on the content of the SMS.
//     Notice than SMS content is the result of the processing of several GPRS shield messages.
void ProcessSms( String sms ){
  
  if( sms.indexOf("ona") >= 0 ){
    digitalWrite( relay_a, HIGH );
  }
   if( sms.indexOf("onb") >= 0 ){
    digitalWrite(  relay_b, HIGH );
  }
   if( sms.indexOf("onc") >= 0 ){
    digitalWrite(  relay_c, HIGH );
  }
  if( sms.indexOf("ond") >= 0 ){
    digitalWrite(  relay_d, HIGH );
  }
  if( sms.indexOf("offa") >= 0 ){
    digitalWrite(  relay_a, LOW );
  }
  if( sms.indexOf("offb") >= 0 ){
    digitalWrite(  relay_b, LOW );
  }
  if( sms.indexOf("offc") >= 0 ){
    digitalWrite(  relay_c, LOW );
  }
  if( sms.indexOf("offd") >= 0 ){
    digitalWrite(  relay_d, LOW );
  }
}
// EN: Request Text Mode for SMS messaging
void GprsTextModeSMS(){
  Serial.println( "AT+CMGF=1" );
}

void GprsReadSmsStore( String SmsStorePos ){
  Serial.print( "AT+CMGR=" );
  Serial.println( SmsStorePos );
}

// EN: Clear the GPRS shield message buffer
void ClearGprsMsg(){
  msg = "";
}

// EN: interpret the GPRS shield message and act appropiately
void ProcessGprsMsg() {
  if( msg.indexOf( "Call Ready" ) >= 0 ){
   //  Serial.println( "*** GPRS Shield registered on Mobile Network ***" );
     GprsTextModeSMS();
  }
  
  // EN: unsolicited message received when getting a SMS message
  if( msg.indexOf( "+CMTI" ) >= 0 ){
   //  Serial.println( "*** SMS Received ***" );
     // EN: Look for the coma in the full message (+CMTI: "SM",6)
     //     In the sample, the SMS is stored at position 6
     int iPos = msg.indexOf( "," );
     String SmsStorePos = msg.substring( iPos+1 );
   //  Serial.print( "SMS stored at " );
  //   Serial.println( SmsStorePos );    
     // EN: Ask to read the SMS store
     GprsReadSmsStore( SmsStorePos );
  }
  
  // EN: SMS store readed through UART (result of GprsReadSmsStore request)  
  if( msg.indexOf( "+CMGR:" ) >= 0 ){
    // EN: Next message will contains the BODY of SMS
    SmsContentFlag = 1;
    // EN: Following lines are essentiel to not clear the flag!
    ClearGprsMsg();
    return;
  }
  
  // EN: +CMGR message just before indicate that the following GRPS Shield message
  //     (this message) will contains the SMS body
  if( SmsContentFlag == 1 ){
 //   Serial.println( "*** SMS MESSAGE CONTENT ***" );
 //   Serial.println( msg );
 //   Serial.println( "*** END OF SMS MESSAGE ***" );
    ProcessSms( msg );
  }
  
  ClearGprsMsg();
  // EN: Always clear the flag
  SmsContentFlag = 0;
}

Now, I am trying to modify the code because my sim300 module has only 25 sms memory.
From the AT command set I learned to delete the entire sms memory by AT+CMGDA="DEL ALL" if TEXT mode (AT+CMGF=1) is selected. Now I am trying to implement the "DELETE SMS" code into the main example code.

I have tried a few alterations but they are not working. I can see what actually happens in the serial communication from the SerialMonitor option of Arduino. The first two Images are my attempt to delete the sms memory & it is the screenshot of the system after sending the "onb" (relay b ON) mesege to sim300. There is no confirmation of receiving any sms, neither my code worked at all.

The example code works fine but the issue is it cant delete the SMS memory. Kindly check my altered code & give any suggestion to get my code into work.

First Attempt...

Nothing happens after sending sms to gsm module


Second Attempt...



How the example code works...

AT+CMGR=8 confirms that the new sms has been strored & read from no. 8 sms location.


the example code prints that a new sms arrived & activates the relay but my code doesn't....

What should be altered..? any clue?
Thanks for putting time to read my post... cheers

[Reply #1 on:]

Hello,
I have added the following code in the void loop () so that every time the RESET happens, it will erase the whole SMS memory first...

Code:

Serial.write("AT+CMGDA=");
Serial.write("34"); //ASCII of "
Serial.write("DEL ALL");
Serial.write("34");
Serial.write("13"); //ASCII of ENTER
Serial.write("10"); //ASCII of\n
delay(1000);

The At command for deleting the whole sms memory in text mode is
AT+CMGF=1                            // Select TEXT MODE
AT+CMGDA="DEL ALL"              // Delete SMS Memory

Am I doing something wrong in the code? Any suggestions will be highly appreciated.
Thanks

[Reply #2 on:]

I have sorted out the problem. I was doing wrong with the delays. My SIM300 modem takes 1 sec for selecting text mode & approx 5 secs for deleting the whole SMS memory. I have added the appropriate delay & finally I am getting the expected output.

The code is here...

Code:

  Serial.println( "AT+CMGF=1" );
 delay(2000);
 Serial.print( "AT+CMGDA=" );
Serial.write(34);
Serial.print("DEL ALL");
Serial.write(34);
Serial.write(13);
Serial.write(10);
delay(6000);
Serial.println( "Let's Test..." );

Cheers...

[Reply #3 on:]

The next step is to make the process asynchronous. Is there some reason you need to wait until the messages are deleted?

[Reply #4 on:]

nope, It would be great if the delay for the DEL SMS can be overcome somehow. But the SMS memory has to be deleted because the GSM modem has only 25 sms memory. I wanted to delete the whole sms memory after every reset. any suggestions?