Go Down

Topic: schwankende werte - bmp085-Sensor (Read 3766 times) previous topic - next topic

wolf360

Hi Leute,

ich hab mir einen bmp085 Luftdrucksensor gekauft und angeschlossen, aber ich bekomme irgendwie schwankende werte....

Für den BMP085 benutze ich folgende Library:

https://github.com/adafruit/Adafruit_BMP085_Unified

und habe mich auch an den Beispielcode gehalten.

Ich bekomme aber werte zwischen 900 hPa - 960 hPa ist das normal oder mache ich irgendwas falsch ?

Grüße

wolf360

jurs


Ich bekomme aber werte zwischen 900 hPa - 960 hPa ist das normal oder mache ich irgendwas falsch ?


Normal ist bei einem ruhig im Zimmer liegenden BMP085 eine Schwankung um wenige Zehntel hPa von Auslesung zu Auslesung.

guntherb

Hast du ein Shield, oder nur den Sensor?
Falls nur den Sensor, hast du die 100nF Kondensatoren drauf?
Grüße
Gunther

wolf360

Ich habe nur einen Sensor ohne shield ( http://dx.com/p/bmp085-barometric-digital-pressure-sensor-module-board-for-arduino-blue-147261#.Uup3c5-IXqA )

Glaube da ist kein Kondensator dabei?
( sorry bin noch recht neu in der Welt der Elektronik ^^)

jurs


( sorry bin noch recht neu in der Welt der Elektronik ^^)


Dann mal ein Tipp: Immer das Datenblatt lesen!

Datenblätter (meist auf Englisch) findest Du bei Google mit der Bezeichnung des Bausteins und dem weiteren Suchbegriff "datasheet". Im gegebenen Beispiel also mit:
http://bit.ly/1idOeuh

Lies mal im Datenblatt die Betriebsspannung ("Supply voltage", VDD) des Sensors nach und vergleiche, an welche Spannung Du den Sensor angeschlossen hast!

wolf360

Am Sensor habe ich VDD 3,3 V angeschlossen

jurs


Am Sensor habe ich VDD 3,3 V angeschlossen


Das ist korrekt.
Große andere Möglichkeiten zur falschen Verkabelung gibt es ja kaum.

Hast  Du ein Multimeter da und könntest mal die Spannung zwischen GND und SDA bzw. SCL messen?

michael_x

sparkfun spendiert dem bmp180 auf seinem Breakout Board  1*10µf und 2*0.1µF für vddd und vdda.  (Und liefert immer super Dokumentation)

Quote
Glaube da ist kein Kondensator dabei?

Auf deinem Modul ist sowas auch drauf,  den Bildern in deinem Link nach zu urteilen, sind da Kondensatoren , 2 * I2C pullup Widerstände a 4.7k, und  das "662k" dient evtl. als Spannungswandler wegen der versprochenen Vcc= 3 .. 5V ?

Der eigentliche Sensor ist das Ding mit den 8 Anschlüssen und dem kleinen Loch, in der Mitte des Platinchens.

rudirabbit

Ich verwende auch diesen Sensor, und habe nur leicht schwankende Werte hinter dem Komma.

Allerdings nehme ich diese Lib. http://code.google.com/p/bmp085driver/downloads/list
Ob es dein Problem löst weiß ich nicht, aber testen kannst du die Lib ja mal.

Du kannst die Sensor Class mit unterschiedlichen Genauigkeiten des Sensor instanzieren.
Wobei deine Lib auch defaultmässig den ULTRA_HIGHRES  Mode nimmt.
Code: [Select]

// BMP085 Modes
#define MODE_ULTRA_LOW_POWER    0 //oversampling=0, internalsamples=1, maxconvtimepressure=4.5ms, avgcurrent=3uA, RMSnoise_hPA=0.06, RMSnoise_m=0.5
#define MODE_STANDARD           1 //oversampling=1, internalsamples=2, maxconvtimepressure=7.5ms, avgcurrent=5uA, RMSnoise_hPA=0.05, RMSnoise_m=0.4
#define MODE_HIGHRES            2 //oversampling=2, internalsamples=4, maxconvtimepressure=13.5ms, avgcurrent=7uA, RMSnoise_hPA=0.04, RMSnoise_m=0.3
#define MODE_ULTRA_HIGHRES      3 //oversampling=3, internalsamples=8, maxconvtimepressure=25.5ms, avgcurrent=12uA, RMSnoise_hPA=0.03,


Arduino UNO,MEGA,DUE 
Dunkel die andere Seite ist. - Klappe, Yoda, und iss deinen Toast :-)

wolf360

erstmal danke für die Hilfe =)

ich habe gerade mal SDA und SCL gemessen ( Plus an SDA / SCL und Minus an GND und habe das Multimeter auf 20 V eingestellt

Bei SDA wird mir -0,16 und bei SDC 1.5 Angezeigt

jurs

#10
Jan 30, 2014, 07:07 pm Last Edit: Jan 30, 2014, 09:45 pm by jurs Reason: 1

Bei SDA wird mir -0,16 und bei SDC 1.5 Angezeigt


Das sieht nicht gut aus!

Ähem, das habe ich vergessen, dazu zu schreiben: Bei LAUFENDEM MESS-SKETCH die Spannung messen!
Hast Du?

Hier nochmal ein kleiner Test-Sketch (nur für die Spannungsmessung):
Code: [Select]

#include <Wire.h>

void setup() {
 Wire.begin();
}

void loop() {
}


Mal alle Hardware abschließen vom Arduino-Board und das nackte Board messen (bei laufendem Test-Sketch):
Spannung GND-SDA?
Spannung GND- SCL?

Dann das Breakout-Board mit dem BMP085 wieder an den Arduino anschließen und nochmal messen:
Spannung GND-SDA?
Spannung GND- SCL?

Nachtrag: Um Probleme mit der von Dir verwendeten Library auszuschließen, hänge ich hier noch einen Test-Sketch bei, der ohne Library von Drittanbietern funktioniert, nur mit der Arduino-eigenen Wire-Library.

Code: [Select]
/* BMP085 Extended Example Code
  by: Jim Lindblom
  SparkFun Electronics
  date: 1/18/11
  license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/
 
  Get pressure and temperature from the BMP085 and calculate altitude.
  Serial.print it out at 9600 baud to serial monitor.

  Update (7/19/11): I've heard folks may be encountering issues
  with this code, who're running an Arduino at 8MHz. If you're
  using an Arduino Pro 3.3V/8MHz, or the like, you may need to
  increase some of the delays in the bmp085ReadUP and
  bmp085ReadUT functions.
*/

#include <Wire.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;

short temperature;
long pressure;

void setup()
{
  Serial.begin(9600);
  Wire.begin();
  bmp085Calibration();
}

void loop()
{
  temperature = bmp085GetTemperature(bmp085ReadUT());
  pressure = bmp085GetPressure(bmp085ReadUP());
  Serial.print("Temperature: ");
  Serial.print(temperature, DEC);
  Serial.println(" *0.1 deg C");
  Serial.print("Pressure: ");
  Serial.print(pressure, DEC);
  Serial.println(" Pa");
  Serial.println();
  delay(1000);
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
  long x1, x2;
 
  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  return ((b5 + 8)>>4); 
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;
 
  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
 
  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
 
  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;
   
  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;
 
  return p;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;
 
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
 
  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;
   
  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;
 
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();
 
  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();
 
  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
  unsigned int ut;
 
  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();
 
  // Wait at least 4.5ms
  delay(5);
 
  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;
 
  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();
 
  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));
 
  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF6);
  Wire.endTransmission();
  Wire.requestFrom(BMP085_ADDRESS, 3);
 
  // Wait for data to become available
  while(Wire.available() < 3)
    ;
  msb = Wire.read();
  lsb = Wire.read();
  xlsb = Wire.read();
 
  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
 
  return up;
}


rudirabbit

#11
Jan 30, 2014, 07:16 pm Last Edit: Jan 30, 2014, 07:22 pm by rudirabbit Reason: 1
Muss mich berichtigen, ich habe nicht genau dein Modul.

Sind bei diesen Messungen wirklich die Pullup Widerstände aktiv ?

Bei deinem Modul fällt mir auf, das die Pullupwiderstande  mit einer Lötbrücke (SJ1) auf VDDIO zu setzen sind.
Und VDDIO (Pin1) auf 5V,  so mein Gedanke.
Lasse dir das aber noch bestätigen, möchte nicht schuld sein wenn du so deinen bmp geschrottet hast.    
Arduino UNO,MEGA,DUE 
Dunkel die andere Seite ist. - Klappe, Yoda, und iss deinen Toast :-)

SkobyMobil

Hallo,
Du hast Deinen Sensor doch am I2C-Bus des Arduino angeschlossen.
D. h. von Deinem Arduino geht eine Leitung SCL, und eine Leitung SDL ab?
Diese beiden Leitungen sind über je einen Pullup-Widerstand mit Plus
verbunden?
Von dieser Plus-Leitung nimmst Du die Versorgungsspannung für Deinen
Sensor ab?
Wenn Du mehrere I2C-Slave´s am I2C hast, dann haben die auch unterschiedliche
Adressen?
Wenn Du mehrere I2C-Slave´s am I2C hast, dann haben die auch je einen
EntkopplungsKondensator an der Versorgungsspannung?
Die richtige Adresse hast Du in Deinem Sketch eingestellt?
Prüf das doch mal.
Gruß und Spaß
Andreas
die zweite Maus bekommt den Speck...

Go Up