Read data from computer to arduino

Using Arduino Networking, Protocols, and Devices
6

However When i key in value
"test" or "1000.00", I am sure i need to write the code to received this value in arduino right?

Having a reason to send random junk to the Arduino would be good. If you have one, state what it is.

Delimiting the packet that you send makes it easier to know when the full packet has been received. If you have start and end delimiters, you can use code like this to receive data from the serial port:

#define SOP '<'
#define EOP '>'

bool started = false;
bool ended = false;

char inData[80];
byte index;

void setup()
{
   Serial.begin(57600);
   // Other stuff...
}

void loop()
{
  // Read all serial data available, as fast as possible
  while(Serial.available() > 0)
  {
    char inChar = Serial.read();
    if(inChar == SOP)
    {
       index = 0;
       inData[index] = '\0';
       started = true;
       ended = false;
    }
    else if(inChar == EOP)
    {
       ended = true;
       break;
    }
    else
    {
      if(index < 79)
      {
        inData[index] = inChar;
        index++;
        inData[index] = '\0';
      }
    }
  }

  // We are here either because all pending serial
  // data has been read OR because an end of
  // packet marker arrived. Which is it?
  if(started && ended)
  {
    // The end of packet marker arrived. Process the packet

    // Reset for the next packet
    started = false;
    ended = false;
    index = 0;
    inData[index] = '\0';
  }
}

Where it says "Process the packet", you'd add code to deal with the random data sent (stored in inData).