Go Down

Topic: Need a piece of code written (Solved) Thank you wildbill (Read 462 times) previous topic - next topic

Flowsensor

I need help with this code and I am willing to pay! as I will not learn how to do it in this lifetime.

I want to use an Arduino to monitor water flow in a mains pipe (in case of another leak!) and trigger an alarm via a relay, if a pre determined amount of water has flowed through continuously.

I have set up the hardware. I found this code on the internet. It reads the flow via a flow sensor and triggers a relay if 5000 (arbitrary figure for test purposes) milliliters have passed. All this suits my needs, however, with this code, if the flow sensor stops before the target, the program remembers the last reading and when the flow sensor starts again it continues counting from that point. I need it to reset the reading to zero each time the flow sensor stops and restart the count.

Only trigger the relay if the target figure is reached in one continuous flow. If the relay is activated, then a manual reset is OK. I hope this is clear to the reader.

Code: [Select]

int sensorInterrupt = 0;  // interrupt 0
int sensorPin       = 2; //Digital Pin 2 // using this design https://www.bc-robotics.com/tutorials/using-a-flow-sensor-with-arduino/
int Relay = 5; // Digital pin 5 // Using SRD--T73_PDF
unsigned int SetPoint = 5000; //5000 milileter

/*The hall-effect flow sensor outputs pulses per second per litre/minute of flow.*/
float calibrationFactor = 4.5; //You can change according to your datasheet

volatile byte pulseCount =0; 

float flowRate = 0.0;
unsigned int flowMilliLitres =0;
unsigned long totalMilliLitres = 0;

unsigned long oldTime = 0;

void setup()
{

  // Initialize a serial connection for reporting values to the host
  Serial.begin(9600);
  pinMode(Relay , OUTPUT);
  pinMode(sensorPin, INPUT);
  digitalWrite(sensorPin, HIGH);

  /*The Hall-effect sensor is connected to pin 2 which uses interrupt 0. Configured to trigger on a FALLING state change (transition from HIGH
  (state to LOW state)*/
  attachInterrupt(sensorInterrupt, pulseCounter, FALLING); //you can use Rising or Falling
}

void loop()
{

   if((millis() - oldTime) > 1000)    // Only process counters once per second
  {
    // Disable the interrupt while calculating flow rate and sending the value to the host
    detachInterrupt(sensorInterrupt);

    // Because this loop may not complete in exactly 1 second intervals we calculate the number of milliseconds
    // that have passed since the last execution and use that to scale the output. We also apply the calibrationFactor
    // to scale the output based on the number of pulses per second per units of measure (litres/minute in this case) coming from the sensor.
    flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;

    // Note the time this processing pass was executed. Note that because we've
    // disabled interrupts the millis() function won't actually be incrementing right
    // at this point, but it will still return the value it was set to just before
    // interrupts went away.
    oldTime = millis();

    // Divide the flow rate in litres/minute by 60 to determine how many litres have
    // passed through the sensor in this 1 second interval, then multiply by 1000 to
    // convert to millilitres.
    flowMilliLitres = (flowRate / 60) * 1000;

    // Add the millilitres passed in this second to the cumulative total
    totalMilliLitres += flowMilliLitres;

    unsigned int frac;

    // Print the flow rate for this second in litres / minute
    Serial.print("Flow rate: ");
    Serial.print(flowMilliLitres, DEC);  // Print the integer part of the variable
    Serial.print("mL/Second");
    Serial.print("t");           

    // Print the cumulative total of litres flowed since starting
    Serial.print("Output Liquid Quantity: ");       
    Serial.print(totalMilliLitres,DEC);
    Serial.println("mL");
    Serial.print("t");
           
    if (totalMilliLitres > 5000)
    {
      SetRelay ();
    }
// Reset the pulse counter so we can start incrementing again
    pulseCount = 0;

    // Enable the interrupt again now that we've finished sending output
    attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
  }
}

//Insterrupt Service Routine

void pulseCounter()
{
  // Increment the pulse counter
  pulseCount++;
}

void SetRelay()
{
  digitalWrite(Relay, HIGH);
}



wildbill

Is it enough to assume that if there was no flow during any particular second, that there is no leak? If so, try replacing:
Code: [Select]

    // Reset the pulse counter so we can start incrementing again
    pulseCount = 0;
    // Enable the interrupt again now that we've finished sending output
    attachInterrupt(sensorInterrupt, pulseCounter, FALLING);

with:
Code: [Select]

    // Reset the pulse counter so we can start incrementing again
    pulseCount = 0;
    if (flowRate == 0)
    {
      totalMilliLitres = 0;
    }
    // Enable the interrupt again now that we've finished sending output
    attachInterrupt(sensorInterrupt, pulseCounter, FALLING);

wvmarle

Flow sensor measures pulses.

"No flow" means in that case "no pulses for a certain amount of time". You should define this time. Reset the timer every time you have a pulse, and if more than a certain time passed without pulses reset it.
Quality of answers is related to the quality of questions. Good questions will get good answers. Useless answers are a sign of a poor question.

Go Up