I thought ping sensors used 1 pin for input and output, I only see input here.
(btw, use the Code key (#) above, when you're posting code, makes it much easier to read:))
The code looks okay for the most part, haven't used the 4bitLCD, usually use liquid crystal, but something I'm curious about
// PRINT USING INCHES
lcd.printIn(itoa(val, buf, 10));
lcd.printIn(" in / ");
// PRINT USING CENTIMETERS
lcd.printIn(itoa(val * 2.54, buf, 10));
lcd.printIn(" cm");
Not sure if the first one is really inches, but if so.. you're saying that a CM is equal to 2.54 times the size of an inch. (Maybe your comments are backwards?:X)
But you never stated WHAT your problems are...
are you receiving some data, but it doesn't make sense?
are you not receiving any data?
which ping sensor is it? Some have 2 pins for the input and output, but others just use one. Both can work with the Arduino, but have to adjust your code.. and the code you're using suggests, uhh.. that your ping sensor is working all the time.
Take a look at the ping example with the IDE. You first need to put the output pin HIGH, then read the input. I'm not seeing where you put the sensor high for the reading. Your code would *probably* work with some analog sensor, such as an LDR, potentiometer, sharp sensor.. etc.
/* Ping))) Sensor
This sketch reads a PING))) ultrasonic rangefinder and returns the
distance to the closest object in range. To do this, it sends a pulse
to the sensor to initiate a reading, then listens for a pulse
to return. The length of the returning pulse is proportional to
the distance of the object from the sensor.
The circuit:
* +V connection of the PING))) attached to +5V
* GND connection of the PING))) attached to ground
* SIG connection of the PING))) attached to digital pin 7
http://www.arduino.cc/en/Tutorial/Ping
created 3 Nov 2008
by David A. Mellis
modified 30 Jun 2009
by Tom Igoe
*/
// this constant won't change. It's the pin number
// of the sensor's output:
const int pingPin = 7;
void setup() {
// initialize serial communication:
Serial.begin(9600);
}
void loop()
{
// establish variables for duration of the ping,
// and the distance result in inches and centimeters:
long duration, inches, cm;
// The PING))) is triggered by a HIGH pulse of 2 or more microseconds.
// Give a short LOW pulse beforehand to ensure a clean HIGH pulse:
pinMode(pingPin, OUTPUT);
digitalWrite(pingPin, LOW);
delayMicroseconds(2);
digitalWrite(pingPin, HIGH);
delayMicroseconds(5);
digitalWrite(pingPin, LOW);
// The same pin is used to read the signal from the PING))): a HIGH
// pulse whose duration is the time (in microseconds) from the sending
// of the ping to the reception of its echo off of an object.
pinMode(pingPin, INPUT);
duration = pulseIn(pingPin, HIGH);
// convert the time into a distance
inches = microsecondsToInches(duration);
cm = microsecondsToCentimeters(duration);
Serial.print(inches);
Serial.print("in, ");
Serial.print(cm);
Serial.print("cm");
Serial.println();
delay(100);
}
long microsecondsToInches(long microseconds)
{
// According to Parallax's datasheet for the PING))), there are
// 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
// second). This gives the distance travelled by the ping, outbound
// and return, so we divide by 2 to get the distance of the obstacle.
// See: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
return microseconds / 74 / 2;
}
long microsecondsToCentimeters(long microseconds)
{
// The speed of sound is 340 m/s or 29 microseconds per centimeter.
// The ping travels out and back, so to find the distance of the
// object we take half of the distance travelled.
return microseconds / 29 / 2;
}
Notice how the code puts the pin to an OUTPUT first, then pings, then puts it back into an INPUT.
