Go Down

Topic: Ethernet Shield, Serveur sur WAN (Read 165 times) previous topic - next topic

Nepetalactones

Bonjour,

Je me suis lancé pour projet récemment de créer un serveur web avec une Arduino Uno et un shield Ethernet V2. Mon projet à pour but de contrôler 7 relais depuis n'importe ou dans le monde  8)

C'est bien beau, mais au final, j'ai repris du code sur internet, j'ai tout branché et.. bah non, ça fonctionne pas.

En gros, je peux accéder à mon serveur sur mon arduino depuis partout, pas de problème. Sauf que quand je clics sur un bouton afin d'activer un relais, après un petit délais d'attente, je me retrouve avec une page blanche ou il est inscrit "le délais d'attente est dépassé". De plus, je peux contrôler mes relais sans aucun problème depuis mon LAN. C'est quand je suis sur le WAN que je n'arrive pas à gérer ses fichus relais..  :smiley-sad: . Je tiens à préciser que pour mettre mon serveur sur le WAN, j'ai suivi les instructions du cours sur OpenClassRoom intitulé " Perfectionnez-vous dans la programmation Arduino > Pilotez votre Arduino sur le réseau mondial"

J'ai néanmoins utilisé le bout de code trouvé sur le net, car j'ai déjà crée dessus ma page HTML..


Pouvez vous m'expliquer pourquoi je me retrouve avec un délais d'attente dépassé quand j'utilise mon serveur sur le WAN ?

Merci d'avance pour votre aide  ;D

infobarquee

bonjour,
sans code, lien, etc... impossible d'aider.
AUCUNE AIDE PAR MP

B@tto

T'as fait les bonnes redirection de port sur ton routeur ?
Blog électronique : battomicro.wordpress.com
Photographie : www.interactive-celebration.fr
Fablab de Montpellier : www.labsud.org

Nepetalactones

Bonjour, merci de m'avoir répondu aussi rapidement !

T'as fait les bonnes redirection de port sur ton routeur ?
Oui, en port interne le port 80, en port externe 1580 :).

bonjour,
sans code, lien, etc... impossible d'aider.
Le code est plutôt conséquent, voici la première partie.

Code: [Select]
// -------- Que fait ce programme ? ---------
 /* Commande 7 relais sur une carte Arduino
couplée à un module Ethernet
configurée en serveur HTTP
à partir d'un navigateur client sur le PC

La connexion série est utilisée sur le PC connecté au serveur
pour visualiser le protocole HTTP utilisé
et les échanges Serveur/client

Les chaines de caractères constantes
sont stockées en mémoire flash programme
en raison du grand nombre de chaines utilisées

Programme très didactique pour comprendre
ce qui se passe entre le serveur et le client

 */

// --- Fonctionnalités utilisées ---

// Utilise la connexion série vers le PC
// Utilise le module Ethernet Arduino
// en mode serveur HTTP

// utilise la librairie Flash de stockage en mémoire programme FLASH

// -------- Circuit à réaliser ---------

// La connexion série vers le PC utilise les broches 0 et 1 (via le câble USB)

// Le module Ethernet est à enficher broche à broche sur la carte Arduino

//****************** Entête déclarative ****************
// A ce niveau sont déclarées les librairies incluses, les constantes, les variables...

// --- Déclaration des constantes ---

// --- Inclusion des librairies ---

//-- librairies utilisées pour le module Ethernet
#include <SPI.h>
#include <Ethernet.h>
#include <Server.h>
#include <Client.h>

// librairie pour stockage en mémoire flash programme
#include <Flash.h>
// attention : l'utilisation de F("chaine") necessite modification
// du fichier print.h
// voir : www.mon-club-elec.fr/pmwiki_reference_arduino/pmwiki.php?n=Main.LibrairieFlashProgramme


// --- Déclaration des constantes des broches E/S numériques ---

const int LED[7]={2,3,5,6,7,8,9}; // Constante pour les broches
//--- la broche 4 est utilisée par le module ethernet

bool ETAT1, ETAT2, ETAT3, ETAT4, ETAT5, ETAT6, ETAT7 = LOW;
// --- Déclaration des constantes des broches analogiques ---

int cho;

// --- Déclaration des variables globales ---

//--- déclaration du tableau d'adresse MAC ---
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED }; // valeur arbitraire

//---- tableau de l'adresse IP de la carte Arduino
byte ip[] = { 192,168,1,30 }; // le PC a pour IP : 192.168.1.30

//----- tableau de l'adresse de la passerelle ---
byte passerelle[] = { 192, 168, 1, 1 }; // l'adresse du PC de connexion ou de la Box

//----- tableau du masque de sous réseau
byte masque[] = { 255, 255, 255, 0 }; // idem masque sous-réseau du PC : 255.255.255.0

// variables globales utiles
String chaineRecue=""; // déclare un string vide global
int comptChar=0; // variable de comptage des caractères reçus

//------ tableau de String ----
// variables globales de mémorisation de l'état d'une case à cocher "" ou "checked"
String etatCase[7]={ "","","","","","",""};

// --- Déclaration des objets utiles pour les fonctionnalités utilisées ---

//--- création de l'objet serveur ----
EthernetServer serveurHTTP(80); // crée un objet serveur utilisant le port 80 = port HTTP


//**************** FONCTION SETUP = Code d'initialisation *****
// La fonction setup() est exécutée en premier et 1 seule fois, au démarrage du programme

void setup()   { // debut de la fonction setup()

// --- ici instructions à exécuter 1 seule fois au démarrage du programme ---

// ------- Initialisation fonctionnalités utilisées ------- 

Serial.begin(9600); // initialise connexion série à 115200 bauds
// IMPORTANT : régler le terminal côté PC avec la même valeur de transmission

//---- initialise la connexion Ethernet avec l'adresse MAC, l'adresse IP et le masque
Ethernet.begin(mac, ip, passerelle, masque);

//---- initialise le serveur HTTP----
serveurHTTP.begin(); //---- initialise le serveur HTTP


// ------- Broches en sorties numériques ------- 
for (int i=0; i<=6; i++) {
   pinMode (LED[i],OUTPUT); // Broche LED configurée en sortie
}

// ------- Broches en entrées numériques ------- 

// ------- Activation si besoin du rappel au + (pullup) des broches en entrées numériques ------- 

} // fin de la fonction setup()
// ********************************************************************************

//*************** FONCTION LOOP = Boucle sans fin = coeur du programme *************
// la fonction loop() s'exécute sans fin en boucle aussi longtemps que l'Arduino est sous tension

void loop(){ // debut de la fonction loop()


// --- ici instructions à exécuter par le programme principal ---

 

//---- Code type pour une connexion d'un client au serveur ---

// crée un objet client basé sur le client connecté au serveur HTTP
 
  //while(!serveurHTTP.available()); // attend qu'un client soit disponible

  // si un client est disponible, création de l'objet client correspondant
  EthernetClient client = serveurHTTP.available();

  if (client) { // si l'objet client n'est pas vide = si le client existe


    //-- initialisation des variables utilisées pour l'échange serveur/client
    chaineRecue=""; // vide le String de reception
    comptChar=0; // compteur de caractères en réception à 0 

    if (client.connected()) { // si le client est connecté



//////////////// Reception de la requete envoyée par le client //////////////////


      while (client.available()) { // tant que des octets sont disponibles en lecture

                char c = client.read(); // lit l'octet suivant reçu du client (pour vider le buffer au fur à mesure !)
                comptChar=comptChar+1; // incrémente le compteur de caractère reçus

                //--- on ne mémorise que les n premiers caractères de la requete reçue
                //--- afin de ne pas surcharger la RAM et car cela suffit pour l'analyse de la requete
                if (comptChar<=100) chaineRecue=chaineRecue+c; // ajoute le caractère reçu au String pour les N premiers caractères

      } // --- fin while client.available





Nepetalactones

.. et voici la seconde partie.

Code: [Select]
/////////////////// Analyse de la requete reçue //////////////////////

 


    // variables pour analyse de la requete reçue
    String chaineAnalyse=""; // crée un string utilisé pour analyser la requete
    int indexChaine=0; // variable index pour parcourir la chaine reçue

    //----- longeur de la chaine recue
    int longeurChaine=chaineRecue.length(); // variable de la longeur de la chaine reçue

    //------ type de la requete reçue --------
    if (chaineRecue.startsWith("GET")) { // si la chaine recue commence par "GET"
    }

    //------------- analyse si présence données formulaire ---------

    //-- analyse la présence du ? => présent si appui sur bouton envoi coté client
    indexChaine=5; // analyse le 6ème caractère
    chaineAnalyse=chaineRecue.substring(indexChaine,indexChaine+1); // extrait le 6ème caractère

    if (chaineAnalyse == "?") { // test si le 6ème caractère est un ?



      // *****************  analyse des données de formulaires disponibles ************
      // ---- l'analyse des éléments de formulaire reçus se base sur le formulaire HTML envoyé au client ci-dessous      


      // ------------- recherche du champ de case à cocher nommé case=----------------
      // le plus simple est de chercher la chaine "caseLED=ON" sans tenir compte de l'index
      // car cette chaine est fixe si le case est cochée

  for (int i=0; i<=6; i++) { // analyse pour les 6 LEDs

      chaineAnalyse="L"+String(i+1)+"=ON";

      //Serial.println(chaineRecue.indexOf(chaineAnalyse)); // affiche l'index de la chaine recherchée - debug

      if (chaineRecue.indexOf(chaineAnalyse)!=-1){ // si la chaine recherchee a été trouvée

        etatCase[i]="checked"; // mémorise valeur HTML de la case cochée

        digitalWrite(LED[i],LOW); // allume la LED

      } // fin if chaineRecue.indexOf

      else { // debut else chaineRecue.indexOf

        etatCase[i] =""; // mémorise valeur HTML bouton non coché

        digitalWrite(LED[i],HIGH); // eteint la LED

      } // fin else  chaineRecue.indexOf

  } // fin for i


    } // fin if Chaineanalyse==?

    else { // debut chaineAnalyse == "?"


    } // fin else chaineAnalyse == "?"



//////////// ENVOI DE LA REPONSE DU SERVEUR ///////////////




        // envoi d'une entete standard de réponse http
          client.println(F("HTTP/1.1 200 OK"));
          client.println(F("Content-Type: text/html"));
          client.println(F("Connection: close")); // indique au client que la connexion est fermée après réponse
          // à noter que la connexion est persistante par défaut coté client en l'absence de cette ligne          
          client.println(); // ligne blanche obligatoire après l'entete HTTP envoyée par le serveur


        // envoi du code HTML de la page

             //---- debut de la page HTML ---
             client.println(F("<html>"));

             // ---- Entete de la page HTML ----
             client.println(F("<head>"));

               //client.println("<meta content=\"text/html; charset=ISO-8859-1\" http-equiv=\"Content-Type\">");
               client.println(F("<title>Serveur Arduino</title>"));

               // balise meta pour réactualisation automatique de la page Web toutes les n secondes
               // client.println("<META HTTP-EQUIV=\"Refresh\" CONTENT=\"60\">");

             client.println(F("</head>"));

             //----- Corps de la page HTML ---
             // body avec fond coloré
             client.println(F("<body style=\"color: rgb(200, 200, 200); background-color: rgb(0, 0, 0); font-size: x-large\">"));

             client.println(F("<br>"));

             client.println(F("<center>")); // pour centrer la page HTML
             client.println(F("~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ <br> "));
             client.println(F(" Serveur Arduino <br>"));
             client.println(F(" Nicolas Lefebvre <br>"));
             client.println(F("~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ <br>"));
             client.println(F("<br>"));

             // intègre une image - suppose connexion internet disponible
             //client.println("<CENTER> <img src=\"http://www.arduino.cc/mes_images/clipart/logo_arduino_150.gif\"> </CENTER>");
             client.println(F("<CENTER> <img src=\"http://logo-all.ru/uploads/posts/2016-04/thumbs/0_arduino_logo-thumb.jpg\"> </CENTER>"));

             client.println(F("<br>"));


      for (int i=0; i<=6; i++) { // pour les 6 LEDs    

             if (etatCase[i]=="checked") client.print(F("Relais ")), client.print(i+1), client.println(F(" actif <br>"));
             if (etatCase[i]=="")client.print(F("Relais ")), client.print(i+1), client.println(F(" inactif <br>"));  

      } // fin for i

             //------------- génération du formulaire ----------------

             client.println(F("<FORM method=\"get\" action=\"http://192.168.1.30/\">")); // debut du formulaire - utilise méthode Get
             client.println(F("<P>")); // balise paragraphe

             // intégration d'un champ texte invisible pour obtenir un ? à l'appui sur le bouton submit
             client.println(F("<INPUT type=\"text\" style=\"display:none\" name=\"vide\" value=\"\" <br>"));


        for (int i=0; i<=6; i++) { // pour les 6 LEDs    

             client.print(F("<INPUT type=\"checkbox\" name=\"L")),client.print(i+1), client.print(F("\" value=\"ON\" "));
             client.print(etatCase[i]); // pour utiliser valeur courante de l'etat du bouton (mémorise valeur précédente)
             // etatCase vaut "" ou "checked"
             client.print(F("> Active/Desactive le relais ")),client.print(i+1), client.println(F(" . <BR>"));

        } // fin boucle for i


             client.println(F("<INPUT type=\"submit\" value=\"envoi\"> "));
             client.println(F("</P>"));// balise fin paragraphe  
             client.println(F("<br>"));

             client.println(F("</center>"));

             client.println(F("</FORM>"));// ne pas oublier ++


             client.println(F("<br>"));


             client.println(F("</body>"));

             //---- fin de la page HTML
             client.println(F("</html>"));





    } // --- fin if client connected

    delay(1);
    // on donne au navigateur le temps de recevoir les données

    // fermeture de la connexion avec le client après envoi réponse
    client.stop();


  } //---- fin if client existe ----



} // fin de la fonction loop() - le programme recommence au début de la fonction loop sans fin
// ********************************************************************************


désolé pour le double post  :smiley-sad-blue:

Nepetalactones

#5
Feb 04, 2017, 11:05 am Last Edit: Feb 04, 2017, 11:17 am by Nepetalactones
J'ai trouvé mon erreur :).

A la ligne 343, j'avais mis mon adresse de serveur local. Mon adresse LAN pour le WAN.. la bonne blague !  :-[

Code: [Select]
client.println(F("<FORM method=\"get\" action=\"http://IPdeMaBox:Port\">")); // debut du formulaire - utilise méthode Get

J'ai à la place mis l'adresse IP de ma box et le port qui m'intéresse pour communiquer avec mon serveur..

Bonne continuation !

Go Up
 


Please enter a valid email to subscribe

Confirm your email address

We need to confirm your email address.
To complete the subscription, please click the link in the email we just sent you.

Thank you for subscribing!

Arduino
via Egeo 16
Torino, 10131
Italy