Go Down

Topic: Arduino DS1307 and LCD questions (Read 813 times) previous topic - next topic

Sajuuk

Hello,

I made myself an DS1307 RTC module, following the SparkFun schematics. This is where the "fun" begins...
I assembled the module and it's working but it acts in a strange way: if it's plugged in to the 5V pin and GND it shows the date/time correctly. But if i disconnect the pin from either GND or 5V it shows something like: 00:00:01 1/1/1999 ... or 1970 sometimes...
If I connect the module back to the GND or 5V pin and restart the arduino(via onboard reset button) it shows the date/time correctly again.

A second problem I have is: how do I read the date/time so I can print it on LCD... !? I am using the TIME library available on the Arduino.cc site.

Thank you.

Jack Christensen

Make sure the backup battery is good, correctly in place, and making good contact.
MCP79411/12 RTC ... "One Million Ohms" ATtiny kit ... available at http://www.tindie.com/stores/JChristensen/

PaulS

Code: [Select]
But if i disconnect the pin from either GND or 5V it shows something like: 00:00:01 1/1/1999 ... or 1970 sometimes...
Your DS1307 displays the time? Most don't.

What is "it" that really displays the time?

Quote
how do I read the date/time so I can print it on LCD

If you don't know how to read the date and time, how can you says that it (whatever it is) behaves strangely when you unplug it?

Quote
I am using the TIME library available on the Arduino.cc site.

To read from the RTC? I don't think so.

pe1br

to print the time and date on A lcd display I use:

Code: [Select]

// Date and time functions using a DS1307 RTC connected via I2C and Wire lib

#include <Wire.h>
#include "RTClib.h"
#include <LiquidCrystal.h>


RTC_DS1307 RTC;

LiquidCrystal lcd(2, 3, 4, 5, 6, 7);

void setup () {
   Serial.begin(57600);
   Wire.begin();
   RTC.begin();

 if (! RTC.isrunning()) {
   Serial.println("RTC is NOT running!");
   // following line sets the RTC to the date & time this sketch was compiled
  RTC.adjust(DateTime(__DATE__, __TIME__));
 }

}

void loop () {
   DateTime now = RTC.now();
   lcd.begin(16, 2);
   lcd.setCursor(8, 0);
   
   Serial.print(now.year(), DEC);
   Serial.print('/');
   Serial.print(now.month(), DEC);
   Serial.print('/');
   Serial.print(now.day(), DEC);
   Serial.print(' ');
   Serial.print(now.hour(), DEC);
   Serial.print(':');
   Serial.print(now.minute(), DEC);
   Serial.print(':');
   Serial.print(now.second(), DEC);
   Serial.println();
   
   lcd.print(now.year(), DEC);
   lcd.print('/');
   lcd.print(now.month(), DEC);
   lcd.print('/');
   lcd.print(now.day(), DEC);
   lcd.print(' ');
   lcd.setCursor(0, 1);
   lcd.print(now.hour(), DEC);
   lcd.print(':');
   lcd.print(now.minute(), DEC);
   lcd.print(':');
   lcd.print(now.second(), DEC);
   lcd.println();
   
   Serial.println();
   delay(1000);
}

cyberteque

The example I still use to test and set the date/time is this -

Code: [Select]
/*
* RTC Control v.01
* by <http://www.combustory.com> John Vaughters
* Credit to:
* Maurice Ribble - http://www.glacialwanderer.com/hobbyrobotics for RTC DS1307 code
*
* With this code you can set the date/time, retreive the date/time and use the extra memory of an RTC DS1307 chip. 
* The program also sets all the extra memory space to 0xff.
* Serial Communication method with the Arduino that utilizes a leading CHAR for each command described below.
* Commands:
* T(00-59)(00-59)(00-23)(1-7)(01-31)(01-12)(00-99) - T(sec)(min)(hour)(dayOfWeek)(dayOfMonth)(month)(year) - T Sets the date of the RTC DS1307 Chip.
* Example to set the time for 02-Feb-09 @ 19:57:11 for the 3 day of the week, use this command - T1157193020209
* Q(1-2) - (Q1) Memory initialization  (Q2) RTC - Memory Dump
*/

#include "Wire.h"
#define DS1307_I2C_ADDRESS 0x68  // This is the I2C address


// Global Variables

int command = 0;       // This is the command char, in ascii form, sent from the serial port     
int i;
long previousMillis = 0;        // will store last time Temp was updated
byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;
byte test;
 
// Convert normal decimal numbers to binary coded decimal
byte decToBcd(byte val)
{
  return ( (val/10*16) + (val%10) );
}

// Convert binary coded decimal to normal decimal numbers
byte bcdToDec(byte val)
{
  return ( (val/16*10) + (val%16) );
}

// 1) Sets the date and time on the ds1307
// 2) Starts the clock
// 3) Sets hour mode to 24 hour clock
// Assumes you're passing in valid numbers, Probably need to put in checks for valid numbers.

void setDateDs1307()               
{

   second = (byte) ((Serial.read() - 48) * 10 + (Serial.read() - 48)); // Use of (byte) type casting and ascii math to achieve result. 
   minute = (byte) ((Serial.read() - 48) *10 +  (Serial.read() - 48));
   hour  = (byte) ((Serial.read() - 48) *10 +  (Serial.read() - 48));
   dayOfWeek = (byte) (Serial.read() - 48);
   dayOfMonth = (byte) ((Serial.read() - 48) *10 +  (Serial.read() - 48));
   month = (byte) ((Serial.read() - 48) *10 +  (Serial.read() - 48));
   year= (byte) ((Serial.read() - 48) *10 +  (Serial.read() - 48));
   Wire.beginTransmission(DS1307_I2C_ADDRESS);
   Wire.send(0x00);
   Wire.send(decToBcd(second));    // 0 to bit 7 starts the clock
   Wire.send(decToBcd(minute));
   Wire.send(decToBcd(hour));      // If you want 12 hour am/pm you need to set
                                   // bit 6 (also need to change readDateDs1307)
   Wire.send(decToBcd(dayOfWeek));
   Wire.send(decToBcd(dayOfMonth));
   Wire.send(decToBcd(month));
   Wire.send(decToBcd(year));
   Wire.endTransmission();
}

// Gets the date and time from the ds1307 and prints result
void getDateDs1307()
{
  // Reset the register pointer
  Wire.beginTransmission(DS1307_I2C_ADDRESS);
  Wire.send(0x00);
  Wire.endTransmission();

  Wire.requestFrom(DS1307_I2C_ADDRESS, 7);

  // A few of these need masks because certain bits are control bits
  second     = bcdToDec(Wire.receive() & 0x7f);
  minute     = bcdToDec(Wire.receive());
  hour       = bcdToDec(Wire.receive() & 0x3f);  // Need to change this if 12 hour am/pm
  dayOfWeek  = bcdToDec(Wire.receive());
  dayOfMonth = bcdToDec(Wire.receive());
  month      = bcdToDec(Wire.receive());
  year       = bcdToDec(Wire.receive());
 
  Serial.print(hour, DEC);
  Serial.print(":");
  Serial.print(minute, DEC);
  Serial.print(":");
  Serial.print(second, DEC);
  Serial.print("  ");
  Serial.print(month, DEC);
  Serial.print("/");
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  Serial.print(year, DEC);

}


void setup() {
  Wire.begin();
  Serial.begin(57600);

}

void loop() {
     if (Serial.available()) {      // Look for char in serial que and process if found
      command = Serial.read();
      if (command == 84) {      //If command = "T" Set Date
       setDateDs1307();
       getDateDs1307();
       Serial.println(" ");
      }
      else if (command == 81) {      //If command = "Q" RTC1307 Memory Functions
        delay(100);     
        if (Serial.available()) {
         command = Serial.read();
         if (command == 49) {      //If command = "1" RTC1307 Initialize Memory - All Data will be set to 255 (0xff).  Therefore 255 or 0 will be an invalid value. 
          Wire.beginTransmission(DS1307_I2C_ADDRESS); // 255 will be the init value and 0 will be considered an error that occurs when the RTC is in Battery mode.
          Wire.send(0x08); // Set the register pointer to be just past the date/time registers.
         for (i = 1; i <= 27; i++) {
             Wire.send(0xff);
            delay(100);
         }   
         Wire.endTransmission();
         getDateDs1307();
         Serial.println(": RTC1307 Initialized Memory");
         }
         else if (command == 50) {      //If command = "2" RTC1307 Memory Dump
          getDateDs1307();
          Serial.println(": RTC 1307 Dump Begin");
          Wire.beginTransmission(DS1307_I2C_ADDRESS);
          Wire.send(0x00);
          Wire.endTransmission();
          Wire.requestFrom(DS1307_I2C_ADDRESS, 64);
          for (i = 1; i <= 64; i++) {
             test = Wire.receive();
             Serial.print(i);
             Serial.print(":");
             Serial.println(test, DEC);
          }
          Serial.println(" RTC1307 Dump end");
         }
        } 
       }
      Serial.print("Command: ");
      Serial.println(command);     // Echo command CHAR in ascii that was sent
      }
     
      command = 0;                 // reset command
      delay(100);
    }
//*****************************************************The End***********************


It works pretty well just to see if the module is working.
I've since moved on to the Time library, I'll post that code when I figure out how to!
The sketch is 8 separate tabs in the IDE these days.

One thing, if you use the RTClib I'm pretty sure you need a

#define DS1307_I2C_ADDRESS 0x68 

line somewhere.

Nick Gammon


But if i disconnect the pin from either GND or 5V it shows something like: 00:00:01 1/1/1999 ... or 1970 sometimes...


I don't quite understand your point. You disconnect the power, and it stops working. Don't you expect that?
Please post technical questions on the forum, not by personal message. Thanks!

More info:
http://www.gammon.com.au/electronics

pe1br


I don't quite understand your point. You disconnect the power, and it stops working. Don't you expect that?


You have to now what the ds1307 module does.
Its A real time clock with A battery that keeps time even if you unplug the circuit from the powersupply.

Nick Gammon


You have to now what the ds1307 module does.
Its A real time clock with A battery that keeps time even if you unplug the circuit from the powersupply.


I know what it does. I have a few of them here.


If I connect the module back to the GND or 5V pin and restart the arduino(via onboard reset button) it shows the date/time correctly again.


You said yourself it keeps the time if you unplug the power.

It doesn't claim to keep working (that is, inform you of the time) if you unplug the power. It claims to keep the time internally.

It's like my alarm clock. It has a battery. If the power goes off during the night it remembers the time. However the display is blank until the power comes back on.
Please post technical questions on the forum, not by personal message. Thanks!

More info:
http://www.gammon.com.au/electronics

cyberteque

From what you have said, I think your existing sketch will work, AFTER you define the I2C address.
Who knows where and what you are reading and writing now.

humour me, just try it...

Sajuuk

Thank you all for your replies. :)

I managed to get it working, it was a problem with the sketch I was using to set the time/date.
I used cyberteque's sketch and set the time/date.

I am currently using pe1br's sketch and I managed to get the time/date string from the RTC module and print it on an LCD.

Thanks again for your help. :)

Go Up