Go Down

Topic: Projet cibles basculantes motorisées (Read 159 times) previous topic - next topic

Franck39

Feb 14, 2020, 04:37 pm Last Edit: Feb 14, 2020, 04:41 pm by Franck39
Bonjour à tous,

Débutant dans l'univers Arduino, je tente difficilement de faire fonctionner mon projet de cibles basculantes motorisées.

Voici ce à quoi j'aimerai arriver:

3 cibles basculantes (imprimées en 3D) sont équipées d'une led et d'un tilt (type SW-200D) chacune.
Dès que les trois tilts sont low, donc les 3 cibles basculées, un servo moteur les relèvent.
J'aimerai avoir vos conseil pour ajouter l'allumage aléatoire d'une des trois leds (cibles) mais uniquement parmi les cibles non low.

Le code que j'ai réalisé avec Tinkercad:

Code: [Select]
#include <Servo.h>

int tilt1 = 0;

int tilt2 = 0;

int tilt3 = 0;

Servo servo_8;

void setup()
{
  pinMode(5, INPUT);
  pinMode(6, INPUT);
  pinMode(7, INPUT);
  servo_8.attach(8);

  pinMode(10, OUTPUT);
  pinMode(11, OUTPUT);
  pinMode(12, OUTPUT);
}

void loop()
{
  tilt1 = digitalRead(5);
  tilt2 = digitalRead(6);
  tilt3 = digitalRead(7);
  if (tilt1 == LOW && (tilt2 == LOW && tilt3 == LOW)) {
    servo_8.write(90);
  } else {
    servo_8.write(0);
  }
  if (tilt1 == HIGH) {
    digitalWrite(10, HIGH);
  } else {
    digitalWrite(10, LOW);
  }
  if (tilt2 == HIGH) {
    digitalWrite(11, HIGH);
  } else {
    digitalWrite(11, LOW);
  }
  if (tilt3 == HIGH) {
    digitalWrite(12, HIGH);
  } else {
    digitalWrite(12, LOW);
  }
  delay(10); // Delay a little bit to improve simulation performance
}


Merci d'avance pour votre aide


hbachetti

Linux is like a wigwam: no Windows, no Gates, and an Apache inside ...

Franck39


hbachetti

Linux is like a wigwam: no Windows, no Gates, and an Apache inside ...

Franck39

As-tu regardé du côté de random() ?

oui mais je ne sais pas comment dire à random de choisir uniquement parmi les titls toujours high

hbachetti


Il va seulement te permettre de choisir un numéro entre 0 (aucun TILT HIGH) et N (nombre de tilts HIGH).

C'est à toi de déterminer quels sont les tilts HIGH.
Linux is like a wigwam: no Windows, no Gates, and an Apache inside ...

hbachetti

Tu devrais adopter une structure en tableau :

Code: [Select]

int tilt1 = 0;
int tilt2 = 0;
int tilt3 = 0;
// tableau
#define NTILTS    3

int tilt[NTILTS] = {0, 0, 0};
// ensuite
  for (int i = 0 ; i < NTILTS ; i++) {
    tilt[i] = digitalRead(tiltPin[i]);
  }
// ainsi de suite ...


Cela simplifierait les choses.
Linux is like a wigwam: no Windows, no Gates, and an Apache inside ...

hbachetti

#7
Feb 14, 2020, 07:07 pm Last Edit: Feb 14, 2020, 07:21 pm by hbachetti
Tu es sûr de ceci :
Code: [Select]

  pinMode(5, INPUT);

Tu as des résistances de PULL_DOWN ?
Linux is like a wigwam: no Windows, no Gates, and an Apache inside ...

hbachetti

J'ai réfléchi à ton problème.

Il te faut une fonction qui récupère la liste des tilts HIGH :

Code: [Select]

int getHighTilts(int *highTilts)
{
  int index = 0;
  int n = 0;

  for (int i = 0 ; i < NTILTS ; i++) {
    if (tilt[i] == HIGH) {
      highTilts[index] = i;
      n ++;
    }
  }
  return n;
}

  // dans loop()
  int nTiltsHigh;
  int highTilts[NTILTS];

  nTiltsHigh = getHighTilts(highTilts);


Ensuite il faut mémoriser le nombre de tilts HIGH afin d'allumer une LED seulement si ce nombre change.

Code: [Select]

  // dans setup
  randomSeed(analogRead(0)); // initialiser le générateur

  // dans loop()
  static int nPrevTiltsHigh;

  if (nTiltsHigh != nPrevTiltsHigh) {
    // on éteint tout
    for (int i = 0 ; i < NTILTS ; i++) {
      digitalWrite(ledPin[i], LOW);
    }
    int randNumber = random(nTiltsHigh);
    // on allume la LED random
    digitalWrite(randNumber, HIGH);
    // on mémorise
    nPrevTiltsHigh = nTiltsHigh;
  }


Cela devrait ressembler à quelque chose d'assez proche.
Linux is like a wigwam: no Windows, no Gates, and an Apache inside ...

Franck39

J'ai réfléchi à ton problème.

Il te faut une fonction qui récupère la liste des tilts HIGH :

Code: [Select]

int getHighTilts(int *highTilts)
{
  int index = 0;
  int n = 0;

  for (int i = 0 ; i < NTILTS ; i++) {
    if (tilt[i] == HIGH) {
      highTilts[index] = i;
      n ++;
    }
  }
  return n;
}

  // dans loop()
  int nTiltsHigh;
  int highTilts[NTILTS];

  nTiltsHigh = getHighTilts(highTilts);


Ensuite il faut mémoriser le nombre de tilts HIGH afin d'allumer une LED seulement si ce nombre change.

Code: [Select]

  // dans setup
  randomSeed(analogRead(0)); // initialiser le générateur

  // dans loop()
  static int nPrevTiltsHigh;

  if (nTiltsHigh != nPrevTiltsHigh) {
    // on éteint tout
    for (int i = 0 ; i < NTILTS ; i++) {
      digitalWrite(ledPin[i], LOW);
    }
    int randNumber = random(nTiltsHigh);
    // on allume la LED random
    digitalWrite(randNumber, HIGH);
    // on mémorise
    nPrevTiltsHigh = nTiltsHigh;
  }


Cela devrait ressembler à quelque chose d'assez proche.

Merci beaucoup, je vais tester :)

hbachetti

OK.
J'espère que les tilts restent dans un état stable.
C'est à dire HIGH = cible relevée.
C'est à dire LOW = cible abaissée.
Apparemment c'est un capteur à bille, pas un simple capteur de choc à lame ?
Linux is like a wigwam: no Windows, no Gates, and an Apache inside ...

J-M-L

#11
Feb 14, 2020, 11:33 pm Last Edit: Feb 15, 2020, 10:21 am by J-M-L
Voulez vous qu'une cible (led) soit choisie pendant un temps donné avant de passer à une autre ?
Que se passe-t-il si on rate la cible allumée mais qu'on en touche une autre ?
La remontée des cibles est elle possible individuellement ou toutes les cibles sont reliées ?

d'un point de vue algorithmique, vous souhaitez faire un tri aléatoire jusqu'à épuisement des éléments d'un tableau. La première solution qui vient à l'esprit consisterait à générer un indice aléatoire et vérifier si l'élément figurant à cet indice a déjà été tiré, et si tel est le cas, recommencer. c'est pas super efficace car moins il reste d'éléments dans le tableau et plus le risque de prendre du temps avant d'en trouver un est grand.

Une solution plus élégante se fonde l'algorithme de Fisher-Yates (mélange de Fisher-Yates / mélange de Knuth).

L'idée est de trier le tableau dans un ordre aléatoire, puis de tirer un à un ses éléments, en le parcourant séquentiellement depuis le début.

Pour mélanger un tableau a de n éléments (indicés de 0 à n-1), l'algorithme est le suivant.

Code: [Select]
Pour i allant de n − 1 à 1 faire :
       j ← entier aléatoire entre 0 et i
       échanger tableau[j] et tableau[i]


ensuite dans le code on peut décider de mélanger une fois, ou à chaque fois qu'on a présenter chaque cible une fois. ça pourrait ressembler à cela (un vieil exemple que j'avais)
Code: [Select]
//---------------------------------------------------------------------------------
// TIR AU PIGEON
// Copyright © (c) 2016  J-M-L
// The MIT License (MIT)
//
// Permission is hereby granted, free of charge, to any person obtaining a copy
// of this software and associated documentation files (the "Software"), to deal
// in the Software without restriction, including without limitation the rights
// to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
// copies of the Software, and to permit persons to whom the Software is
// furnished to do so, subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in
// all copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
// OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
// THE SOFTWARE.
//---------------------------------------------------------------------------------

const uint32_t tempsParCible = 1000000UL; // une seconde pour tirer sur la cible max en microsecondes

struct cible_t {
  uint8_t numero;
  uint8_t pinCapteur;
  uint8_t pinLED;
  bool cibleActive;
} cibles[] = {
  { 1, 2, 3, true},  // N° de cible, pin du capteur, pin de la LED, cible Activée
  { 2, 4, 5, true},
  { 3, 6, 7, true},
  { 4, 8, 9, true},
  { 5, 10, 11, true},
  { 6, 12, 13, true},
  { 7, A0, A1, true},
  { 8, A2, A3, true},
};

const uint8_t nombreTotalDeCibles = sizeof(cibles) / sizeof(cibles[0]);

int16_t nombreDeCiblesRestantes;
uint8_t indexCibleEnCours;

uint32_t tempsTotal;

void imprimeCibles()
{

  for (uint8_t i = 0; i < nombreTotalDeCibles; i++) {
    if (cibles[i].cibleActive) Serial.print(cibles[i].numero);
    else Serial.print('x');
    Serial.print(' ');
  }
  Serial.println();
}

void melangeCibles()
{
  // mélange de Fisher-Yates cf https://fr.wikipedia.org/wiki/Mélange_de_Fisher-Yates
  for (uint8_t i = nombreTotalDeCibles - 1; i >= 1; --i) {
    uint8_t j = random(0, i + 1);
    cible_t temporaire = cibles[i];
    cibles[i] = cibles[j];
    cibles[j] = temporaire;
  }
  imprimeCibles();
}

void resetCibles()
{
  // on secoue un peu la génération de nombres aléatoires
  randomSeed(analogRead(A5));

  // commander le moteur pour relever toutes le cibles
  // ...

  // mettre toutes les cibles actives
  for (uint8_t i = 0; i < nombreTotalDeCibles; i++)
    cibles[i].cibleActive = true;

  imprimeCibles();
  melangeCibles();

  nombreDeCiblesRestantes = nombreTotalDeCibles;
  indexCibleEnCours = 0; // la première du tableau mélangé
  tempsTotal = 0;
}

void setup() {
  Serial.begin(115200);

  // on met les pins des capteurs en PULL-UP et les LEDs en sortie
  for (uint8_t i = 0; i < nombreTotalDeCibles; i++) {
    pinMode(cibles[i].pinCapteur, INPUT_PULLUP);
    pinMode(cibles[i].pinLED, OUTPUT);
  }

  // on prépare une séquence de jeu
  resetCibles();
}

void loop()
{

  if (nombreDeCiblesRestantes > 0) {

    Serial.print(F("Tirez sur la cible #"));
    Serial.print(cibles[indexCibleEnCours].numero);

    digitalWrite(cibles[indexCibleEnCours].pinLED, HIGH); // allume cette LED

    // on teste si la cible a été touchée, le tireur a un certain temps pour tirer
    uint32_t chrono = micros();
    while (micros() - chrono < tempsParCible) {
      // =====================================================
      // A METTRE DANS LA VERSION FINALE
      //      if (digitalRead(cibles[indexCibleEnCours].pinCapteur) == LOW) { // cible touchée
      //        cibles[indexCibleEnCours].cibleActive = false;
      //        Serial.println(F("\tTOUCHEE"));
      //        nombreDeCiblesRestantes--;
      //        break;
      //      }
      // =====================================================
    }
    tempsTotal += micros() - chrono;

    // =====================================================
    // A ENLEVER DANS LA VERSION FINALE
    // on simule un tir réussi à 50%
    if (random(0, 10) >= 5) { // on l'a eue
      cibles[indexCibleEnCours].cibleActive = false;
      Serial.println(F("\tTOUCHEE"));
      nombreDeCiblesRestantes--;
    }
    else Serial.println(F("\tRATEE"));
    // =====================================================

    digitalWrite(cibles[indexCibleEnCours].pinLED, LOW); // éteint cette LED

    // on passe à la cible suivante
    if (nombreDeCiblesRestantes) {
      // on cherche la prochaine qui n'est pas tombée
      do {
        indexCibleEnCours++;
        if (indexCibleEnCours >= nombreTotalDeCibles) {  // plus rapide que de faire modulo
          indexCibleEnCours = 0;
          imprimeCibles(); // imprime un résumé de là où on en est
          if (nombreDeCiblesRestantes > 1) melangeCibles(); // éventuellement on re-mélange
        }
      } while (!cibles[indexCibleEnCours].cibleActive);
    }
  } else {
    // gagné !
    Serial.print(F("BRAVO, TEMPS = "));
    Serial.print(tempsTotal / 1000000.0);
    Serial.println(F(" secondes\n\n"));
    delay(2000);
    resetCibles();
  }

}


Hello - Please do not PM me for help,  others will benefit as well if you post your question publicly on the forums.
Bonjour Pas de messages privés SVP, postez dans le forum directement pour que ça profite à tous

Go Up