Pages: [1] 2   Go Down
Author Topic: Hue-controllable RGB LED lamp  (Read 17288 times)
0 Members and 1 Guest are viewing this topic.
Brixton, London, UK
Offline Offline
Newbie
*
Karma: 0
Posts: 26
Arduino rocks
View Profile
WWW
 Bigger Bigger  Smaller Smaller  Reset Reset

My first Arduino project!  smiley

I wanted an RGB LED whose colour I could control with just one potentiometer. To do this, I created this workflow:

Read potentiometer > take pot value as a Hue value in a HSB system1 > convert HSB values (with S=1 and B=1) into RGB values > Use arduino pins to PWM RGB output to my RGB LED

The hardest part was converting HSB into RGB - the equations that I worked on from wikipedia are an absolute nightmare to translate into code (at least for me at this stage). I was about to give up when I saw this link, full of ready-made colour conversion functions: http://www.easyrgb.com/math.php?MATH=M21#text21.

The hardware is sitting on a breadboard, with a bit of paper diffusing the LED lamp, so it's not too pretty-looking. Here's my code anyhow:

Code:
int potpin = 2;              // Switch connected to digital pin 2

int rpin = 9;
int gpin = 10;
int bpin = 11;
float h;
int h_int;
int r=0, g=0, b=0;

int val=0;

void h2rgb(float h, int &R, int &G, int &B);

void setup()                    // run once, when the sketch starts
{
  Serial.begin(9600);           // set up Serial library at 9600 bps
}


void loop()                     // run over and over again
{
  val=analogRead(potpin);    // Read the pin and display the value
  //Serial.println(val);
  h = ((float)val)/1024;
  h_int = (int) 360*h;
  h2rgb(h,r,g,b);
  Serial.print("Potentiometer value: ");
  Serial.print(val);
  Serial.print(" = Hue of ");
  Serial.print(h_int);
  Serial.print("degrees. In RGB this is: ");
  Serial.print(r);
  Serial.print(" ");
  Serial.print(g);
  Serial.print(" ");
  Serial.println(b);

  analogWrite(rpin, r);
  analogWrite(gpin, g);
  analogWrite(bpin, b);
}

void h2rgb(float H, int& R, int& G, int& B) {

  int var_i;
  float S=1, V=1, var_1, var_2, var_3, var_h, var_r, var_g, var_b;

  if ( S == 0 )                       //HSV values = 0 ÷ 1
  {
    R = V * 255;
    G = V * 255;
    B = V * 255;
  }
  else
  {
    var_h = H * 6;
    if ( var_h == 6 ) var_h = 0;      //H must be < 1
    var_i = int( var_h ) ;            //Or ... var_i = floor( var_h )
    var_1 = V * ( 1 - S );
    var_2 = V * ( 1 - S * ( var_h - var_i ) );
    var_3 = V * ( 1 - S * ( 1 - ( var_h - var_i ) ) );

    if      ( var_i == 0 ) {
      var_r = V     ;
      var_g = var_3 ;
      var_b = var_1 ;
    }
    else if ( var_i == 1 ) {
      var_r = var_2 ;
      var_g = V     ;
      var_b = var_1 ;
    }
    else if ( var_i == 2 ) {
      var_r = var_1 ;
      var_g = V     ;
      var_b = var_3 ;
    }
    else if ( var_i == 3 ) {
      var_r = var_1 ;
      var_g = var_2 ;
      var_b = V     ;
    }
    else if ( var_i == 4 ) {
      var_r = var_3 ;
      var_g = var_1 ;
      var_b = V     ;
    }
    else                   {
      var_r = V     ;
      var_g = var_1 ;
      var_b = var_2 ;
    }

    R = (1-var_r) * 255;                  //RGB results = 0 ÷ 255
    G = (1-var_g) * 255;
    B = (1-var_b) * 255;
  }
}
« Last Edit: April 04, 2008, 12:52:39 pm by akgraphics » Logged

Brixton, London, UK
Offline Offline
Newbie
*
Karma: 0
Posts: 26
Arduino rocks
View Profile
WWW
 Bigger Bigger  Smaller Smaller  Reset Reset

This evening I've also created another 2 functions for controlling an RGB LED. The first function holds an LED at a certain RGB value for a given time period, using PWM, nothing special there. The second function accepts 2 RGB values, then fades between them over a given time period, with a smooth gradient. One can now program a lighting sequence using the simple colour "holds" and "fades".

My problem with the fade code is that I could only seem to make it work when using floating point arithmetic. Attempting to mix up integer math made the PWM go all wrong. So the Arduino is performing a LOT more operations that it really should be doing. This does not affect the timing of the LED colour-changes (to my eyes at least) though I havn't done any rigorous sort of test on that:

Code:
//i/o pin declarations
int rpin = 9;
int gpin = 10;
int bpin = 11;

//function prototypes
void solid(int r, int g, int b, int t);
void fade(int r1, int g1, int b1, int r2, int g2, int b2, int t);

void setup()                
{
//empty
}

void loop()                    
{
  //colour sequence instructions
  
  //Example sequence one: Rainbow fade over 15 seconds:
  fade(255,0,0,0,255,0,5000); //fade from red to green over 5 seconds
  fade(0,255,0,0,0,255,5000); //fade from green to blue over 5 seconds
  fade(0,0,255,255,0,0,5000); //fade from blue to red over 5 seconds
}

//function holds RGB values for time t milliseconds
void solid(int r, int g, int b, int t)
{

  //map values - arduino is sinking current, not sourcing it
  r = map(r, 0, 255, 255, 0);
  g = map(g, 0, 255, 255, 0);
  b = map(b, 0, 255, 255, 0);

  //output
  analogWrite(rpin,r);
  analogWrite(gpin,g);
  analogWrite(bpin,b);
  
  //hold at this colour set for t ms
  delay(t);

}

//function fades between two RGB values over fade time period t
//maximum value of fade time = 30 seconds before gradient values
//get too small for floating point math to work? replace floats
//with doubles to remedy this?
void fade(int r1, int g1, int b1, int r2, int g2, int b2, int t)
{

  float r_float1, g_float1, b_float1;
  float r_float2, g_float2, b_float2;
  float grad_r, grad_g, grad_b;
  float output_r, output_g, output_b;
  
  //declare integer RGB values as float values
  r_float1 = (float) r1;
  g_float1 = (float) g1;
  b_float1 = (float) b1;
  r_float2 = (float) r2;
  g_float2 = (float) g2;
  b_float2 = (float) b2;
  
  //calculate rates of change of R, G, and B values
  grad_r = (r_float2-r_float1)/t;
  grad_g = (g_float2-g_float1)/t;
  grad_b = (b_float2-b_float1)/t;
  
  //loop round, incrementing time value "i"
  for ( float i=0; i<=t; i++ )
  {
    
    output_r = r_float1 + grad_r*i;
    output_g = g_float1 + grad_g*i;
    output_b = b_float1 + grad_b*i;
    
    //map values - arduino is sinking current, not sourcing it
    output_r = map (output_r,0,255,255,0);
    output_g = map (output_g,0,255,255,0);
    output_b = map (output_b,0,255,255,0);
    
    //output
    analogWrite(rpin, (int)output_r);
    analogWrite(gpin, (int)output_g);
    analogWrite(bpin, (int)output_b);
    
    //hold at this colour set for 1ms
    delay(1);
    
  }
}

« Last Edit: April 06, 2008, 05:43:35 pm by akgraphics » Logged

0
Offline Offline
Newbie
*
Karma: 0
Posts: 2
Arduino rocks
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Could this be done using more than one LED on the output?  Basically I was wondering if this could be scaled up with enough LEDs to add ambient lighting to an entire room.  Nothing too complex as in they could all change at once.  I am guessing you would need some sort of external power supply though as they would draw too much current for just the arduino board.
Logged

Bagshot, UK
Offline Offline
Full Member
***
Karma: 1
Posts: 114
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

akgraphics, could you explain this piece of code?

Code:
//map values - arduino is sinking current, not sourcing it
r = map(r, 0, 255, 255, 0);
g = map(g, 0, 255, 255, 0);
b = map(b, 0, 255, 255, 0);
I'm learning a lot of programming techniques at the moment and it appears you're reversing/inverting the output by mapping it? Is that just to do with how you have your LED's connected to the outputs?

Thanks in advance, Easty.

PS Sorry thebias I can't answer your question (yet) but I'm planning something similar by the sounds of it.
Logged

Paris FR
Offline Offline
Full Member
***
Karma: 0
Posts: 155
cute little geek...
View Profile
WWW
 Bigger Bigger  Smaller Smaller  Reset Reset

As you partially guessed, map() takes an amount and the range of values to which it belongs, and remaps it to another range of values. I think the documentation page on it is very clear :

http://www.arduino.cc/en/Reference/Map
Logged

... could use some sleep

Bagshot, UK
Offline Offline
Full Member
***
Karma: 1
Posts: 114
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Thanks Theboii, I had had a read of the reference material and seemed to understand it!

I was wondering why akgraphics had used it in his code as in my brief experiments with PWM'ing LEDs last night I didn't have to perform that change. I guess it's circuit specific though...

Cheers, Easty.
Logged

Paris FR
Offline Offline
Full Member
***
Karma: 0
Posts: 155
cute little geek...
View Profile
WWW
 Bigger Bigger  Smaller Smaller  Reset Reset

Ok, sorry ^^

Basically, you have to revert the value of an output pin when the pin is connected to the ground of the component. This is called "sinking" instead of "sourcing", which is when you output power to the component.

You often sink current from components instead of sourcing them because the µC can sink more than it can source, since sinking just basically means "connecting to GND"

So, if a component is connected on the gnd side on a pin, and on the cathode side on a power source, you just reverse the values you send : Putting the pin to 0 or LOW will sink 100% of the power (within the limit of the µC capabilities, of course.), putting it to HIGH or PWM255 will prevent electricity to circulate.

I hope I made myself clear... I'm not sure smiley-kitty
Logged

... could use some sleep

Bagshot, UK
Offline Offline
Full Member
***
Karma: 1
Posts: 114
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Understood 100%!

Interesting about the sink/source comparision... I think I'd better redesign my circuit!

Thanks, Easty.
Logged

0
Offline Offline
God Member
*****
Karma: 1
Posts: 513
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

It is a neat idea, only thing I would suggest is that I might not invite float to the party.

AnalogRead returns 10 bits (0-1023)
You might want to look at the individual bits and assign them to colors directly


say 1 bits for intensity, 3 bits per color

analog read returns 1023 = 1111111111 in binary
intensity,   R,   G,   B
1        , 111, 111, 111

multiply R, G, B by 18 and if intensity is set add 128 to each.  

Edit: while this isn't technically hue, it will give you access to more color combinations and intensities than hue alone would.
« Last Edit: June 16, 2008, 11:42:34 am by dcb » Logged

0
Offline Offline
God Member
*****
Karma: 1
Posts: 513
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Here is a non-float, hue only version also.  What is the application?  It sounds like it could be interesting.
Code:
void setup(){
  Serial.begin(9600);
}

void loop(){
//colors out of phase by 341  (1023/3)
  Serial.println("V,R,G,B");
  for(int v = 0; v < 1024; v++){ //analogRead surrogate
    Serial.print(v);
    Serial.print(",");
    Serial.print(colVal(v+341),DEC);    //red
    Serial.print(",");
    Serial.print(colVal(v),DEC);        //green
    Serial.print(",");
    Serial.println(colVal(v+682),DEC);  //blue
  }
  while(true);
}

//based on green hue function, add phase adjustment for red or blue value
byte colVal(int val){
  int v = val % 1024;
  if(v<=170)
    return (v * 3) / 2;
  if(v<=512)
    return 255;
  if(v<=682)
 return 255 - (((v%171) * 3) / 2);
  return 0;
}

Edit:  Just noticed the part about non-floats messing up the pwm functions, that doesn't sound right.
« Last Edit: June 16, 2008, 10:49:58 pm by dcb » Logged

0
Offline Offline
Newbie
*
Karma: 0
Posts: 1
Arduino rocks
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

akgraphics,

Nice job with that.  Wish I ran across this post earlier.  I actually ended up writing pretty much the same code for the fading, just without the map() and I'm using random values so that it fades from one random color to another.  It's amazing that you thought of pretty much the same exact algorithm.

I ended up adding the map() because my tri-color LED has a common Anode
Logged

0
Offline Offline
Newbie
*
Karma: 0
Posts: 2
Arduino rocks
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

Not sure if this is at all helpful for you too easty but my theory so far is to use a combo of the code you guys have put up here with 3 of these circuits http://www.arduino.cc/playground/uploads/Learning/multiple_leds2.jpg in order to drive the each of 3 colours for each LED.  To start with I would just like to get 3 RGB leds up and running.  I think this should work bearing in mind that I want them to all do the same thing at the same time. If anyone sees any gaping holes in my theory please point it out!

Cheers
Logged

0
Offline Offline
Newbie
*
Karma: 0
Posts: 18
Arduino rocks
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

I've got a question about the 'sinking' technique:
When the source is +5V, and the PWM pin is HIGH, no electricity will flow even if the +5V is capable of higher current than the pin, correct?

Also, how much current can an arduino pin safely sink?  I know the pins can source 40ma, but didnt see a value for sink.

Thanks, and very nice code!
Logged

Manchester (England England)
Offline Offline
Brattain Member
*****
Karma: 597
Posts: 33328
Solder is electric glue
View Profile
WWW
 Bigger Bigger  Smaller Smaller  Reset Reset

Quote
When the source is +5V, and the PWM pin is HIGH, no electricity will flow even if the +5V is capable of higher current than the pin, correct?

Yes if there is no voltage difference then there is no current flow.

Quote
Also, how much current can an arduino pin safely sink?  I know the pins can source 40ma, but didnt see a value for sink.


You can sink 60mA at 25C and get down to a voltage of 1.5v.

That means sinking current you will not get the full 5v across the load but 5 - 1.5 = 3.5v

Sinking 40mA gets you down to under 1V on the output where as 20mA gets the output voltage down to 0.5v
Logged

0
Offline Offline
Newbie
*
Karma: 0
Posts: 1
Arduino rocks
View Profile
 Bigger Bigger  Smaller Smaller  Reset Reset

akgraphics, just wanted to thank you. I have used some of your code in my own project to get a pot to control RGB values. Very useful! smiley
Logged

Pages: [1] 2   Go Up
Jump to: