Freeze during put request

heligone · May 4, 2018, 11:48am

Hi,

I am using mkrGSM1400 for a remote sensing project.

The board is using GPRS to send periodically data to my server.

I am sending data with a PUT request incorporating a simple JSON

It is working fine BUT : randomly, the data stops being sent. This occurs after a few tens to a few thousand request.

The console debug shows that the freeze occurs in the beginning or at the middle of the PUT request. (See attache picture)

Does anybody face the same problem ?

Note : I am using a soracom IOT simcard. This simcard connects to the best carrier available at a given point and time

sandeepmistry · May 4, 2018, 1:16pm

Hi @heligone,

Could you please share a sketch that can reproduce the issue?

Do you have a lipo battery connected to the board?

Marcussacapuces91 · May 4, 2018, 7:30pm

Hello everybody,

I'm working with Heligone and I just produce a example :

gist.github.com

https://gist.github.com/Marcussacapuces91/a8ec89a932eee359ac741e0ade9078ea

SimplePut.ino

/*
  Simple PUT client for ArduinoHttpClient library
  Connects to server once every five seconds, sends a PUT request
  and a request body

 

  created 14 Feb 2016
  by Tom Igoe

This file has been truncated. show original

arduino_secrets.h

#pragma once

#define PIN_CODE "0000"

#define APN_NAME "soracom.io"
#define APN_USERNAME "sora"
#define APN_PASSWORD "sora"

Of course we both use the 2000mA bat.

Thanks for any help

heligone · May 5, 2018, 12:33pm

thanks for your reply @sandeepmistry

For information, here is another sketch with a custom PUT Implementation, without using ArduinoHttpClient library, as was done in the code linked in the previous message from my friend @Marcussacapuces91.

It seems that this custom implementation of PUT is working better, nevertheless, it is still freezing after a random number of request...

NOTE : I am using a LIPO 18650 1S3P 7800mAh

/* adapted from  M. sibert May 2018 */

#  define DEBUG(x) do { Serial.print(x); } while(0)

#include <MKRGSM.h> 

#define PIN_CODE "0000"
#define APN_NAME "soracom.io"
#define APN_USERNAME "sora"
#define APN_PASSWORD "sora"

const String GPRS_APN(F(APN_NAME));
const String GPRS_LOGIN(F(APN_USERNAME));
const String GPRS_PASSWORD(F(APN_PASSWORD));


GSM gsm;
GPRS gprs;
GSMClient gprsClient;

bool put( String path,  String body)  {
    DEBUG("PUT "); DEBUG(path); DEBUG('\n');
    
    GSMClient client;
    String serverName = "httpbin.org";
    if (!client.connect(serverName.c_str(), 80)) {
      Serial.println(F("Erreur de connexion"));
      return false;
    }
    
    client.print(F("PUT "));   client.print(path);   client.println(F(" HTTP/1.0"));
    client.print(F("Host: ")); client.println(serverName.c_str());
    client.println(F("Content-Type: application/json"));
    client.print(F("Content-Length: ")); client.println(body.length());
    client.println(F("Connection: close"));
    client.println();

    String t = body;
    while(t.length() > 0) {
      const unsigned m = (t.length() >= 100 ? 100 : t.length());
      client.print(t.substring(0, m));
      t = t.substring(m);
    }

    String s;
    const unsigned long start = millis();
    while ((client.available() || client.connected()) && (millis() - start) < 30000) {
      if (client.available() > 0) {
        const int c = client.read();
        if (c != -1) s += char(c);
      }
    }
    Serial.println(s);
    return true;
  }

void setup() {
  Serial.begin(9600);
  MODEM.begin();

  if (GSM_READY != gsm.begin(PIN_CODE)) {
    Serial.println("No GSM conection!");
  }

  if (GPRS_READY != gprs.attachGPRS(GPRS_APN.c_str(), GPRS_LOGIN.c_str(), GPRS_PASSWORD.c_str())) {
    Serial.println("No GPRS connection!");
  }

}


void loop() {
  Serial.println("Making PUT request");

  const String Path = "/put";
  const String putData = "{ \"name\": \"light\", \"age\": 46 }";

  put(Path, putData);
  Serial.println("Wait five seconds");
  delay(5000);
}

viktor_laitinen · May 6, 2018, 5:18am

Hello,
I have some problems.
For me this is wrong in the design of MKRGSM1400.
at the moment, developers advise to connect the battery. But this does not help, the MKRGSM1400 stops working and needs to be restarted.
We can not find a solution, as in this case, stop the loop and restart the MKRGSM1400 automatically.
For Arduino UNO we use #include <avr / wdt.h>, unfortunately it does not work in MKRGSM1400.

dmonrabal · May 7, 2018, 9:29pm

Hello.

I have the same problems. The device works fine during a few days, but after that fails. I have beed testing different power options, like USB cable, with Vin and a Lipo battery of 2500 mAh connected all time, but the result is always the same. I have been thinking in log the events in a SD card to view more details... I hope the developers give us some indication to resolve that.

Thanks.

Riccardo_Rizzo · May 21, 2018, 8:49am

Hi to all, @heligone i have tested the sketch of @Marcussacapuces91, and and reproduced the issue, now i take some modifications like introducing a timeout and impose a client.close() and a client.flush() after the put request, the code that i use is the following:

/*
 Simple PUT client for ArduinoHttpClient library
 Connects to server once every five seconds, sends a PUT request
 and a request body

 created 14 Feb 2016
 by Tom Igoe

 update by M. Sibert May 2018

 this example is in the public domain
*/
#include <MKRGSM.h>
#include <ArduinoHttpClient.h>
#include "arduino_secrets.h"

const String serverName(("httpbin.org"));//F("httpbin.org"));
const unsigned serverPort = 80;
const String servicePath(("/put"));//F("/put"));

const String GPRS_APN((APN_NAME));//F(APN_NAME));
const String GPRS_LOGIN((APN_USERNAME));//F(APN_USERNAME));
const String GPRS_PASSWORD((APN_PASSWORD));//F(APN_PASSWORD));

unsigned long initTime = millis();

GSM gsm(true);
GPRS gprs;
GSMClient gprsClient;

HttpClient client = HttpClient(gprsClient, serverName, serverPort);

const String contentType = "application/json";
const String putData = "{ \"name\": \"light\", \"age\": 46 }";


void setup() {
 Serial.begin(9600);
 MODEM.begin();
 boolean connected = false;
 while (!connected) {
   if ((gsm.begin(PIN_CODE) == GSM_READY) &&
       (gprs.attachGPRS(GPRS_APN.c_str(), GPRS_LOGIN.c_str(), GPRS_PASSWORD.c_str()) == GPRS_READY)) {
     connected = true;
   } else {
     Serial.println("Not connected");
     delay(1000);
   }
 }
 Serial.println("Connected");
}
unsigned long int count = 0;
void loop() {

 Serial.println("Making PUT request");
 int ret = client.put(servicePath.c_str(), contentType, putData);
 if (ret < 0) {
   client.flush();
   client.stop();
   return;
 }
 unsigned long looptime = millis();
 while (client.available() <= 0 || millis() - looptime < 5000) {
 }

 // read the status code and body of the response
 const int statusCode = client.responseStatusCode();
 const String response = client.responseBody();
 if (statusCode != 200) {
   client.flush();
   client.stop();
 } else {
   Serial.print("Status code: ");
   Serial.println(statusCode);
   Serial.print("Response: ");
   Serial.println(response);
   Serial.print(count);
   count++;
 }
 Serial.print("battery charge: ");
 Serial.println(String(analogRead(ADC_BATTERY)));

 unsigned long start = millis();
 Serial.print("Time ");
 Serial.println((millis() - initTime) / 1000);
 while (client.connected())
 {

   Serial.println("Connected!!!");
   delay(100);
   if (millis() - start > 5000)
   {
     client.flush();
     client.stop();
   }
 }
}

In my test it run for 3 hours and put around 1000 of request, could you try and let me now if works?, while i proceed to test it more and more, another things could you share the log of the debug mode?

heligone · June 2, 2018, 8:51am

Thank you Riccardo_Rizzo :

We managed to find a workaround using tinyGSM libray.

We laso needed to manually implement a reconnection if the GPRS goes down in between 2 connections.

Your proposition using mkrgsm library looks good and I will test ASAP and let you know,

Best regards

Prof62 · June 3, 2018, 7:45am

This known issue may be relevant:

github.com/arduino-libraries/MKRGSM

MKR1400 hangs when running the GsmWebClient sketch

opened 08:09PM - 22 Apr 18 UTC

lathoub

My MKRGSM1400 hangs after a random amount of time (sometime after a couple of se…conds, sometimes after an hour). The Code (based on the `GsmWebClient` example, but then 'get' is put in a loop). The` Serial Monitor` provides a trace (see below) If I want to upload new code to the MKR1400, I need to reset it first using the little reset button to 'unhang' it. I'm using a MacBook Pro (15-inch, 2017) with High Sierra (10.13.4 (17E199)), Thunderbolt 3 to USB dongle. The MKR1400 has a charged 850mAh battery attached to it (I also tried a 2000mAh battery, same result). Used both Arduino IDE 1.8.5. and 1.9.0 Beta - same result, hangs at random places during the run. ``` #include <MKRGSM.h> #include "arduino_secrets.h" // Please enter your sensitive data in the Secret tab or arduino_secrets.h // PIN Number const char PINNUMBER[] = SECRET_PINNUMBER; // APN data const char GPRS_APN[] = SECRET_GPRS_APN; const char GPRS_LOGIN[] = SECRET_GPRS_LOGIN; const char GPRS_PASSWORD[] = SECRET_GPRS_PASSWORD; // initialize the library instance GSMClient client; GPRS gprs; GSM gsmAccess(true); // URL, path and port (for example: arduino.cc) char server[] = "arduino.cc"; char path[] = "/asciilogo.txt"; int port = 80; // port 80 is the default for HTTP void setup() { // initialize serial communications and wait for port to open: Serial.begin(9600); while (!Serial) {} Serial.println("Starting Arduino web client."); // connection state boolean connected = false; // After starting the modem with GSM.begin() // attach the shield to the GPRS network with the APN, login and password while (!connected) { if ((gsmAccess.begin(PINNUMBER) == GSM_READY) && (gprs.attachGPRS(GPRS_APN, GPRS_LOGIN, GPRS_PASSWORD) == GPRS_READY)) { connected = true; } else { Serial.println("Not connected"); delay(1000); } } } void loop() { Serial.println("connecting..."); // if you get a connection, report back via serial: if (client.connect(server, port)) { Serial.println("connected"); // Make a HTTP request: client.print("GET "); client.print(path); client.println(" HTTP/1.1"); client.print("Host: "); client.println(server); client.println("Connection: close"); client.println(); Serial.println("awaiting response"); while (true) { // if there are incoming bytes available // from the server, read them and print them: if (client.available()) char c = client.read(); // if the server's disconnected, stop the client: if (!client.available() && !client.connected()) { Serial.println(); Serial.println("disconnecting."); client.stop(); break; } } } else { // if you didn't get a connection to the server: Serial.println("connection failed"); } delay(5000); } ``` The content of the serial monitor: ``` 21:49:19.604 -> Starting Arduino web client. 21:49:23.393 -> ⸮AT 21:49:23.605 -> OK 21:49:23.605 -> AT+IPR=921600 21:49:23.605 -> OK 21:49:23.712 -> AT 21:49:23.712 -> OK 21:49:23.712 -> AT+UPSV=3 21:49:23.712 -> OK 21:49:23.817 -> AT+CPIN? ``` ... ``` 21:51:57.115 -> +UUSORD: 0,2 21:51:57.115 -> AT+USORD=0,1 21:51:57.115 -> +USORD: 0,1,"20" 21:51:57.115 -> 21:51:57.115 -> OK 21:51:57.115 -> 21:51:57.115 -> +UUSORD: 0,1 21:51:57.115 -> AT+USORD=0,1 21:51:57.115 -> +USORD: 0,1,"0A" 21:51:57.115 -> 21:51:57.115 -> OK 21:51:57.369 -> 21:51:57.369 -> +UUSOCL: 0 21:51:57.369 -> 21:51:57.369 -> disconnecting. 21:52:02.352 -> connecting... 21:52:02.463 -> AT+USOCR=6 21:52:02.463 -> +USOCR: 0 21:52:02.463 -> 21:52:02.463 -> OK 21:52:02.675 -> AT+USOCO=0,"arduino.cc",80 21:52:02.961 -> OK 21:52:02.961 -> connected 21:52:02.961 -> AT+USOWR=0,4,"47455420" 21:52:02.961 -> +USOWR: 0,4 21:52:02.961 -> 21:52:02.961 -> OK 21:52:02.961 -> AT+USOWR=0,14,"2F61736369696C6F676F2E747874" 21:52:02.961 -> +USOWR: 0,14 21:52:02.961 -> 21:52:02.961 -> OK 21:52:02.961 -> AT+USOWR=0,9,"20485454502F312E31" 21:52:02.997 -> +USOWR: 0,9 21:52:02.997 -> 21:52:02.997 -> OK 21:52:02.997 -> AT+USOWR=0,2,"0D0A" 21:52:02.997 -> +USOWR: 0,2 21:52:02.997 -> 21:52:02.997 -> OK 21:53:05.524 -> 21:53:05.524 -> +UUSOCL: 0 ``` A regular successful sequence would be: ``` connecting... AT+USOCR=6 +USOCR: 0 OK AT+USOCO=0,"arduino.cc",80 OK connected AT+USOWR=0,4,"47455420" +USOWR: 0,4 OK AT+USOWR=0,14,"2F61736369696C6F676F2E747874" +USOWR: 0,14 OK AT+USOWR=0,9,"20485454502F312E31" +USOWR: 0,9 OK AT+USOWR=0,2,"0D0A" +USOWR: 0,2 OK ``` **processing broke here and should normally continue with the messages below. Yet, +UUSOCL: 0 is the last message before the MKR1400 hangs** ``` AT+USOWR=0,6,"486F73743A20" +USOWR: 0,6 OK AT+USOWR=0,10,"61726475696E6F2E6363" +USOWR: 0,10 OK AT+USOWR=0,2,"0D0A" +USOWR: 0,2 OK AT+USOWR=0,17,"436F6E6E656374696F6E3A20636C6F7365" +USOWR: 0,17 OK AT+USOWR=0,2,"0D0A" +USOWR: 0,2 OK AT+USOWR=0,2,"0D0A" +UOWR: 0,2 OK awaiting response ```

Basically there is an issue that allows the MKRGSM library to get out of sync and lock up waiting dor a reply to a command.

heligone · August 22, 2018, 10:55am

Thank you all for advice.

Unfortunately, none of the solutions tried is working :

use of tinyGSM resulted in 5 freeze during a 2 mont test in a remote location
Riccardo_Rizzo : I have tried your code but it still freeze if I emulate a network glitch by removing and then putting pack the antenna (see attached pic)
I have tried code from SORACOM team
GitHub - alexissusset/soracom-mkrgsm1400: Soracom Air and Harvest services with Arduino MKR GSM 1400 project example
--> freeze after few iteration
I have tried code form francmunoz
GitHub - FrancMunoz/MKRGSM
who forked mkrgsm library to patch delay issue with SARA and programmed an asynchronous connection exemple. The board does not freeze anymore , BUT sometimes gsm.begin() gets stuck and the board is unable to reconnect to GSM (even though other functionnalities in the loop are still running)

It is unfortunate that an arduino board necessitates advanced low level programming skill to establish a simple GPRS connection without a glitch ...

freeze
froze
frozen ...

smgs · August 23, 2018, 12:44am

Is there any high level way to introduce a function in your code that monitors for timeout's or errors and if a function doesn't complete within x number of seconds then it resets the module?

Interested to help in any further testing you might be doing too.

heligone · August 23, 2018, 4:23pm

Hi smgs,

Thanks for your interest.

I am currently diving deeper into libraries up to AT commands

Currently, even a simple test sketch like GSMScanNetwork is not working (From MKRGSM Lib, see below)

I have tried 2 boards, i am using a soracom iot simcard AND i have tried several loaded lipo batteries.

I have activated the AT debug option line 26, passing the TRUE parameter to the gsmAccess object constructor : GSM gsmAccess(true);

It gets stuck with console showing :

...
AT+CREG?

+CREG: 0,0

OK
AT+CREG?

+CREG: 0,0

OK
AT+CREG?

+CREG: 0,0

OK

If the board gets no signal, or if there is a problem with AT+CREG?, there should be time out and the loop should continue...AM I WRONG ?

// libraries
#include <MKRGSM.h>

//#include "arduino_secrets.h"
// Please enter your sensitive data in the Secret tab or arduino_secrets.h
// PIN Number
const char PINNUMBER[] = "";

// initialize the library instance
GSM gsmAccess(true); // include a 'true' parameter to enable debugging
GSMScanner scannerNetworks;
GSMModem modemTest;

// Save data variables
String IMEI = "";

// serial monitor result messages
String errortext = "ERROR";

void setup() {
// initialize serial communications and wait for port to open:
Serial.begin(9600);
while (!Serial) {
; // wait for serial port to connect. Needed for Leonardo only
}

MODEM.debug();

Serial.println("GSM networks scanner");
scannerNetworks.begin();

// connection state
boolean connected = false;

// Start GSM shield
// If your SIM has PIN, pass it as a parameter of begin() in quotes
while (!connected) {
if (gsmAccess.begin(PINNUMBER) == GSM_READY) {
connected = true;
} else {
Serial.println("Not connected");
delay(1000);
}
}

// get modem parameters
// IMEI, modem unique identifier
Serial.print("Modem IMEI: ");
IMEI = modemTest.getIMEI();
IMEI.replace("\n", "");
if (IMEI != NULL) {
Serial.println(IMEI);
}
}

void loop() {
// scan for existing networks, displays a list of networks
Serial.println("Scanning available networks. May take some seconds.");
Serial.println(scannerNetworks.readNetworks());

// currently connected carrier
Serial.print("Current carrier: ");
Serial.println(scannerNetworks.getCurrentCarrier());

// returns strength and ber
// signal strength in 0-31 scale. 31 means power > 51dBm
// BER is the Bit Error Rate. 0-7 scale. 99=not detectable
Serial.print("Signal Strength: ");
Serial.print(scannerNetworks.getSignalStrength());
Serial.println(" [0-31]");

}

smgs · August 24, 2018, 4:40am

Hi Heligone

I uploaded the GSM scan example from the Examples > MKRGSM > tools > GsmScanNetworks
out put is included below, I've tagged it with the code format to make it clearer and easier to read

GSM networks scanner
Modem IMEI: 111000012345670
Scanning available networks. May take some seconds.

Current carrier: YES OPTUS
Signal Strength: 18 [0-31]
Scanning available networks. May take some seconds.
> Optus AU
> vodafone AU

Current carrier: YES OPTUS
Signal Strength: 18 [0-31]
Scanning available networks. May take some seconds.
> Optus AU
> Telstra Mobile
> vodafone AU

Current carrier: YES OPTUS
Signal Strength: 18 [0-31]
Scanning available networks. May take some seconds.

So not sure whats happening with yours, does your SIM card have a PIN number?

You have an Aerial plugged in too right?

smgs · August 24, 2018, 5:51am

I suggest you load up the SerialGSMPassthrough sketch from the examples and enter "AT" which should be followed by the prompt returning with OK. If that works then try the "AT+CIND?"

which will return a series of values to indicate your battery status, sim card status etc etc.

AT+CIND=?

+CIND: ("battchg",(0-5)),("signal",(0-5)),("service",(0-1)),("sounder",(0-1)),("message",(0-1)),("call",(0-1)),("roam",(0-1)),("smsfull",(0-1)),("gprs",(0-2)),("callsetup",(0-3)),("callheld",(0-1)),("simind",(0-2))

OK
AT+CIND?

+CIND: 5,3,1,0,0,0,0,0,2,0,0,1

OK

Further information available in the u-blox AT command manual.

https://www.u-blox.com/sites/default/files/u-blox-CEL_ATCommands_(UBX-13002752).pdf

you could also make your own sketch and send this command rather than using the pass through option, whatever works for you.

heligone · August 24, 2018, 7:12am

Thank you for your interest @smgs

I am using a soracom IOT multioperator Simcard, and yes I am using an aerial and yes I know I can tag code BUT there is a BUG in the interface here : depending on the code you want to post, some part of it might not be included in the code box.

Even though the battery had a voltage >4V, I changed it with anew one and now AT+CREG is not freezing.

Here is the return for "AT+CIND?"

AT

OK
AT+CIND?

+CIND: 5,2,1,0,0,0,1,0,2,0,0,1

OK

Also the gsm scan :

Scanning available networks. May take some seconds.
AT+COPS=?

+COPS: (2,"F SFR","SFR","20810",2),(1,"Free","Free","20815",2),(1,"F-Bouygues Telecom","BYTEL","20820",2),(1,"Orange F","Orange","20801",2),(2,"F SFR","SFR","20810",0),(1,"Orange F","Orange","20801",0),(1,"F-Bouygues Telecom","BYTEL","20820",0),,(0-6),(0-2)

OK
> F SFR
> Free
> F-Bouygues Telecom
> Orange F
> F SFR
> Orange F
> F-Bouygues Telecom

Current carrier: AT+COPS?

+COPS: 0,0,"F SFR",2

OK
F SFR
Signal Strength: AT+CSQ

+CSQ: 16,3

heligone · August 24, 2018, 7:27am

Here are my views concerning this infamous AT+CREG? freeze.

I have several battery packs LI-ION 18650 1S3P, 3.7V 7800mAh.

I check the battery voltage before use.

But I have noticed that even if the battery voltage is correct, which means >4V, if the battery has not been charged for sometimes, the freeze can occur.

This does not happen with a new battery or a just recharged battery.

I understand that the board needs to draw much current when establishing the connection, and that requires a plugged in battery : USB power or solar power is not enough.

BUT what I dont understand is : If there is no battery connected, or if the battery cannot furnish enough current, the board should not freeze during the initial AT+CREG? loop.

Indeed, for a remote and autonomous IOT project, requiring periodic reconnexion to GSM network, it can always happen that the battery has become a bit weak.

In that case, the freeze will occur at GSM reconnexion and the whole board will freeze and need a manual or watchdog reset.

Maybe this can be adressed progammatically in the gsm.begin() or other parts pof the library

If it is a hardware limitation of SARA chip : time to look for another board ?

heligone · August 24, 2018, 8:09am

concerning AT+CREG? freeze at GSM reconnection please check also :

https://forum.arduino.cc/index.php?topic=565177.0

Riccardo_Rizzo · September 10, 2018, 3:05pm

Hi @heligone, i have modified the sketch proposed before:

Now it is able to retry the connection when the antenna disconnect or loose signal; consider that my code actually (in the sketch) don't have timeout or counter for count the number of re-connection, it try to reconnect forever until when the modem return registered status, you could manage this simply adding in the loop() a counter and choose to do nothing or what you need;
When you disconnect the antenna it try to open a new socket, if not possible it return on the sketch, the time required for this action seems long but each time that i have tried to disconnect the antenna, it always was able to:

follow to run and restart to communicate with the server if i reconnect the antenna;
goes in the else condition of if (gsm.isAccessAlive()) in the main loop;

In the sketch that i propose following i have added some comments, if you look in the loop all the action is subordinated to if (gsm.isAccessAlive()) this check the CREG value and if it is different from a value that represent the registered status to the network it return false, in this way if +CREG=0 case happen when you are in the main loop it allow you to impose your condition in the main sketch, consider that the modem manage automatically the value of CREG, then could you try the code from your side and let me know if work?

/*
  Simple PUT client for ArduinoHttpClient library
  Connects to server once every five seconds, sends a PUT request
  and a request body

  created 14 Feb 2016
  by Tom Igoe

  update by M. Sibert May 2018

  this example is in the public domain
*/

#include <MKRGSM.h>
#include <ArduinoHttpClient.h>
#include "arduino_secrets.h"



const String serverName(("httpbin.org"));
const unsigned serverPort = 80;
const String servicePath(("/put"));

const String GPRS_APN((APN_NAME));
const String GPRS_LOGIN((APN_USERNAME));
const String GPRS_PASSWORD((APN_PASSWORD));

unsigned long initTime = millis();

GSM gsm(true);
GPRS gprs;
GSMClient gprsClient;

HttpClient client = HttpClient(gprsClient, serverName, serverPort);

const String contentType = "application/json";
const String putData = "{ \"name\": \"light\", \"age\": 46 }";
unsigned long int count = 0;

void setup() {
  Serial.begin(115200);

  MODEM.begin();
  boolean connected = false;
  while (!connected) {
    if ((gsm.begin(PIN_CODE) == GSM_READY) &&
        (gprs.attachGPRS(GPRS_APN.c_str(), GPRS_LOGIN.c_str(), GPRS_PASSWORD.c_str()) == GPRS_READY)) {
      connected = true;
    } else {
      Serial.println("Not connected");
      delay(1000);
    }
  }
  Serial.println("Connected");
}

void loop() {
  
  /* Here is checked if the connection is lost, simply check the CREG status
     there you can also count the tentative number until when you could stop to reconect and do other
     you could do somthing like this also in the setup() imposing some condition in the line:45 in the "while (!connected)"
  */
  if (gsm.isAccessAlive()) {

    Serial.println("Making PUT request");
    int ret = client.put(servicePath.c_str(), contentType, putData);
    if (ret < 0) {
      client.flush();
      client.stop();
      return;
    }
    unsigned long looptime = millis();
    /*
      changing the condition here the sketch don't freeze when the connection is lost and the antenna is detached 
    */
    while (client.available() <= 0 && millis() - looptime < 5000) {
    }

    // read the status code and body of the response
    const int statusCode = client.responseStatusCode();
    const String response = client.responseBody();
    if (statusCode != 200) {
      client.flush();
      client.stop();
    } else {
      Serial.print("Status code: ");
      Serial.println(statusCode);
      Serial.print("Response: ");
      Serial.println(response);
      Serial.print(count);
      count++;
    }

    unsigned long start = millis();
    Serial.print("Time ");
    Serial.println((millis() - initTime) / 1000);
    while (client.connected())
    {

      Serial.println("Connected!!!");
      delay(100);
      if (millis() - start > 5000)
      {
        client.flush();
        client.stop();
      }
    }
  } else {
    /*
      here you can implement all the actions that could be done if the connection is lost 
    */
    Serial.println("not connected, loop:sketch "); 
    delay(1000);
  }

}

in my actual test, it run from 4 days, i have disconnected random the antenna and each time that i have reconnected, it was able to establish again the connection with the server, all the problem was managed from sketch, be sure to have the last library version, the only condition that i have change is that in the MKRGSM library in file Modem.cpp in the last line i change the baudrate to 115200 in my test, soon i'll report the results of a long run test with the highest speed possible.

Topic		Replies	Views
freeze with +UUPSDD: 0 return MKRGSM1400	1	1478	May 7, 2021
Board freezes up MKRGSM1400	7	1870	May 7, 2021
MKR1400 freezes while modem activity (send/ receive sms or phone call) MKRGSM1400	5	2160	May 7, 2021
Wire.onRequest causes slave arduino to freeze?? Programming Questions	24	7258	May 5, 2021
MKR1400 hangs up after hours MKRGSM1400	2	666	December 9, 2021

Freeze during put request

Related Topics