2 Parallax RFID Reader + Arduino Mega

Hi I am working on a project that uses 2 parallax rfid reader connected to an arduino mega. I am just trying a simple program to make sure the 2 readers will light up separate LEDs when they read a tag. I am using the hardware serial ports on the Mega.

The problem is when I connected both readers to the Mega, only one of the readers lights up an LED. I tried testing the readers individually and they work fine on their own. I am not sure how to get the readers to read tags separately.

I used the MultiSerialMega sample code as a template for my code.

#define RFIDSerialRate 2400 

int led1 = 11;
int led2 = 5;

void setup() 
{
  Serial1.begin(RFIDSerialRate);
  Serial2.begin(RFIDSerialRate);
  
  pinMode(2,OUTPUT); 
  pinMode(3, OUTPUT);
  pinMode(led1, OUTPUT);
  pinMode(led2, OUTPUT);
  
  digitalWrite(2, LOW);
  digitalWrite(3, LOW);

  Serial.begin(9600);          
}

void loop() 
{
  if(Serial1.available()) 
  { 
    Serial.println("Test1");
    digitalWrite(led1, HIGH);
    delay(2000);
    digitalWrite(led1, LOW);
    delay(2000);
  }

  if(Serial2.available()) 
  { 
    Serial.println("Test2");
    digitalWrite(led2, HIGH);
    delay(2000);
    digitalWrite(led2, LOW);
    delay(2000);
  }
}

There is nowhere in your code that you actually do a serial read. That means that the characters remain in the buffer so next time you check for the serial available it will still be true. You will have to purge the buffer.
Also using delay the way you do will block the cpu for 4 full seconds.

#define RFIDSerialRate 2400 

int led1 = 11;
int led2 = 5;

unsigned long reader1Blink;
unsigned long reader2Blink;

void setup(){
  Serial1.begin(RFIDSerialRate);
  Serial2.begin(RFIDSerialRate);
  
  pinMode(2,OUTPUT); 
  pinMode(3, OUTPUT);
  pinMode(led1, OUTPUT);
  pinMode(led2, OUTPUT);
  
  digitalWrite(2, LOW);
  digitalWrite(3, LOW);

  Serial.begin(9600);          
}//setup()

void loop(){
  if(Serial1.available()){ 
    Serial.println("Test1");
    reader1Blink = millis()+500;
    while(Serial1.available()) Serial1.read();//purge buffer
  }//if(Serial1)

  if(Serial2.available()){ 
    Serial.println("Test2");
    reader2Blink = millis()+500;
    while(Serial2.available()) Serial2.read();//purge buffer
  }//if(Serial2)
  
  digitalWrite(led1, reader1Blink>millis());
  digitalWrite(led2, reader2Blink>millis());
}//loop()