Go Down

Topic: NewPing Library: HC-SR04, SRF05, SRF06, DYP-ME007, Parallax PING))) - v1.7 (Read 582873 times) previous topic - next topic

codlink

Wanted to say thanks for the hard work.  Really appreciate this library!
//LiNK

fairorgan

Fantastic job with this new library!

I am especially liking the median feature of v1.5 to eliminate rogue results, but how can this be integrated into the 15 sensor example sketch which does not use ping() but sonar.ping_timer(function) instead?

teckel


Fantastic job with this new library!

I am especially liking the median feature of v1.5 to eliminate rogue results, but how can this be integrated into the 15 sensor example sketch which does not use ping() but sonar.ping_timer(function) instead?


To actually combine the two would be simple.  However, in the process it would lose the interrupt aspect of the ping_timer() method.  I've been toying with the idea, and considering new ways of doing it.  One thing I've considered is a mass ping of all sensors at the same time followed by interrupt waiting for the ping echo.  With 15 sensors there could be crazy cross-talk.  But with 4 sensors it would probably work.

Also consider that with 15 sensors, if it were to poll each sensor 3 times it would take 3 times as long.  Not sure how much processing time you have left after pinging 15 sensors.  But, multiply the time it takes by 3 or 5 and you may no longer have time to do anything else, or the pings are just too slow to sense something in time if your robot is moving at a high enough speed.

Tim
My platforms Arduino, Teensy 3.2, Arduino Pro Mini, ATmega328
My libraries: NewPing, LCDBitmap, toneAC, toneAC2, NewTone, TimerFreeTone
My projects: https://dogblocker.com & https://baconorbeer.com
My beer: Great Lakes Brewing Co. Lake Erie Monster

fairorgan

Hi Tim,

I was actually only thinking of using two SR-04 sensors (at most three), but like your use of the array in the 15 sensor example for holding the data. Would I be better just duplicating the new ping_median once per sensor and not use an array nor interrupt method?

My project: I am controlling a robot's head position via servos, which currently have either remote control (via joystick) or automatic random positioning of x and y axis. I would like to add the ability for close object tracking of the x axis, so thought the best way would be two ultrasonic sensors pointing slightly apart concealed on the head itself, and in the event of an object coming within say a couple of metres range, the head will stop random movements and track the object in x axis by moving the servo to keep the signal from both ultrasonic sensors the same, until either the object goes out of range or the robot gets bored.

Nick

Bi0H4z4rD

First of all, thanks for the great job you are doing!

Now, i wanted to comment two issues i am having.

First one is the "0" thing. I still get it too often, but i have found some "logic" sequence on it.

Here are some results:
Code: [Select]
210 210
211 211
210 210
211 211
0 211
0 211 211
0 0
210 211
210 210
211 210
210 210
210 210
0 210
0 210 210
0 0
210 0
210 0 210
210 210
210 210
210 211
0 211
0 211 211
0 0
209 0
209 0 209
209 209
210 211
210 210
210 210
0 210
0 210 210
0 0
210 211
210 210
210 0
210 0 210
211 210
0 211
0 211 211
0 0
210 213
210 210
211 210
210 210
211 211
0 210
0 210 210
188 0
188 0 188
210 0
210 0 210
210 210
210 210
210 209
209 210
0 210
0 210 210
0 0
210 0
210 0 210
210 209
210 210
210 211
0 210
0 210 210
0 0
209 211
210 210
210 210
210 210
210 211
0 210
0 210 210
0 0


First and second colums are read values, and third is just the difference between first and second, so can be ignored. There seems to be an issue that affects after X cycles and makes it return value "0".

Here is the code that i am running:

Code: [Select]
#include <NewPing.h>

NewPing sonar1(2, 3, 400); // Sensor 1: trigger pin, echo pin, maximum distance in cm


#define pingSpeed 35 // Ping frequency (in milliseconds), fastest we should ping is about 35ms per sensor, 100ms is default


void setup() {
 Serial.begin(115200);

}

void loop() {

  unsigned int current_distance1 = sonar1.convert_cm(sonar1.ping());
  delay(100);
  unsigned int current_distance2 = sonar1.convert_cm(sonar1.ping());
        Serial.print(current_distance1);
     Serial.print(" ");
     Serial.println(current_distance2);

  if (current_distance1 > current_distance2) {
   unsigned int result = (current_distance1 - current_distance2);
   if (result > 10){
     Serial.print(current_distance1);
     Serial.print(" ");
     Serial.print(current_distance2);
     Serial.print(" ");
     Serial.println(result);

}
  }
  if (current_distance1 < current_distance2) {
   unsigned int result = (current_distance2 - current_distance1);
   if (result > 10){
     Serial.print(current_distance1);
     Serial.print(" ");
     Serial.print(current_distance2);
     Serial.print(" ");
     Serial.println(result);

}
  }
  delay(29);
}


Maybe it helps you solve this issue.

Second thing, is that after a determined number of cycles, the board stops working. I mean, it just freezes. It might take something like 4 minutes or so. Im not too sure about what the reason is, but just wanted to comment it.

This code is being run on an UNO with an SRF05.

BR


Bi0H4z4rD

I have some very good news for ppl with so many "0".

The issue is not the library (NewPing). The issue are the connections between the sensor and the board. I just found out that, if i hold tight the connections in the sensor with my hand, i get these results:

Code: [Select]
38 54
38 54 16
34 196
34 196 162
199 198
177 197
177 197 20
172 195
172 195 23
171 171
195 170
195 170 25
109 59
109 59 50
96 46
96 46 50
58 75
58 75 17
55 195
55 195 140
196 83
196 83 113
176 0
176 0 176
171 175
169 195
169 195 26
195 169
195 169 26
194 61
194 61 133
90 137
90 137 47
196 57
196 57 139
111 61
111 61 50


With same code as posted in post above this one, moving the sensor all around my room.

So, hope this helps!

BR

teckel

Your code works fine for me.  I guess a loose connection could the the source of the problem.  But, it could also be that you're trying to get a ping that's just too far away.  These sensors really don't work all the way out to 400 or 500cm.  They seem to work okay to about 200cm for most, but I have some sensors that won't read anything consistently beyond around 75cm.  This is the fault of the sensors, not the library as the same thing happens with other libraries or with no library at all.  Try putting something 50cm away from the sensor and see what happens then.  It's just suspicious that it stops working around 200cm and then in your next test all the results are within 200cm.  Maybe it would work without you holding the sensor if all the readings were <50cm?  But, if it is a lose connection, that could also be why it's crashing after a few minutes, it's simply shorting out.  BTW, I've *never* got a zero reading that wasn't for a logical reason and I've *never* had any of my Arduino or Teensy 2.0 crash while using the NewPing library.  And, I've sometimes ran them for several hours or even overnight without a single issue.

Tim
My platforms Arduino, Teensy 3.2, Arduino Pro Mini, ATmega328
My libraries: NewPing, LCDBitmap, toneAC, toneAC2, NewTone, TimerFreeTone
My projects: https://dogblocker.com & https://baconorbeer.com
My beer: Great Lakes Brewing Co. Lake Erie Monster

Bi0H4z4rD


Your code works fine for me.  I guess a loose connection could the the source of the problem.  But, it could also be that you're trying to get a ping that's just too far away.  These sensors really don't work all the way out to 400 or 500cm.  They seem to work okay to about 200cm for most, but I have some sensors that won't read anything consistently beyond around 75cm.  This is the fault of the sensors, not the library as the same thing happens with other libraries or with no library at all.  Try putting something 50cm away from the sensor and see what happens then.  It's just suspicious that it stops working around 200cm and then in your next test all the results are within 200cm.  Maybe it would work without you holding the sensor if all the readings were <50cm?  But, if it is a lose connection, that could also be why it's crashing after a few minutes, it's simply shorting out.  BTW, I've *never* got a zero reading that wasn't for a logical reason and I've *never* had any of my Arduino or Teensy 2.0 crash while using the NewPing library.  And, I've sometimes ran them for several hours or even overnight without a single issue.

Tim


Yeah, as i say, it was all due to loose connections. I just got everything soldered, and now i get 0 only when its out of range. Both tests you see above where done in the same room, where i should get no zeros at all since its pretty small.

I guess the "arduino stops working" would be due to some data generated by the loose connection that would cause an overflow.

Everything working pretty much perfect right now!

BR

teckel


I was actually only thinking of using two SR-04 sensors (at most three), but like your use of the array in the 15 sensor example for holding the data. Would I be better just duplicating the new ping_median once per sensor and not use an array nor interrupt method?

My project: I am controlling a robot's head position via servos, which currently have either remote control (via joystick) or automatic random positioning of x and y axis. I would like to add the ability for close object tracking of the x axis, so thought the best way would be two ultrasonic sensors pointing slightly apart concealed on the head itself, and in the event of an object coming within say a couple of metres range, the head will stop random movements and track the object in x axis by moving the servo to keep the signal from both ultrasonic sensors the same, until either the object goes out of range or the robot gets bored.


If you just wanted to use an array to store the ping results, you could easily modify the 15 sensor sketch to work with ping_median instead of ping_timer.  The problem is that the sketch would no longer be interrupt driven, and would be waiting for ping echos instead of doing anything else (like positioning the servo on the robot or doing probably much of anything else).  For example, if you had 3 sensors and each sensor would take 5 samples to find the median that would be a total of 15 pings with at least a 29ms delay between each or a total of around 435ms (about 1/2 second) every ping cycle where your robot can do nothing but read the sensors.  Not at all interrupt driven like the 15 sensor sketch where very little time is wasted monitoring the pings and you're free to do other things what seems like the same time.

A better solution is to continue to use the 15 sensor sketch as a base, but use oversampling to read the sensors multiple times, then average the results.  Here's an example sketch:

Code: [Select]
#include <NewPing.h>

#define SENSORS        3 // Number or sensors.
#define ITERATIONS     5 // Iterations for each sensor.
#define PING_NUM ITERATIONS * SENSORS // Calculates the number of pings.
#define MAX_DISTANCE 200 // Maximum distance (in cm) to ping.
#define PING_INTERVAL 29 // Milliseconds between sensor pings (29ms is about the min to avoid cross-sensor echo).

unsigned long pingTimer[PING_NUM]; // Holds the times when the next ping should happen for each sensor.
unsigned int cm[PING_NUM];         // Where the ping distances are stored.
uint8_t currentSensor = 0;         // Keeps track of which sensor is active.

NewPing sonar[PING_NUM] = {      // Sensor object array (Each sensor's trigger pin, echo pin, and max distance to ping).
 NewPing(12, 11, MAX_DISTANCE), // Sensor 0, sample 1
 NewPing(2, 3, MAX_DISTANCE),   // Sensor 1, sample 1
 NewPing(4, 5, MAX_DISTANCE),   // Sensor 2, sample 1
 NewPing(12, 11, MAX_DISTANCE), // Sensor 0, sample 2
 NewPing(2, 3, MAX_DISTANCE),   // Sensor 1, sample 2
 NewPing(4, 5, MAX_DISTANCE),   // Sensor 2, sample 2
 NewPing(12, 11, MAX_DISTANCE), // Sensor 0, sample 3
 NewPing(2, 3, MAX_DISTANCE),   // Sensor 1, sample 3
 NewPing(4, 5, MAX_DISTANCE),   // Sensor 2, sample 3
 NewPing(12, 11, MAX_DISTANCE), // Sensor 0, sample 4
 NewPing(2, 3, MAX_DISTANCE),   // Sensor 1, sample 4
 NewPing(4, 5, MAX_DISTANCE),   // Sensor 2, sample 4
 NewPing(12, 11, MAX_DISTANCE), // Sensor 0, sample 5
 NewPing(2, 3, MAX_DISTANCE),   // Sensor 1, sample 5
 NewPing(4, 5, MAX_DISTANCE)    // Sensor 2, sample 5
};

void setup() {
 Serial.begin(115200);
 pingTimer[0] = millis() + 75;          // First ping starts at 75ms, gives time for the Arduino to chill before starting.
 for (uint8_t i = 1; i < PING_NUM; i++) // Set the starting time for each sensor.
   pingTimer[i] = pingTimer[i - 1] + PING_INTERVAL;
}

void loop() {
 for (uint8_t i = 0; i < PING_NUM; i++) { // Loop through all the sensors.
   if (millis() >= pingTimer[i]) {        // Is it this sensor's time to ping?
     pingTimer[i] += PING_INTERVAL * PING_NUM;   // Set next time this sensor will be pinged.
     if (i == 0 && currentSensor == PING_NUM - 1) oneSensorCycle(); // Sensor ping cycle complete, do something with the results.
     sonar[currentSensor].timer_stop();          // Make sure previous timer is canceled before starting a new ping (insurance).
     currentSensor = i;                          // Sensor being accessed.
     cm[currentSensor] = NO_ECHO;                // Make distance NO_ECHO in case there's no ping echo for this sensor.
     sonar[currentSensor].ping_timer(echoCheck); // Do the ping (processing continues, interrupt will call echoCheck to look for echo).
   }
 }
 // The rest of your code would go here.
}

void echoCheck() { // If ping received, set the sensor distance to array.
 if (sonar[currentSensor].check_timer())
   cm[currentSensor] = sonar[currentSensor].ping_result / US_ROUNDTRIP_CM;
}

void oneSensorCycle() { // Sensor ping cycle complete, do something with the results.
 unsigned int uS[ITERATIONS], last;
 uint8_t i, j, x, it, ii;
 for (x = 0; x < SENSORS; x++) {
   uS[0] = NO_ECHO;
   it = ITERATIONS;
   ii = 0;
   for (i = 0; i < ITERATIONS; i++) {
     last = cm[x + (i * SENSORS)];
     if (last != NO_ECHO) {   // Ping in range, include as part of median.
       if (i > 0) {           // Don't start sort till second ping.
         for (j = ii; j > 0 && uS[j - 1] < last; j--) // Insertion sort loop.
           uS[j] = uS[j - 1]; // Shift ping array to correct position for sort insertion.
       } else j = 0;          // First ping is starting point for sort.
       uS[j] = last;          // Add last ping to array in sorted position.
       ii++;                  // Next ping in insertion sort array.
     } else it--;             // Ping out of range, skip and don't include as part of median.
   }
   Serial.print(x);
   Serial.print("=");
   Serial.print(uS[it >> 1]);
   Serial.print("cm ");
 }
 Serial.println();
}


The above sketch is 3 sensors with 5 times oversampling.  Instead of just printing the results in the oneSensorCycle function, it does the same insertion sort/median calculation as NewPing does with the ping_median method.  It pings each sensor (0,1,2) then repeats 5 times.  For example, the ping order is: 0,1,2,0,1,2,0,1,2,0,1,2,0,1,2.  This sketch will also accommodate different oversampling (iterations).  Just change the ITERATIONS define and sonar array to match.

The advantage is that this sketch is totally interrupt driven.  So, the ATmega has all kinds of time to do other things.  While pinging, every 24uS it checks for a ping echo, but the rest of the time your sketch can do other things (like rotate a servo, move, etc).  Once a full 3 sensor, 5 oversample pass is made, it goes to the oneSensorCycle function where the median values for the 3 sensors are calculated, which is very quick and only takes about 30uS.  Basically, the ATmega is free to do other things at the same time it's pinging.  Just be sure to not use any delay statements in your sketches!

Tim
My platforms Arduino, Teensy 3.2, Arduino Pro Mini, ATmega328
My libraries: NewPing, LCDBitmap, toneAC, toneAC2, NewTone, TimerFreeTone
My projects: https://dogblocker.com & https://baconorbeer.com
My beer: Great Lakes Brewing Co. Lake Erie Monster

teckel

fairorgan got me to thinking about exactly how much processing time is spent using the ping_timer method.  Which also helps to understand what else your sketch could be doing in the remaining time.  So, I wrote a sketch to tests this.  The sketch runs for 30 seconds and logs how much time is spent both initiating the ping and checking for the return echo.  It's not perfect, as there's some overhead in doing these calculations making these estimates a little on the high side.  Anyway, here's the results with pings happening every 29ms.

5cm pings = <1% load
20cm pings = 2% load
70cm pings = 7% load
125cm pings = 12% load
200cm pings = 19% load
500cm pings = 45% load

When reducing the maximum sensor distance value when calling the NewPing constructor, you can greatly reduce the maximum ping_timer load.  For example, if you leave it at the default of 500cm, using ping_timer every 29ms will use up to 45% processor load.  However, lowering the max distance to 200cm means the maximum load can be only 19%, or lowering it to 50cm makes the max load only 5%.  So, setting a maximum distance to the longest distance you need will greatly free up the ATmega to do other parts of your sketch.

The ping frequency also effects the processor load.  The above numbers were all done at a 29ms ping rate.  However, if the ping rate is every 100ms, the load is drastically reduced to only 5.5% (down from 19%).  200cm maximum distance and pinging every 50ms uses a maximum of 11% processor load.

So, when creating an interrupt driven sketch and using NewPing, setting the maximum sensor distance and ping rate to what you really need for your project will greatly effect how much processing time you have available to do other parts of your sketch.  Doing a maximum ping rate of 29ms and leaving the default maximum distance at 500cm will use almost half of the ATmega processing time (45%).  If your project really only needs to sense out to 200cm and pinging once every 100ms is all the faster you really need, you've lowered the processing time down to only 5.5% (almost 1/10th the load).

Keep in mind that these are maximum load amounts.  If the a ping echo is sensed at a shorter distance, the load can be greatly reduced.  For example, the 45% load for a max distance of 500cm at a 29ms ping rate is only if there's a NO_ECHO (zero value).  If under the same settings there's a constant ping echo at 10cm, the load is only 1%.  So, these are truly worse case numbers.  But, to avoid your sketch to be sluggish at times, you should consider the worst case scenario.

Tim
My platforms Arduino, Teensy 3.2, Arduino Pro Mini, ATmega328
My libraries: NewPing, LCDBitmap, toneAC, toneAC2, NewTone, TimerFreeTone
My projects: https://dogblocker.com & https://baconorbeer.com
My beer: Great Lakes Brewing Co. Lake Erie Monster

sbright33

Thinking...  Instead of measuring the time of a reflection returned from an object.  What if we had 2 devices synchronized by GPS or an accurate clock.  One sending the ping, the other receiving it.  If we can measure the delay within 1-2us that would be accurate.  Roughly 0.01".  Obviously that is not possible because of the physics of a sound wave. 

What is the theoretical limit using the frequency of the ultrasonic sensors in this configuration? 
It's the same as the normal method.
Let's use 100khz as an example.  Each cycle is 10us.  So 1/10"?  Certainly <1/2".  Averaging multiple readings.

Wouldn't this greatly increase the range compared to using only 1 device?

You could send a ping every 2ms once you know the rough distance. 
Then you'd have 500 measurements to average in only 1 sec, regardless of the distance.

Obviously the limitation would not be the accuracy of the PPS clock, since GPS is +-10ns.
10ns is about 10ft at the speed of LIGHT!
We'll leave that for another LightPing Library...

How can I use this method with the receiver in a Quadcopter?
The problem is the sound from the motors and blades.
The obvious answer is to put the transmitter in the air,
the receiver on the ground where you want to land, then Xbee to send the data.
This works much better, with a huge increase in range, compared to reflecting from the ground when it's grass.

Thoughts?

teckel


Thinking...  Instead of measuring the time of a reflection returned from an object.  What if we had 2 devices synchronized by GPS or an accurate clock.  One sending the ping, the other receiving it.  If we can measure the delay within 1-2us that would be accurate.  Roughly 0.01".  Obviously that is not possible because of the physics of a sound wave. 

What is the theoretical limit using the frequency of the ultrasonic sensors in this configuration? 
It's the same as the normal method.
Let's use 100khz as an example.  Each cycle is 10us.  So 1/10"?  Certainly <1/2".  Averaging multiple readings.

Wouldn't this greatly increase the range compared to using only 1 device?

You could send a ping every 2ms once you know the rough distance. 
Then you'd have 500 measurements to average in only 1 sec, regardless of the distance.

Obviously the limitation would not be the accuracy of the PPS clock, since GPS is +-10ns.
10ns is about 10ft at the speed of LIGHT!
We'll leave that for another LightPing Library...

How can I use this method with the receiver in a Quadcopter?
The problem is the sound from the motors and blades.
The obvious answer is to put the transmitter in the air,
the receiver on the ground where you want to land, then Xbee to send the data.
This works much better, with a huge increase in range, compared to reflecting from the ground when it's grass.

Thoughts?


The current ping sensors I've found can't ping that quickly.  I'm finding some ping sensors now that can't really ping faster than about 48-49ms, and none can faster than once every 29-32ms.  Basically, they initiate a ping, then you can't initiate another ping till some set time has passed.

Also, when you initiate a ping they take a little while before they actually start (around 450uS).  This varies greatly from device to device.  My library waits for the sensor to be ready so an accurate measurement is taken.

Finally, when sending a large number of pings, there's no way the receiving sensor would be able to know when the ping that arrived was sent.  The only way that would be possible is if the ping itself actually contained a timestamp.

Without some kind of time stamp on the ping itself, very accurately synchronized sensors, and custom built sensors that would ping on command, it's not really possible.  There are probably easier ways of doing it, albeit probably just as expensive.

Tim
My platforms Arduino, Teensy 3.2, Arduino Pro Mini, ATmega328
My libraries: NewPing, LCDBitmap, toneAC, toneAC2, NewTone, TimerFreeTone
My projects: https://dogblocker.com & https://baconorbeer.com
My beer: Great Lakes Brewing Co. Lake Erie Monster

sbright33

There must be a way to SEND a ping every 5ms.  Once you know the rough distance, there's no need to put a timestamp on each ping.  You already know the rough distance, hence how many integer ms it takes.  When you send them at 2-5ms intervals you're now trying to measure the 100us interval.  0.1ms which you add to the integer rough distance you already found.  0.1ms or 0.05ms can be obtained by averaging many samples.  Forget about all this for a minute, it's not my main point.  Let's just use your 50ms interval with no timestamps.

Wouldn't the distance or range increase greatly with 2 devices, sender and receiver in sync?



teckel


There must be a way to SEND a ping every 5ms.  Once you know the rough distance, there's no need to put a timestamp on each ping.  You already know the rough distance, hence how many integer ms it takes.  When you send them at 2-5ms intervals you're now trying to measure the 100us interval.  0.1ms which you add to the integer rough distance you already found.  0.1ms or 0.05ms can be obtained by averaging many samples.  Forget about all this for a minute, it's not my main point.  Let's just use your 50ms interval with no timestamps.

Wouldn't the distance or range increase greatly with 2 devices, sender and receiver in sync?


Around double the distance.  So maybe up to 10 meters for very inexpensive SR04 type sensors.  There are commercial sensors that have a range of up to 50 feet, so using two sensors that range could be as high as 100 feet.

In the case of an Quadcopter, you would need to have two synchronized timers.  I'm not sure if this is the environment you're really considering, but you wouldn't need synchronized timers if you could tie the send and receive sensors to the same Arduino.  There could be an issue with wire length, however.

I still think you'd need a time stamp, unless you're only trying to measure acceleration, which may be possible as the distance between the pings would vary due to acceleration.

Tim
My platforms Arduino, Teensy 3.2, Arduino Pro Mini, ATmega328
My libraries: NewPing, LCDBitmap, toneAC, toneAC2, NewTone, TimerFreeTone
My projects: https://dogblocker.com & https://baconorbeer.com
My beer: Great Lakes Brewing Co. Lake Erie Monster

sbright33

Interesting discussion Tim.  I disagree about timestamps.  Here's how to synchronize 2 Uno's to 2us.
As you can see they stay in sync even without GPS once initialized.
http://arduino.cc/forum/index.php/topic,120288.0.html

Go Up