analog input e blink without delay: aiuto!

International Italiano Software
1

Ciao a tutti,
non ne vengo fuori e vi chiedo un aiuto.
Devo azionare dei rele e contemporaneamente acquisire degli analog input ed altri segnali via I2C.
Ho provato ad integrare un programma di acquisizione per un HST1x (temperatura ed umidità) con l'esempio del blinkwithoutdelay. Non funziona! In pratica il led lampeggia con il delay e non con la sua routine.
Qualcuno mi può dire dove sbaglio?
Grazie in anticipo a tutti.
Andrea.

#include <SHT1x.h>
#define dataPin  22  // DATA
#define clockPin 24  // SCK
SHT1x sht1x(dataPin, clockPin); // temp and humidity sensor

                                          // constants won't change. Used here to 
                                         // set pin numbers:
const int ledPin =  2;      // the number of the LED pin

                                      // Variables will change:
int ledState = LOW;             // ledState used to set the LED
long previousMillis = 0;        // will store last time LED was updated

                                          // the follow variables is a long because the time, measured in miliseconds,
                                            // will quickly become a bigger number than can be stored in an int.
long interval = 1000;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);   
 Serial.begin(9600);
   Serial.println("Starting up");
   Serial.print("Temperature: ");
   Serial.println("F. Humidity: "); 
}

void loop()
{
                                               // here is where you'd put code that needs to be running all the time.

                                            // check to see if it's time to blink the LED; that is, if the 
                                                // difference between the current time and last time you blinked 
                                        // the LED is bigger than the interval at which you want to 
                                            // blink the LED.
  unsigned long currentMillis = millis();
 
  if(currentMillis - previousMillis > interval) {
                                                   // save the last time you blinked the LED 
    previousMillis = currentMillis;   

                                                      // if the LED is off turn it on and vice-versa:
    if (ledState == LOW)
      ledState = HIGH;
    else
      ledState = LOW;

                                                 // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
  }
{  
  float temp_c;
  float humidity;                 
  temp_c = sht1x.readTemperatureC();
  humidity = sht1x.readHumidity();
  {
  
  }
  Serial.print(temp_c);
  Serial.print(" ");
  Serial.print(",");
  Serial.print(humidity);
  Serial.print(" ");
  Serial.println(",");
  
  
  delay(5000); 
    
  }
}
2

Intanto crea le variabili tutte dello stesso tipo unsigned, mischi "long" (previousMillis e interval) con "unsigned long" (currentMillis).

Poi se metti un delay alla fine del loop, il delay ti bloccherà tutto. Devi replicare ciò che hai fatto in precedenza con un altro controllo su millis con un intervallo con 5000 ms.

3

Grazie mille per la risposta.
Ok per gli unsigned ecc, hai ragione.
Scusa ma non ho capito il secondo consiglio: se lascio un delay sui dati che acquisisco dal SHTX1 DI 5000 msec non dovrebbe influenzare la sequenza di on off che ha un tempo di 1000 msec.
Poi nn ho capito dove devo "Devi replicare ciò che hai fatto in precedenza con un altro controllo su millis con un intervallo con 5000 ms."
Grazie per la pazienza.
Andrea.

4

Il delay è alla fine del ciclo loop per cui prima di ripartire da capo la CPU esegue quell'istruzione, che blocca il codice per 5 secondi.

5

Una cosa del genere:

#include <SHT1x.h>
#define dataPin  22  // DATA
#define clockPin 24  // SCK
SHT1x sht1x(dataPin, clockPin); // temp and humidity sensor

const int ledPin =  2;      // the number of the LED pin

int ledState = LOW;             // ledState used to set the LED
unsigned long previousMillis = 0;        // will store last time LED was updated
unsigned long interval = 1000;           // interval at which to blink (milliseconds)

unsigned long previousMillis2 = 0;
unsigned long interval2 = 5000; 

unsigned long currentMillis;

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);   
  Serial.begin(9600);
  Serial.println("Starting up");
  Serial.print("Temperature: ");
  Serial.println("F. Humidity: "); 
}

void loop()
{
  currentMillis = millis();

  if(currentMillis - previousMillis > interval) {
    // if the LED is off turn it on and vice-versa:
    if (ledState == LOW)
      ledState = HIGH;
    else
      ledState = LOW;
    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
    // save the last time you blinked the LED 
    previousMillis = currentMillis;   
  }

  if(currentMillis - previousMillis2 > interval2) {
    float temp_c;
    float humidity;                 
    temp_c = sht1x.readTemperatureC();
    humidity = sht1x.readHumidity();  
    Serial.print(temp_c);
    Serial.print(" ");
    Serial.print(",");
    Serial.print(humidity);
    Serial.print(" ");
    Serial.println(",");
    previousMillis2 = currentMillis;   
  }

}

Compila, ma non l'ho verificato sull'Arduino non avendo il sensore.