Go Down

Topic: J204A LCD - Unusual Symbols Being Displayed (Read 464 times) previous topic - next topic

redz06vette

Greetings to All,
I am having an issue with displaying proper values when writing to an lcd within a loop; I am only able to get "chinese" type symbols out.  I have noticed that there exists a pattern to the unusual symbols; for example, if attempting to display "TTTTT", I get the same symbols.  Any help would be GREATLY appreciated.  I have spent countless hours researching this and trying to correct this issue.  Also, note I am using a Leonardo.  As you will notice, I am very new to this, so bear with me...
Regards
Code: [Select]

/*Based largely on code by  Jim Lindblom

Get pressure and temperature from the BMP085.
Serial.print it out at 9600 baud to serial monitor.
*/

#include <Wire.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;

// include the library code:
#include <LiquidCrystal.h>

// initialize the library with the numbers of the interface pins
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);
int backlight=13;

void setup(){
  pinMode(backlight, OUTPUT);
  analogWrite(backlight, 25); 
  // set up the LCD's number of columns and rows:
  lcd.begin(20, 4);
  Serial.begin(9600);
    while(!Serial);
  Wire.begin();

  bmp085Calibration();
}

void loop()
{
  float temperature = (((bmp085GetTemperature(bmp085ReadUT())*9) / 5) +32); //MUST be called first
  float pressure = ((bmp085GetPressure(bmp085ReadUP())) / 3386.38816);

  lcd.print("Temperature: ");
  lcd.print(temperature, 2); //display 2 decimal places
  lcd.println("deg F");

  lcd.print("Pressure: ");
  lcd.print(pressure, 2); //whole number only.
  lcd.println(" in Hg");

  lcd.println();//line break

  delay(1000); //wait a second and get values again.
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature in deg C
float bmp085GetTemperature(unsigned int ut){
  long x1, x2;

  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  float temp = ((b5 + 8)>>4);
  temp = temp /10;

  return temp;
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up){
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;

  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;

  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;

  long temp = p;
  return temp;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;

  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();

  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT(){
  unsigned int ut;

  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();

  // Wait at least 4.5ms
  delay(5);

  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP(){

  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;

  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();

  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));

  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  msb = bmp085Read(0xF6);
  lsb = bmp085Read(0xF7);
  xlsb = bmp085Read(0xF8);

  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

  return up;
}

void writeRegister(int deviceAddress, byte address, byte val) {
  Wire.beginTransmission(deviceAddress); // start transmission to device
  Wire.write(address);       // send register address
  Wire.write(val);         // send value to write
  Wire.endTransmission();     // end transmission
}

int readRegister(int deviceAddress, byte address){

  int v;
  Wire.beginTransmission(deviceAddress);
  Wire.write(address); // register to read
  Wire.endTransmission();

  Wire.requestFrom(deviceAddress, 1); // read a byte

  while(!Wire.available()) {
    // waiting
  }

  v = Wire.read();
  return v;
}



redz06vette

#1
Mar 13, 2014, 02:04 am Last Edit: Mar 13, 2014, 02:11 am by redz06vette Reason: 1
Just to clarify, when code is placed within the setup function, the text diplays on the LCD just fine.  It is only when 'lcp.print' is used within the loop that I get bad data displayed.  
Very important to note, data displayed on the serial monitor is absolutely perfect, even with the code residing within the loop function.  Again, I am truly appreciative of any help with this issue!

floresta

Start by getting rid of all of your lcd.println() statements.

Don

redz06vette

Thank you Don for your quick response.  I have tried to remove everything within the loop except for:
Code: [Select]
lcd.print("Temperature: ");
delay(2000);

At this point, nothing is populating the LCD.  Any ideas??

redz06vette

This also may help with determining the root cause.  I have been using a simple example program and have noticed that I get bizzare characters/symbols on the LCD until I remove the Wire.begin().  At that point, I get clear text. Here is the example that I used:
Code: [Select]
#include <LiquidCrystal.h>
#include <Wire.h>

LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

void setup() {
  lcd.begin(20, 4);
Wire.begin();
}
void loop() {
lcd.print("HELP");
  delay(1000);
}


redz06vette

GOT IT!!!!!!!!!! XD

I moved my LCD pins from '5, 4, 3, 2' to '7, 6, 5, 4' and it works!  I did read somewhere that the Leonardo's SCL and SDA pins are hardwired/tied to pins 2 & 3.  Perhaps this had something to do with it (as I am communicating with a BMP085, barometer/temp sensor).  Please comment as necessary.  I am hoping that moving my pins to these locations will not interfere with projects in the future.  Again, thank you for your help and time!

Go Up