Go Down

Topic: Grafiek op Nextion HMI (Read 299 times) previous topic - next topic

jmnijsse

Ben bezig met een project om aquarium waterwaardes weer te geven op een Nextion display.
Het realtime uitlezen is inmiddels werkend. Mede met dank aan dit forum!

Nu wil ik verder met het weergeven van grafieken van deze waarden (o.a. temp, pH, geleidbaarheid), die ook de historie laat zien en liefst ook nog ergens opslaat.
De standaard grafiek-module in Nextion begint echter elke keer met een leeg assenstelsel.

Wat ik dus zou willen is dat de data ergens (kan dat in Arduino zelf? moet dat op een SD-kaartje?) weggeschreven wordt en op het moment dat ik op de grafiek-knop klik, moeten de waardes weergegeven worden die opgeslagen zijn.

Nu heb ik van Nextion nog niet alles door.

De volgende vragen:

  • Is het mogelijk om zonder een SD kaart waardes op te slaan in het geheugen van arduino (UNO) zelf?
  • Zo ja, kun je daar PROGMEM voor gebruiken? En hoeveel ruimte heb je daarvoor op een UNO? Ik zie namelijk Flash Memory, SRAM en EEPROM staan in de specs.
  • In Nextion moet een deel van het mooie display niet zozeer geprogrammeerd worden, dan wel als plaatje geupload. Betekent dat dat een mooie grafiek alleen mogelijk is als ik alleen de 'lijn' weergeef en heel het raster met assenstelsels als plaatje daarachter moet plakken? Heeft iemand daar ervaring mee?


Wie kan me een duw in de goede richting geven?

Vriendelijke groet,
Johan

MAS3

Hoi jmnijsse.

Bij jouw verhaal moest ik meteen denken aan een data logger shield.
Daar zijn er heel veel van, ook voor een schijntje uit China.
Die hebben allemaal een SD card slot (kunnen wel voor verschillende fysieke afmetingen bedoeld zijn), een Real Time Clock chip, plus een batterij al dan niet in een houder die er voor zorgt dat de klok ook blijft door "tikken" als het geheel zonder spanning zit.
Soms zit er nog meer nuttigs op, zoals level shifters .

Het gebruiken van een SD kaartje geeft je een gigantische hoeveelheid opslag als je het vergelijkt met het beschikbare geheugen op welke Arduino variant dan ook.
Want geheugen is een achilleshiel voor de Arduino.
En bovendien is een kaart niet vluchtig geheugen, en vaker overschrijfbaar dan het geheugen van je Arduino.

Over de Nextion kan ik je helemaal niets vertellen, daar verwacht ik dat Nico wel bovenop zal springen..
Have a look at "blink without delay".
Did you connect the grounds ?
Je kunt hier ook in het Nederlands terecht: http://arduino.cc/forum/index.php/board,77.0.html

nicoverduin

Als je op een WaveForm in een keer een grafiek wil laten zien met recente data zul je die inderdaad moeten opslaan. Dat kan in een Array (als je voldoende geheugen hebt. MAAR....
Dan moet je ook pointers gaan bij houden om een soort ringbuffer te maken. Een die het begin aangeeft en een die het einde aangeeft. Immers je gaat een array vullen beginnend bij index 0 tot het einde van de tabel. Daarna ga je weer de eerste waarde overschrijven. Dus moet je bijhouden waar het begin en het einde van de reeks is in de tabel.

Op het moment dat je de grafiek (waveform) wil laten zien bouw je hem op en ga je de array uitlezen. Ook hier maak je weer gebruik van de pointers om de juiste volgorde te houden.

Op een SD kaart kan je hetzelfde geintje doen door een bestand te maken en elke  waarde weg te schrijven. Zou je dit volg-ordelijk doen dan blijft hij de data achteraan wegschrijven. Op enig moment is de SD kaart vol en dat lijkt mij niet wenselijk. Wat wel kan is tijdens de setup() een leeg bestand maken met x maal het aantal datapunten dat je wilt laten zien op de grafiek. De waarden kunnen dan gewoon 0 zijn. 

Met de seek() functie kan je overal midden in de SD file prikken en de variabele lezen. Maar ook schrijven (write() functie).

Er zijn wel wat voorbeelden uit het verleden te vinden die de seek() gebruiken om te lezen. Om te schrijven zag ik niet zoveel.

Je hebt dus nog al wat zaken uit te zoeken:
  • maak een array en kijk of je het ringbuffer idee erin geimplementeerd krijg
  • schrijf de array naar het nextion scherm
  • Als dat allemaal lukt bouw om naar SD kaart
  • Kijk of je daar ook kan schrijven en lezen gebruik makend van de write(), read() en seek() functies.
  • Lukt dat ga dan pas jouw programma aanpassen.


Het had mooi geweest als iemand een keer een mooie library had gemaakt (wie weet is die er al). Het zou betekenen dat je met arrays kan werken ter grootte van een SD kaart).... op een eenvoudige Arduino.   
Met vriendelijke groet / kindest regards
Nico Verduin
www.verelec.nl
Do not PM me for personal consultancy unless you are willing to pay for it.

jmnijsse

Bedankt voor de reacties. Ik dacht dat ik wel een melding zou krijgen dat er gereageerd was, maar niet dus...

Ik zat idd ook al aan een SD shield te denken, maar begreep niet hoe dat via Arduino aan een Nextion gekoppeld kon worden.

Nu heb ik dus dit om een temperatuurgrafiek te krijgen:

Code: [Select]

void get_temp()
{
 
  sensors.requestTemperatures();

  float t = sensors.getTempCByIndex(0);

  //convert to char
  char temperatureCTemp[6];
  dtostrf(t, 5, 1, temperatureCTemp);

  //update display
  tTempC.setText(temperatureCTemp);

  ch0_data = t;

  wGraph.addValue(0, ch0_data);

}


Maar i.p.v. die laatste regel moet niet slechts één ch0_data weggeschreven worden, maar dus een hele array.

Als ik je verhaal zo lees, Nico, zal dit niet eenvoudig worden voor een niet-heel-ervaren programmeur. Maar ik ben aan dit project begonnen om er iets nieuws van te leren dus ik ga eens in de wereld van pointers en ringbuffers duiken.

Dank voor de duw!

Gr.
johan



nicoverduin

Een plaatje maken vooraf helpt heel veel voor het oplossen van een probleem
Met vriendelijke groet / kindest regards
Nico Verduin
www.verelec.nl
Do not PM me for personal consultancy unless you are willing to pay for it.

nicoverduin

#5
Dec 06, 2018, 03:55 pm Last Edit: Dec 06, 2018, 04:11 pm by nicoverduin
Hier heb je ff een test programma met een ringbuffer.
Code: [Select]
/*
    Name:      SDArray.ino
    Created:   6-12-2018 08:41:43
    Author:     nico verduin
    Brief:        Eenvoudige manier om met een array  een ringbuffer te maken
*/

// programma constantes
const uint16_t ARRAY_SIZE = 10; // we gaan een array maken van 10 entries

// globale variabelen
uint16_t beginIndex   = 0;         // startpunt van de ring buffer
uint16_t eindIndex = 0;         // eindpunt van de ring buffer
double   array[ARRAY_SIZE]; // creer onze tabel

/*
 * @name addEntry
 * @param value double die aan de tabel wordt toegevoegd
 * @brief voegt een waarde toe aan de tabel. Als de tabel vol is, wordt de oudste waarde overschreden
 */
void addEntry(double value) {

// voeg de waarde toe op de laatste plek
array[eindIndex] = value;

// verhoog naar nieuwe laatste plek en loop around als we op het einde zitten
eindIndex++;
eindIndex = eindIndex % ARRAY_SIZE; // meest eenvoudige loop around
beginIndex++;
beginIndex = beginIndex % ARRAY_SIZE;
}

/*
* @name getEntry
* @param index index in de array waarvan we de waarde willen hebben
* @returns double
* @brief Geeft de waarde terug uit de tabel relatief tov de eerste waarde.
*/
double getEntry(uint16_t index) {

// reken de index om naar de juiste plek in de array
uint16_t berekendeIndex = beginIndex + index;

// modulo nemen en restwaarde gebruiken
berekendeIndex = berekendeIndex % ARRAY_SIZE;

// en geef de waarde maar terug
return array[berekendeIndex];;
}

/*
 * @name printArray
 * @brief  print de tabel uit
 */
void printArray() {

char floatAsString[6]; // buffer voor float conversie
for (uint16_t i = 0; i < ARRAY_SIZE; i++) {
dtostrf(getEntry(i), 5, 1, floatAsString);
Serial.print(floatAsString);
Serial.print(" ");
}
Serial.println();
}
/*
 * @name setup()
 * @brief Initializes the program
 */
void setup()
{
// initialiseer Serial
Serial.begin(115200);

// initialiseer onze tabel
for (uint16_t i = 0; i < ARRAY_SIZE; i++) {
array[i] = 0.0;
}

// vul onze tabel met wat random waarden
randomSeed(analogRead(0));
for (uint16_t i = 0; i < ARRAY_SIZE; i++) {
addEntry((double)random(0, 99) / 10.0);
}

// print de array
printArray();

// voeg nu 5 nieuwe waardes toe
for (uint16_t i = 0; i < 5; i++) {
addEntry((double)random(0, 99) / 10.0);

// en print de tabel elke keer opnieuw uit
printArray();
}

}

// Add the main program code into the continuous loop() function
void loop()
{


}
Met vriendelijke groet / kindest regards
Nico Verduin
www.verelec.nl
Do not PM me for personal consultancy unless you are willing to pay for it.

nicoverduin

Er zat nog een klein foutje in als de tabel nog niet helemaal is opgevuld. IS nu opgelost
Code: [Select]
/*
    Name:       SDArray.ino
    Created:    6-12-2018 08:41:43
    Author:     nico verduin
    Brief:      Eenvoudige manier om met een array  een ringbuffer te maken
*/

// programma constantes
const uint16_t ARRAY_SIZE = 15;        // we gaan een array maken van 10 entries

// globale variabelen
uint16_t beginIndex = 0;               // startpunt van de ring buffer
uint16_t eindIndex    = 0;             // eindpunt van de ring buffer
double   array[ARRAY_SIZE];            // creer onze tabel

/*
 * @name addEntry
 * @param value double die aan de tabel wordt toegevoegd
 * @brief voegt een waarde toe aan de tabel. Als de tabel vol is, wordt de oudste waarde overschreden
 */
void addEntry(double value) {
    static bool loopAround = false;                // nodig voor het afvangen als de tabel nog nooit is gevuld of deels

    // voeg de waarde toe op de laatste plek
    array[eindIndex] = value;

    // verhoog naar nieuwe laatste plek en loop around als we op het einde zitten
    eindIndex++;
    if (eindIndex == ARRAY_SIZE) {
        loopAround = true;                        // de tabel is vol
    }
    eindIndex = eindIndex % ARRAY_SIZE;           // meest eenvoudige loop around

    // pas doen als de tabel helemaal vol is
    if (loopAround) {
        beginIndex++;
        beginIndex = beginIndex % ARRAY_SIZE;
    }
}

/*
* @name getEntry
* @param index index in de array waarvan we de waarde willen hebben
* @returns double
* @brief Geeft de waarde terug uit de tabel relatief tov de eerste waarde.
*/
double getEntry(uint16_t index) {

    // reken de index om naar de juiste plek in de array
    uint16_t berekendeIndex = beginIndex + index;

    // modulo nemen en restwaarde gebruiken
    berekendeIndex = berekendeIndex % ARRAY_SIZE;

    // en geef de waarde maar terug
    return array[berekendeIndex];;
}

/*
 * @name printArray
 * @brief  print de tabel uit
 */
void printArray() {

    char floatAsString[6];        // buffer voor float conversie

    for (uint16_t i = 0; i < ARRAY_SIZE; i++) {
        dtostrf(getEntry(i), 5, 1, floatAsString);
        Serial.print(floatAsString);
        Serial.print(" ");
    }
    Serial.println();
}
/*
 * @name setup()
 * @brief Initializes the program
 */
void setup()
{
    // initialiseer Serial
    Serial.begin(115200);

    // initialiseer onze tabel
    for (uint16_t i = 0; i < ARRAY_SIZE; i++) {
        array[i] = 0.0;
    }

    // vul onze tabel met wat random waarden. Laat de laatste 3 waarden nog ff leeg
    randomSeed(analogRead(0));
    for (uint16_t i = 0; i < (ARRAY_SIZE - 3); i++) {
        addEntry((double)random(0, 99) / 10.0);
    }

    // print de array
    printArray();

    // voeg nu 5 nieuwe waardes toe
    for (uint16_t i = 0; i < 5; i++) {
        addEntry((double)random(0, 99) / 10.0);

        // en print de tabel elke keer opnieuw uit
        printArray();
    }
}

// Add the main program code into the continuous loop() function
void loop()
{
}


Met vriendelijke groet / kindest regards
Nico Verduin
www.verelec.nl
Do not PM me for personal consultancy unless you are willing to pay for it.

jmnijsse

Zo, bedankt Nico. Dit is wel helder, al moet ik het allemaal nog gaan toepassen in mijn eigen code. Komende weken, hopelijk.

Even voor m'n begrip:

Een ringbuffer is een buffer (soort array van sensorwaarden in mijn geval) die de eigenschap heeft dat als hij vol is, de oudste waarde weer overschreven wordt?

Wat is het voordeel om uint16_t te gebruiken? Terwijl er toch eigenlijk kleine getallen in staan? Waarom niet gewoon int?

Bedankt voor het meedenken. Moeilijk, maar wel interessant.

Goed weekend alvast!

J.

nicoverduin

#8
Dec 07, 2018, 04:13 pm Last Edit: Dec 07, 2018, 05:20 pm by nicoverduin
Een int is een signed integer en loopt van -32767 tot +32768. Dat alleen al is eigenlijk fout omdat je geen negatieve index kan hebben in een array.
uint16_t is hetzelfde als een int op de 8bit arduino. Op een 32bit machine is hij nog steeds 16bit. Terwijl een gewone int ineens 32bits is geworden. En als je speciale berekeningen doet oid is jouw uitgangspunt weg.
Met vriendelijke groet / kindest regards
Nico Verduin
www.verelec.nl
Do not PM me for personal consultancy unless you are willing to pay for it.

Jantje

>uint16_t is hetzelfde als een int op de 8bit arduino.

u in uint16_t staat voor unsigned en gaat dus van 0 to 65.535
Das dus niet hetzelfde als int op 8 bit processoren die gaan van -32767 tot +32768
Do not PM me a question unless you are prepared to pay for consultancy.
Nederlandse sectie - http://arduino.cc/forum/index.php/board,77.0.html -

nicoverduin

#10
Dec 07, 2018, 07:47 pm Last Edit: Dec 07, 2018, 07:49 pm by nicoverduin
Een int is een signed integer en loopt van -32767 tot +32768. Dat alleen al is eigenlijk fout omdat je geen negatieve index kan hebben in een array.
int16_t is hetzelfde als een int op de 8bit arduino. Op een 32bit machine is hij nog steeds 16bit. Terwijl een gewone int ineens 32bits (iets van +/- 2^31)is geworden. En als je speciale berekeningen doet oid is je uitgangspunt weg

Dank je Jan... zat ff te pitten
Met vriendelijke groet / kindest regards
Nico Verduin
www.verelec.nl
Do not PM me for personal consultancy unless you are willing to pay for it.

nicoverduin

Ik denk doe 's en schrijf een library om maar gelijk die arrays op een SD te laten werken. Inmiddels werkt het alleen nu nog alleen voor unsigned ints (4 bytes). Ik hem nog generaliseren voor elk type variabele en de code nog netter maken. Maar de resultaten zijn veelbelovend. Getest op een gewone UNO met een oud 256mb sd kaartje uit het jaar 0 :)

Code: [Select]
____________________________________________________________
     10 records to file      W10 created in      0.002 seconds
     10 records initialized in ............      0.005 seconds
     10 records read in ...................      0.002 seconds
      1 record random read in .............      0.000 seconds
____________________________________________________________
    100 records to file     W100 created in      0.003 seconds
    100 records initialized in ............      0.014 seconds
    100 records read in ...................      0.018 seconds
      1 record random read in .............      0.001 seconds
____________________________________________________________
   1000 records to file    W1000 created in      0.004 seconds
   1000 records initialized in ............      0.137 seconds
   1000 records read in ...................      0.198 seconds
      1 record random read in .............      0.003 seconds
____________________________________________________________
  10000 records to file   W10000 created in      0.005 seconds
  10000 records initialized in ............      1.367 seconds
  10000 records read in ...................      1.974 seconds
      1 record random read in .............      0.003 seconds
____________________________________________________________
 100000 records to file  W100000 created in      0.006 seconds
 100000 records initialized in ............     13.723 seconds
 100000 records read in ...................     19.734 seconds
      1 record random read in .............      0.005 seconds
____________________________________________________________
1000000 records to file W1000000 created in      0.010 seconds
1000000 records initialized in ............    136.413 seconds
1000000 records read in ...................    197.318 seconds
      1 record random read in .............      0.009 seconds




Met vriendelijke groet / kindest regards
Nico Verduin
www.verelec.nl
Do not PM me for personal consultancy unless you are willing to pay for it.

Go Up