Arduino and Minecraft

Projects General Guidance
1

I read through an old thread from a user who had inquired if there was an Arduino Minecraft server. Despite a very heavy handed "no", and despite me from being a complete beginner, I am interested in exploring the Arduino and Minecraft. Here then, is my springboard of possible projects. I don't know the feasibility of any of them, except that they must be in the realm of possibility. I would like to open the floor to other users who share in this idea as well.

For your consideration:

Project 1. Arduino as a Minecraft controller. Let's assume iPac does not exist for the moment (because it would be far too easy to get an iPac, add a few switches and call the project done).

Project 2. Arduino to monitor Minecraft variables. This one requires a hell of a lot of patience, and imagination. The idea is to dive right into the source code, and "outsource" a couple of variables that the user might find valuable. For example, a red LED lighting up when a Creeper is dangerously near you, or a blinking LED when you are close to diamonds, and so on.

Project 3. Arduino "add-on" to Minecraft server. The idea here is, you have a server set up, but you have a real long assignment due for school and can't be bothered at the moment. The idea is to "outsource" a few variables. For example, a siren going off when the Minecraft server goes down for any reason at all, a Serial LCD display showing some pixellated Minecraft display for any kind of state (crashed, loading, rebooting, shutting down, running, killing, etc), or LEDs blinking whenever some user logs on, and so on.

Project 4. Arduino as a mini-Minecraft game. Limited memory, limited display, no color at all...think about this one. The Atari 2600 and, what the hey, the early GameBoy was able to do a lot with limitations. If you were to strip away Minecraft and still be the same game, what would it look like?

Thank you!

2

Despite a very heavy handed "no", ...

That would be from me, I think. Just being realistic.

The idea is to "outsource" a few variables. For example, a siren going off when the Minecraft server goes down for any reason at all, a Serial LCD display showing some pixellated Minecraft display for any kind of state (crashed, loading, rebooting, shutting down, running, killing, etc), or LEDs blinking whenever some user logs on, and so on.

I've actually done this part. My son was running a Minecraft server, and we wanted to know if it went down. So an Arduino (and Ethernet shield) connected to it every 30 seconds or so, and got a count of connected users. If it couldn't connect it flashed a warning LED. If it could, it showed the number of players on, on a 8x8 LED matrix. So that's possible, certainly.

3

Here's the part of the code that checks the player count:

void checkMinecraftServer ()
  {
  // interval if server up
  unsigned long interval = MINECRAFT_CHECK_INTERVAL;
  
  // interval if server down (30 seconds)
  if (serverDown)
    interval = MINECRAFT_CHECK_INTERVAL_IF_SERVER_DOWN;
  
  if (state == IDLE)
     {
  
     if (millis () - lastMinecraftCheckTime < interval)
        return;
        
     lastMinecraftCheckTime = millis ();
     
     if (DEBUGGING_PRINTS)
       Serial.println(F("\n\nConnecting to Minecraft ..."));
       
     digitalWrite (ACTIVITY_LED, HIGH);
    
    // if you get a connection, report back via serial:
    if (client.connect (MinecraftServer, MinecraftServerPort)) 
      {
      if (DEBUGGING_PRINTS)
        Serial.println(F("connected to Minecraft OK - server up"));
      client.print (F("\xFE\x01"));  // make it not echo a disconnection message
      // see: https://github.com/redwallhp/MCServerStatus
       
      unsigned long startTime = millis ();
      char buf [100];
      int inCount = 0;
      int outCount = 0;
      
      // spend a second reading the response to keep the server happy
      while (millis () - startTime < 1000)
        {
        if (client.available () > 0) 
          {
          byte c = client.read ();
          if (((inCount++ & 1) == 0) && outCount < sizeof (buf) - 1)
            {
            if (c == 0)
              c = '\n';
            buf [outCount++] = c; 
            }  // odd numbered bytes
            
            
          }  // if available
          
        }  // while < one second elapsed

     buf [outCount] = 0;  // trailing null
     
     // query Minecraft server
     // see: https://github.com/redwallhp/MCServerStatus
     
     char * delim = "\n";
     char * result = NULL;
     char * protocolVersion = "?";
     char * gameVersion = "?";
     char * MOTD = "?";
     char * playersOn = "0";
     char * maxPlayers = "0";
      
     result = strtok(buf, delim );   // initial rubbish
     if (result)
       protocolVersion = strtok (NULL, delim);  
     if (protocolVersion)
       gameVersion = strtok (NULL, delim);      
      if (gameVersion)
       MOTD = strtok (NULL, delim);      
      if (MOTD)
       playersOn = strtok (NULL, delim);      
      if (playersOn)
       maxPlayers = strtok (NULL, delim);
     
     if (DEBUGGING_PRINTS)
       {     
       Serial.print (F("Players on: "));
       Serial.print (playersOn);
       Serial.print (F("/"));
       Serial.print (maxPlayers);
       Serial.print (F(", version: "));
       Serial.print (gameVersion);
       Serial.print (F(", MOTD: "));
       Serial.println (MOTD);
       }  //if debugging prints

      int playersOnCount = atoi (playersOn);
      
      if (playersOnCount > 9)
        letter ('*');
      else
        letter (playersOnCount | '0');
        
      serverDown = false;  
      client.stop();
   
      }   
    else
      {
      // if you didn't get a connection to the server:
      if (DEBUGGING_PRINTS)
        Serial.println(F("connection to Minecraft failed - server down"));
      serverDown = true;
      letter ('M');
      return;
      }

   if (DEBUGGING_PRINTS)
     Serial.println ();
     
   digitalWrite (ACTIVITY_LED, LOW);
     
   }  // end if idle
   
  }  // end of checkMinecraftServer
4

That would be from me, I think. Just being realistic.

That's what I thought.

I had hoped that the originator of that thread would have stepped back and pursued another angle with Minecraft. I think it's rich with opportunities if you can put your mind to it.

Here's another one that I thought of, and this one is mini-game specific:

The Walls 2 (The Walls 2 - PvP Survival Minecraft Map)

The idea here is a 4 to 8 computer LAN set-up with all machines running Minecraft. Think of a tournament of some sort.
One computer would be the administrator/referee/"the button presser" and the other computers would be the contestants.

Here, the project would be "the Arduino as referee".

On the Walls 2 map, there is a place where the referee (or "button pusher") pushes the button and starts the game.

So here's a very rough draft of what I had in mind:
Connect a big red button on the Arduino to send a signal to Minecraft to start the game ("Big red button --> mouse button")
Connect a digital timer to the Arduino to do a count-down in sync with the game ("Minecraft timer --> Arduino timer")
Connect some sort of alarm to Arduino to go off when the walls fall down.

I can see people adding a lot more stuff to this.