Aeroponics: using many sensors and outputs with Arduino Uno/Ethernet sheild

So I am pretty new to electronics but have a background in programming.
Here is my personal research project: I want to see how plants grow using aeroponics (growing plants in nutrient rich fog) and use arduino to monitor and act as a timer for my red and blue LEDs and oscillator. I hope to monitor through a website I am in the process of making by sending my data from my arduino Uno ->ethernet shield ->Xively → webpage.
My problem is in the wiring of the sensors. So far I have done some simple code for individual sensors but I cannot figure how to connect them all to the arduino’s one power outlet. Do I need to wire them in parallel or some other configuration?
I also want to use a DS1307 Real Time Clock module and connect to my oscillator(a hacked computer fan) and LED panel( still working on what this would be made of). I can totally code this but do you have any suggestion on the wiring?

So far these work individually
pH meter: http://www.dfrobot.com/index.php?route=product/product&product_id=1025#.UyPlPq1dXtd

#include <Xively.h> //Xively library
#include <SPI.h>
#include <Ethernet.h>
#include <HttpClient.h>

//Arduino key for Xively
char xivelyKey[] = "my key"; 
//key for Ethernet sheild
byte mac[] = {0x90, 0xA2, 0xDA, 0x0E, 0xFE, 0xD7};

//Define variables and pins

int pHpin = 0;
#define Offset 0.00            //deviation compensate
unsigned long int avgValue;    //Store the average value of the sensor feedback


//array of sensor datastreams
char sensorId4[] = "pH";

XivelyDatastream datastreams[] = {
  XivelyDatastream(sensorId4, strlen(sensorId4), DATASTREAM_FLOAT),};
  
  // Wrap the datastreams into a feed
XivelyFeed feed(1578014314, datastreams, 1 /* number of datastreams */);


EthernetClient client;
XivelyClient xivelyclient(client);

void setup(){
  Serial.begin(9600);
  Serial.println("Starting single datastream upload to Xively...");
  Serial.println();

  while (Ethernet.begin(mac) != 1)
  {
    Serial.println("Error getting IP address via DHCP, trying again...");
    delay(15000);
  }
  
}

void loop(){
int buf[10];                //buffer for read analog
  for(int i=0;i<10;i++)       //Get 10 sample value from the sensor for smooth the value
  { 
    buf[i]=analogRead(pHpin);
    delay(10);
  }
  for(int i=0;i<9;i++)        //sort the analog from small to large
  {
    for(int j=i+1;j<10;j++)
    {
      if(buf[i]>buf[j])
      {
        int temp=buf[i];
        buf[i]=buf[j];
        buf[j]=temp;
      }
    }
  }
  avgValue=0;
  for(int i=2;i<8;i++)                      //take the average value of 6 center sample
    avgValue+=buf[i];
  float phValue=(float)avgValue*5.0/1024/6; //convert the analog into millivolt
  phValue=3.5*phValue+Offset; 
  
  datastreams[0].setFloat(phValue);
 
 Serial.print("Read sensor value ");
  Serial.println(datastreams[0].getFloat()); 
  Serial.println("Uploading it to Xively");
  int ret = xivelyclient.put(feed, xivelyKey);
  Serial.print("xivelyclient.put returned ");
  Serial.println(ret);
  Serial.println();
  delay(6000);
}

DHT22 temperature/humidity sensor:https://www.adafruit.com/products/385

//Just temp sensor

#include <Xively.h> //Xively library
#include <dht.h>    //temperature/humidity libray
#include <SPI.h>
#include <Ethernet.h>
#include <HttpClient.h>

//Arduino key for Xively
char xivelyKey[] = "key"; 
//key for Ethernet shield
byte mac[] = {0x90, 0xA2, 0xDA, 0x0E, 0xFE, 0xD7};
IPAddress ip(my ip); 

//Define Pins
int dhtPin = 2;
 #define DHTTYPE DHT22
 dht DHT;
 
//variables 
 int temp = 0;
 int humidity = 0;
 
//array of sensor datastreams
char sensorId1[] = "Temperature";
char sensorId2[] = "Humidity";

XivelyDatastream datastreams[] = {
  XivelyDatastream(sensorId1, strlen(sensorId1), DATASTREAM_FLOAT),
XivelyDatastream(sensorId2, strlen(sensorId2), DATASTREAM_FLOAT),};
  
  // Wrap the datastreams into a feed
XivelyFeed feed(1578014314, datastreams, 2 /* number of datastreams */);


EthernetClient client;
XivelyClient xivelyclient(client);

void setup(){
  Serial.begin(9600);
Serial.println("Starting single datastream upload to Xively...");
  Serial.println();

  while (Ethernet.begin(mac) != 1)
  {
    Serial.println("Error getting IP address via DHCP, trying again...");
    delay(15000);
  }
}

void loop(){
  int tempHsensor = DHT.read22(dhtPin);
  temp = DHT.temperature;
  humidity = DHT.humidity;
  
 datastreams[0].setFloat(temp); //temp
 datastreams[1].setFloat(humidity);//humidity

 
 //sending values to Xively
  for(int i=0; i<=1; i++){
   Serial.print("Read sensor value ");
  Serial.println(datastreams[i].getFloat()); 
  Serial.println("Uploading it to Xively");
  int ret = xivelyclient.put(feed, xivelyKey);
  Serial.print("xivelyclient.put returned ");
  Serial.println(ret);
  Serial.println();
  }
  
  delay(5000);
  
}

and a water level sensor Water sensor brick: http://www.sainsmart.com/sainsmart-water-sensor-free-cables-arduino-compatile.html?___store=en&___store=en

//try for analog

#include <Xively.h> //Xively library
#include <SPI.h>
#include <Ethernet.h>
#include <HttpClient.h>

//Arduino key for Xively
char xivelyKey[] = "key"; 
//key for Ethernet shield
byte mac[] = {0x90, 0xA2, 0xDA, 0x0E, 0xFE, 0xD7};
IPAddress ip(my ip); 

//Define pins and variables
int waterLevelPin = 1;
int data = 0;

//array of sensor datastreams
char sensorId3[] = "Water_Level";

XivelyDatastream datastreams[] = {
  XivelyDatastream(sensorId3, strlen(sensorId3), DATASTREAM_FLOAT),};
  
  // Wrap the datastreams into a feed
XivelyFeed feed(1578014314, datastreams, 1 /* number of datastreams */);


EthernetClient client;
XivelyClient xivelyclient(client);

void setup(){
  Serial.begin(9600);
Serial.println("Starting single datastream upload to Xively...");
  Serial.println();

  while (Ethernet.begin(mac) != 1)
  {
    Serial.println("Error getting IP address via DHCP, trying again...");
    delay(15000);
  }
}

void loop(){
  
  data = analogRead (waterLevelPin); 
 datastreams[0].setFloat(data);
 
 Serial.print("Read sensor value ");
  Serial.println(datastreams[0].getFloat()); 
  Serial.println("Uploading it to Xively");
  int ret = xivelyclient.put(feed, xivelyKey);
  Serial.print("xivelyclient.put returned ");
  Serial.println(ret);
  Serial.println();
  delay(6000);
}

Do I need to wire them in parallel or some other configuration?

Yes. Since you haven't defined what sensors you are powering, that's the best answer I can give.

So far I have done some simple code for individual sensors but I cannot figure how to connect them all to the arduino's one power outlet.

As long as the sensors do not draw more current than the Arduino can provide, you can connect any number of wires to this pin. Of course, it's simpler to connect the power pin of the Arduino to the power rail on a breadboard, and make the rest of the connections to the same power rail on the breadboard. The same holds true of the ground pin/rail, too.

Sketch:
Make a layout for your sketch.
You need functions for the seperate parts.
For myself, I would prefer to fill a the data (you can use seperate variables, or a few arrays, or even a structure), and once it is filled, translate the data to upload to Xively. I would use a structure of data, with timestamps for every sensor value. The structure itself has no use, but it just shows what the data is.
Do you know how to make new files in a project ? Use the drop-down-menu on the right side of the Arduino IDE.
So you can put the function for example for the DHT11 in its own file.

Uno:
I don’t know if all the extra code will fit in the Arduino Uno. If you want to use all those sensors and also the SD card, you might need an Arduino Mega 2560.

PH-sensors:
They use 5V, have analog output and use very little current. Perhaps the led uses the most current.
You can power all of them with 5V. You need an analog input for each PH-sensor.
You have to make a function to get a valid PH value from a sensor. For example : getPH (number_sensor);

Time:
If you are connected to internet, you can request the time from a NTP service.

DHT11:
Every DHT11 must have it’s own Arduino digital pin. You use the code to get the temperature and humidity for a certain sensor. That code should ofcourse be in a function. You can power them all with the 5V ofcourse, and the data pin needs pull-up resistors.

Suggestion: Remove everything except the DHT22. Make a test sketch and test the return value to see if there is an error.

The DHT22 is very timing specific. If interrupt from the Ethernet library is in between, the timing for the DHT22 might be wrong.
The Adafruit disables interrupts a short moment for the timing of the DHT22. I don't like that. I do not disable the interrupts and let the DHT22 be requested in the background. Two global variables for temperature and humidity are only updated if the DHT22 would give a good value.

Thank you for all your suggestions. Sorry I am replying so late- had finals and did not have time to work on my project.

So far I have hooked up the water level sensor, pH, and DHT22 (with a 4.7K - 10K resistor)sensor in parallel. The problem is that I cannot get the DHT22 sensor data. It does not even work when it is the only one connected. So either my sensor is dead, its a wiring problem or my code is wrong. Any suggestions? I am also getting “avrdude: stk500_getsync(): not in sync: resp=0x00” when I upload. I have tried pressing the reset button and disconnecting and I still get the message.

Below is my code

#include <Xively.h> //Xively library
#include <SPI.h>
#include <Ethernet.h>
#include <HttpClient.h>
#include <dht.h>    //temperature/humidity library

//Arduino key for Xively
char xivelyKey[] = "my key"; 
//key for Ethernet shield
byte mac[] = {0x90, 0xA2, 0xDA, 0x0E, 0xFE, 0xD7};

//Define pins
int DHTpin = 5;
int pHpin = 0;
int waterLevelPin = 1;

//Define variable
int temp = 0;
int humidity = 0;
int waterLevel = 0;
#define Offset 0.00            //deviation compensate
unsigned long int avgValue;    //Store the average value of the sensor feedback
dht DHT;
//array of sensor datastreams
char sensorID1[]= "pH";
char sensorID2[]= "Temperature";
char sensorID3[]= "Humidity";
char sensorID4[]= "Water Level";


XivelyDatastream datastreams[] = {
  XivelyDatastream(sensorID1, strlen(sensorID1), DATASTREAM_FLOAT),
  XivelyDatastream(sensorID2, strlen(sensorID2), DATASTREAM_FLOAT),
  XivelyDatastream(sensorID3, strlen(sensorID3), DATASTREAM_FLOAT),
  XivelyDatastream(sensorID4, strlen(sensorID4), DATASTREAM_FLOAT),};
  
  // Wrap the datastreams into a feed
XivelyFeed feed(1578014314, datastreams, 4 /* number of datastreams */);


EthernetClient client;
XivelyClient xivelyclient(client);

//Setup of system
void setup(){
  Serial.begin(9600);
  Serial.println("Starting single datastream upload to Xively...");
  Serial.println();

  while (Ethernet.begin(mac) != 1)
  {
    Serial.println("Error getting IP address via DHCP, trying again...");
    delay(15000);
  }
  
}
//general outline of getting and sending data
void loop(){
  phGetData();
  tempHumGetData();
  waterLevelGetData();
  sendData();
  delay(1000);
}

void phGetData(){
  //gets pH data from analog pH sensor and stores in array
  int buf[10];                //buffer for read analog
  for(int i=0;i<10;i++)       //Get 10 sample value from the sensor for smooth the value
  { 
    buf[i]=analogRead(pHpin);
    delay(10);
  }
  for(int i=0;i<9;i++)        //sort the analog from small to large
  {
    for(int j=i+1;j<10;j++)
    {
      if(buf[i]>buf[j])
      {
        int temp=buf[i];
        buf[i]=buf[j];
        buf[j]=temp;
      }
    }
  }
  avgValue=0;
  for(int i=2;i<8;i++)                      //take the average value of 6 center sample
    avgValue+=buf[i];
  float phValue=(float)avgValue*5.0/1024/6; //convert the analog into millivolt
  phValue=3.5*phValue+Offset; 
  
  datastreams[0].setFloat(phValue);
  
}

void tempHumGetData(){
  //gets humidity and temp data digital from DHT and stores in array
  int tempHsensor = DHT.read22(DHTpin);
  temp = DHT.temperature;
  humidity = DHT.humidity;
  
 datastreams[1].setFloat(temp); //temp
 datastreams[2].setFloat(humidity);//humidity

}

void waterLevelGetData(){
  //gets approx water level analog and stores in array
  waterLevel = analogRead (waterLevelPin); 
 datastreams[3].setFloat(waterLevel);
}

void sendData(){
  for(int i=0; i<=3; i++){
   Serial.print("Read sensor value ");
  Serial.println(datastreams[i].getFloat()); 
  Serial.println("Uploading it to Xively");
  int ret = xivelyclient.put(feed, xivelyKey);
  Serial.print("xivelyclient.put returned ");
  Serial.println(ret);
  Serial.println();
  }
}