Zeitverzögerte Auswertung von Eingängen?

/*
 * Der Sketch verwendet 1874 Bytes (5%) des Programmspeicherplatzes. Das Maximum sind 32256 Bytes.
 * Globale Variablen verwenden 232 Bytes (11%) des dynamischen Speichers, 1816 Bytes für lokale Variablen verbleiben. Das Maximum sind 2048 Bytes.
 * 
 * Kompiliert ohne Warnungen auf Uno/Nano
 * 
 * Sensoren entprellen, Forenbeitrag
 * https://forum.arduino.cc/index.php?topic=621568.msg4213625#msg4213625
 */

typedef struct {
  byte pin;                     //Pin des Sensor
  uint32_t prellzeit;       //wie lange soll auf ein gültiges Signal gewartet werden?
  uint32_t lastseen;       //wann wurde der letzte Zustand eingelesen
  boolean lastread;        //HIGH oder LOW
  boolean state;            //'sicherer' Zustand HIGH/LOW
} SENSOR;

SENSOR mySensor[] {
  {2, 50, 0, 0, 0},
  {3, 20, 0, 0, 0},
  {5, 50, 0, 0, 0},
  {A0, 10, 0, 0, 0}, //das letzte Komma stört nicht
};
const byte anzahlSensoren = sizeof(mySensor) / sizeof(mySensor[0]);

void setup() {
  for (byte t = 0; t < anzahlSensoren; t++) {
    pinMode(mySensor[t].pin, INPUT_PULLUP);
  }
}

void loop() {
  for (byte t = 0; t < anzahlSensoren; t++) {
    boolean zustand = digitalRead(mySensor[t].pin);
    if (zustand != mySensor[t].lastread) {
      //Zustand hat sich geändert
      mySensor[t].lastread = zustand;
      mySensor[t].lastseen = millis();
    } else {
      //der Zustand hält an
      if (mySensor[t].state != zustand && millis() - mySensor[t].lastseen >= mySensor[t].prellzeit) {
        mySensor[t].state = zustand;
      }
    }
  }
  //.....
  for (byte t = 0; t << anzahlSensoren; t++) {
    Serial.print(mySensor[t].state == 1 ? 'x' : '-'); //Ausgabe aller entprellten Sensoren-Werte
    Serial.print('\t');  //müsste TAB sein
  }
  Serial.println();  //neue Zeile
}

Sketch kompiliert ohne Warnungen ect.
Geht bestimmt eleganter - so weit bin ich aber noch nicht :confused:

Ungetestet!! - Vll. hilft'S ja trotzdem

MfG

Cool, danke, muss ich mir ansehen!

Hallo,

100ms ein = ein,
100ms aus = aus,
Schaltzustände dazwischen ignorieren

Nochmal zum Verständnis. Eingangssignal soll nur "ein" sein wenn der Sensor mindestens ununterbrochen 100ms lang high liefert und umgekehrt 100ms lang low dann "aus"?

Ja richtig.
Damit braucht es wohl eine Änderung von "wie lange soll auf ein gültiges Signal gewartet werden?" zu "wie lange muss das Signal high/low anstehen".

Hi

Äääh ... Nein?
Ggf. meinen Versuch da Oben Mal ansehen?
Bei JEDER Pegel-Änderung wird diese Zeit als Startzeit hinterlegt.
ERST, wenn die Prellzeit vorbei ist, wird dieser Status übernommen.

Dar 'riecht' doch schon durch, daß Da in beiden Richtungen die 100ms (oder was sonst) das Signal sauber anliegen muß - wenn nicht, wird ja die Startzeit neu gesetzt und schon ist's Essig mit der Prellzeit.

MfG

OK, sorry, das hab ich dann nicht kapiert. Dann is ja gut! Danke!

Ggf. meinen Versuch da Oben Mal ansehen?

Hach...
Ich habe ihm auch meine schönste und einfachste Entprellung angeboten.
Aber: Schmeckte nicht!

combie:
Hach...
Ich habe ihm auch meine schönster und einfachste Entprellung angeboten.
Aber: Schmeckte nicht!

Hmm, dein Beispiel kann ich da nur schwerlich lesen, mit den Libs und dem C++ Style.
Einen einfachen habe ich ja nachgebaut, das Array ging noch ab.
Oder kapier ich was nicht ?

combie:
Ich habe ihm auch meine schönster und einfachste Entprellung angeboten.
Aber: Schmeckte nicht!

Das kommt noch. Warte mal so 5 Jahre und 4000 postings.

P.S. Um alle Kommentaren vorzubeugen, ich beziehe mich nicht im entferntesten auf die Intelligenz/Interesse/Lust des TE, sondern auf die Programmierkenntnisse von combie.

So ist es, meine Programmierkenntnisse sind jetzt ein paar Tage jung :wink:
Ich möchte auch kein Profi werden, die Umsetzung meiner Interessen mit eurer Hilfe reicht mir völlig.
Und so wie sich das alles abzeichnet, wird das auch klappen.

Hi

Das ist allerdings schade, daß Du nicht darauf zielst, dem Steinchen das Maximum entlocken zu wollen.
(wobei combie in einer gaaanz anderen Liga spielt - wobei - in Ligen, in Denen ich kaum als Zuschauer erlaubt bin, spielen hier Einige :wink: )
Wenn ich aber so weit bin, werde ich den ganzen Kram schamlos abkupfern ... versprochen!

MfG

Herzlichen Dank für die Blumen!

Ja, ein bisschen fachliche Kompetenz habe ich mir wohl erarbeitet.
Mit C++ bin ich allerdings erst hier, mit Arduino, angefangen.

Was die CombieTimer Lib betrifft, folgt sie einigen Mantras, welche ich mir auch schon vor meiner C++ Zeit ins Hirn gebrannt habe:

Wenn du irgendwas drei mal auf eine bestimmte Art gemacht hast,
dann mach eine Funktion oder Klasse draus.

Wenn du eine Funktion/Klasse baust, sorge für eine möglich simple Schnittstelle
Damit das Ding von jedem benutzt werden kann.

Bedingungen und Blockschachtelungen:
1 Ebene, schön. 2 Ebenen, ok geht noch. 3 Ebenen, muss das? 4 Ebenen, igitt!

Der EntprellTimer meiner Lib ist ganz einfach zu benutzen.
Ok, von innen mag er etwas kompliziert aussehen, aber da muss man ja nicht hinschauen.

Klein anfangen, groß werden. Ja nicht den Spaß an der Sache verlieren, darum die Ziele in griffweite halten.
Heute noch ist das Interesse, dass es einfach nur funktioniert. Morgen, wer weiß :wink:

Ist es das?

#include <CombieTimer.h>
using Combie::Timer::EntprellTimer;

const byte taster =  2; // taster gegen GND schaltend

EntprellTimer entprellen(200);   // in der Praxis wird man wohl eher 20ms verwenden

void setup()
{
 pinMode(LED_BUILTIN,OUTPUT);   
 pinMode(taster,INPUT_PULLUP);
} 

void loop()
{
  // die LED zeigt das, vom prellen bereinigte, Signal
  digitalWrite(LED_BUILTIN,entprellen(!digitalRead(taster)));  // invers, wg. pullup
}

das ist das Kunststück richtig ?

entprellen(!digitalRead(taster))

damit müsste ich meinen Merkerzuweisungen nur das entprellen( ) hinzufügen ?

damit müsste ich meinen Merkerzuweisungen nur das entprellen( ) hinzufügen ?

Ja, denke schon...

// oder so
bool merker = entprellen = not digitalRead(taster);

Natürlich benötigt jede Taste seinen eigenen Entpreller.

Also, wenn man es denn verstanden hat, ist es die einfachste Möglichkeit! Danke.
Lib einfügen
entprellen Aufruf zu jedem Pin-Lesen
fertig

könnte man verm. auch in eine Schleife packen, weniger Zeilen...

ist es die einfachste Möglichkeit

Ist es!

Und, wie du siehst, ist es nicht C++, oder die Komplexität des Entprellers, welche dich erst davon abgehalten hat, ihn zu nutzen, sonder eher ein innerer Widerstand.
Und diese, kann nur der Eigentümer der Widerstände bearbeiten.
Was du ja jetzt wohl erfolgreich gemeistert hast.

Von außen, kommt man/ich da nicht ran.....

Ja schon, aber wenn man das Wissen nicht hat, wie sollst das erkennen geschweige verstehen.
Man kann einfach nicht auf ein galoppierendes Pferd aufspringen, ich zumindest nicht.
Ich muss es häppchenweise machen und ohne die richtungsweisende Führung, bist halt im Wald.

Ich hab grad das Gefühl, dass ich auf einen Schnellzug aufspringe :wink:
So lange ihr mir nicht abspringt, fährt der Zug!

C++ steht auf der Todo, aber so schnell geht das nicht, das wird seine Zeit brauchen.
Aktuell möchte ich nur nicht die Lust und Laune verlieren und mal das gesetzte Ziel schaffen.

Die Schleife fehlt mir noch, dann würde ich meinen wäre diese Aufgabenstellung gelöst.

Hallo,

habe mich heute auch rangesetzt. Ergebnis ist ähnlich wie das von postmaster. Wenn es mehrere Eingänge sein sollen, würde ich auch ein struct array erstellen und alles in einer for erschlagen. Im Endeffekt wirds dann recht zügig zu einer Klasse.

const byte pin_Taster = 2;
const byte pin_Led = 13;

void setup(void) {
  pinMode(pin_Taster, INPUT_PULLUP);
  pinMode(pin_Led, OUTPUT);
}

void loop(void) {
  
  bool var = update_Taster(pin_Taster, 100);
  digitalWrite(pin_Led, var); 

}


// ****** Funktionen ******

bool update_Taster (const byte pin, const byte zeit)                         
{
  static unsigned long last_ms = 0;
  static bool last_state = true;
  static bool new_state = true;
  
  unsigned long ms = millis();

  bool state = digitalRead(pin);    // pin einlesen

  if (state != last_state) {        // Hat sich Eingangspegel geändert?
    last_ms = ms;                   // Wenn ja aktuelle Zeit 
    last_state = state;             // und diesen Zustand merken
  }
  
  if (ms - last_ms >= zeit) {       // Blieb letzter Zustand für x ms stabil ?
    new_state = state;              // Wenn ja aktuellen Zustand merken
  }

  return new_state;                 // und zurückgeben
}

... und die Klasse ist fertig :wink:

// https://forum.arduino.cc/index.php?topic=621568.0

class Sensor
{
  private:
    const byte pin;
    bool last_state;
    bool new_state;
    const byte debounce;    // max. 255ms, ansonsten auf unsigned int/long ändern
    unsigned long last_ms;

  public:
    // Konstruktor
    Sensor (byte p, unsigned long deb) :
      // Initialisierungsliste
      pin(p),
      last_state(true),
      new_state(true),
      debounce(deb),
      last_ms(0)
    {}

    // Methoden
    void init()
    {
      pinMode(pin, INPUT_PULLUP);
    }

    void entflattern ()
    {
      unsigned long ms = millis();
      bool state = digitalRead(pin);    // pin einlesen

      if (state != last_state) {        // Hat sich Eingangspegel geändert?
        last_ms = ms;                   // Wenn ja aktuelle Zeit
        last_state = state;             // und diesen Zustand merken
      }

      if (ms - last_ms >= debounce) {   // Blieb letzter Zustand für x ms stabil ?
        new_state = state;              // Wenn ja aktuellen Zustand merken
      }
    }

    bool get_state() { return new_state; }
};

Sensor sensoren[] = {
      {2, 100},   // pin, Entprellzeit
      {3, 90},
      {4, 110},
      {5, 80}
};  


void setup()
{
  Serial.begin(9600);
      
  for (Sensor & s : sensoren)
  {
    s.init();
  }

}

void loop()
{
  for (Sensor &s : sensoren)
  {
    s.entflattern(); 
  } 

  serieller_Monitor (500);      // nur zum sichtbar machen
}


void serieller_Monitor (const unsigned int INTERVALL)
{
  static unsigned long last_ms = 0;
  unsigned long ms = millis();

  if (ms - last_ms > INTERVALL)
  {
    last_ms = ms;
    for (Sensor &s : sensoren)
    {
      Serial.print(s.get_state() );
      Serial.print('\t');
    }
    Serial.println();
  }
}