the module is blocked when passing through a delay()

Hardware MKR Family MKRFOX1200
1

Hello everyone.
I have a problem, when I run the next skech, the module crashes. The LED stays on, the terminal appears "dato recivido" and the terminal can not close it until I restart the module.
If I remove the delay, everything works correctly.
My version of arduino is 1.8.5 and of card 1.6.19
Any ideas? Thank you.

#include <ArduinoLowPower.h>
#include <SigFox.h>

void setup() 
{
  Serial.begin(9600);
  Serial.println("Hello world");
  pinMode (4,OUTPUT);
  SigFox.debug();
  pinMode(7, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(7), Active, FALLING);
}

void loop() 
{
  Serial.println("loop"); 
}
void Active()
{
  Serial.println("dato recivido");
  digitalWrite(4, HIGH);
  delay(5);
  digitalWrite(4, LOW); 
}
2

interrupt service routines such as Active() should be as short as possible so the system does not hang or miss other events, e.g. in particular do not do serial IO or use delay()
you could use a volatile variable to pass information from the interrupt service routine to loop()

#include <ArduinoLowPower.h>
#include <SigFox.h>

void setup()
{
  Serial.begin(9600);
  Serial.println("Hello world");
  pinMode (4,OUTPUT);
  SigFox.debug();
  pinMode(7, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(7), Active, FALLING);
}

volatile int interrupt=0;

void loop()
{
  Serial.println("loop");
  if(interrupt)
  {
      Serial.println("dato recivido");
      digitalWrite(4, HIGH);
      delay(5);
      digitalWrite(4, LOW);
      interrupt=0;
  }
}
void Active()
{
  interrupt=1;
}

when an interrupt occurs interrupt is set to 1 and information displayed in loop()

3

Thank you for your response, I will provide that option.