Arduino Uno and ATMEL memory chip using SPI

Hey all.

I’ve been working hard the past 2 weeks trying to get my Arduino to successfully and consistently write/read from memory using SPI but I am having problems. I used the tutorial code for SPIEEPROM to get me started and have made the proper modifications for the memory chip I am using. I’m using the Arduino Uno and the Atmel AT25DF641 chip (data sheet here: http://www.atmel.com/dyn/resources/prod_documents/doc3680.pdf).

For the connections I used pins 13,12,11,10 from the Arduino to the chip (on a breadboard), and also tied the WP to Vcc.

Here’s the code that I have so far:

int DATAOUT =  11;//MOSI
int DATAIN =  12;//MISO 
int SPICLOCK =  13;//sck
int SLAVESELECT =  10;//ss
 
byte eeprom_output_data;
byte clr;
int address=0;
char buffer [128]; 

void setup()
{
  
  Serial.begin(9600);
  
  initPins();  //initialize data pins
  
  digitalWrite(SLAVESELECT,HIGH); //disable device
  
  DDRB = (1<<DDB5)|(1<<DDB3)|(1<<DDB2);  // set DDRB register
   
  delay(1000);      // delay
  
  // CPOL = 0 base value of clock is zero (SPI Mode0)
  // CPHA = 0 data captured on rising edge(SPI Mode0)
  // Arduino Master Mode
  SPCR = (1<<SPE)|(1<<MSTR)|(1<<SPR1)|(1<<SPR0);
  clr=SPSR;
  clr=SPDR;
  
  delay(1000);    // delay
  
  fill_buffer();    // fill a char array in code
  
  digitalWrite(SLAVESELECT,HIGH);
  digitalWrite(SLAVESELECT,LOW);   // start operation HIGH->LOW
  spi_transfer((char)6);                 //write enable
  digitalWrite(SLAVESELECT,HIGH);  //end operation LOW->HIGH  
   
  delay(1000);  // wait 1 second
  
  digitalWrite(SLAVESELECT,LOW); //start operation HIGH->LOW
  spi_transfer((char)2);       // write command
  spi_transfer((char)0);       //first address byte (MSB)
  spi_transfer((char)0);       //second address byte (next byte)
  spi_transfer((char)0);       //third address byte (LSB)
  
  // Loop sending each char in char array to memory chip
  for (int I=0;I<128;I++)
  {
    Serial.print("Sending "); Serial.print(buffer[I], DEC);
    Serial.println(" to memory.");
    spi_transfer(buffer[I]); //write data byte
    delay(3);
  }
 
  digitalWrite(SLAVESELECT,HIGH); //end operation LOW->HIGH
  
  delay(3000); // wait 3 seconds 
  
  Serial.print('h',BYTE);
  Serial.print('i',BYTE);
  Serial.print('\n',BYTE);//debug
}

void loop()
{
  
  eeprom_output_data = read_eeprom(address);
  
  Serial.print("Data: ");Serial.print(eeprom_output_data,DEC);Serial.print(" from Address: ");Serial.println(address,DEC);
    
  address++;
  
  if(address == 128)
    address=0;
 
 delay(500);
 
}

void fill_buffer()
{
  for (int I=0;I<128;I++)
  {
    buffer[I]=I;
  }
} 

char spi_transfer(char data)
{ 
  SPDR = data;                    // Start the transmission
    
  while (!(SPSR & (1<<SPIF)))     // Wait for the end of the transmission
  {
  };
  
  return SPDR;                    // return the received byte
}


byte read_eeprom(int EEPROM_address)
{
  int data;
  
  digitalWrite(SLAVESELECT,LOW);
  spi_transfer((char)11);                       //transmit read opcode
  spi_transfer((char)(EEPROM_address>>8)); // first address byte
  spi_transfer((char)(EEPROM_address>>8)); // second address byte
  spi_transfer((char)(EEPROM_address));   // third address byte
  spi_transfer((char)(B11111111)); // dummy byte
  data = spi_transfer((char)(B11111111)); // generate extra clock signals for data
  digitalWrite(SLAVESELECT,HIGH); //release chip, signal end transfer
  
  delay(10);
  
  return data;
}

void initPins()
{
  pinMode(DATAOUT, OUTPUT);
  pinMode(DATAIN, INPUT);
  pinMode(SPICLOCK,OUTPUT);
  pinMode(SLAVESELECT,OUTPUT);
}

My output is:

Data: 0 from Address: 0
Data: 0 from Address: 1
.
.

I get 0’s for each address despite having the loop that writes to memory. Does anything in the code stick out as wrong? Any help is appreciated!!

Don't you to print eeprom_output_data after the read, and not testdata?

eeprom_output_data = read_eeprom(address);

Serial.print("Data: ");Serial.print(testdata,DEC);Serial.print(" from Address: "); Serial.println(address,DEC);

CrossRoads: Don't you to print eeprom_output_data after the read, and not testdata?

eeprom_output_data = read_eeprom(address);

Serial.print("Data: ");Serial.print(testdata,DEC);Serial.print(" from Address: "); Serial.println(address,DEC);

Yes, I apologize; I accidentally posted an earlier version of my code that gave me an error (I'll change the original post). However, the output I posted is what I get even when I print eeprom_output_data.

So I've still been working on it to no avail. Any chance it's a timing issue? Maybe I need to throw some delays in there. I'm just not sure what the problem is; it seems as if I'm doing everything in the proper order.

I haven't looked at any of the data sheets in a while, but if I remember correctly, when I was using the DataFlash AT45 parts way back when, there is a clock polarity issue - you will have to play around with the clock polarity/phase on the master SPI port to match. So, if the AT25 parts use the same SPI hardware, you may face this as well.

Again, I'm not 100% certain of what's going on, but I thought I'd pass on my findings from a while back.

b

Why not use the SPI library?

Anyway, your problem is either writing or reading, agreed?

Now if the reading part is correct, then check out this from the data sheet:

The Byte/Page Program command allows anywhere from a single byte of data to 256-bytes of data to be programmed into previously erased memory locations. An erased memory location is one that has all eight bits set to the logical “1” state (a byte value of FFh).

You read back zero, which doesn't meet the condition of being the value 0xFF. Therefore it won't write to it.

I’ve been trying to do the same thing…with different hardware.

truce: I’ve tried your code on a nano 3.0 and atmel AT25DF041A (datasheet - http://www.atmel.com/dyn/resources/prod_documents/doc3668.pdf)

I’m using the same pins on the arduino and a logic level converter (http://www.sparkfun.com/products/8745) between the eeprom and the nano.

The results I’m getting are:

Data: 255 from Address: 0
Data: 255 from Address: 1
Data: 255 from Address: 2
Data: 255 from Address: 3
...

Nick: because I am reading 0xFF, do you have any other ideas what might be going on?

bhagman: i’ve tried both supported modes (0 and 3)

//CPOL = 0 base value of clock is zero (SPI Mode0)
//CPHA = 0 data captured on rising edge(SPI Mode0)
SPCR = (1<<SPE)|(1<<MSTR)|(1<<SPR1)|(1<<SPR0);

and

//CPOL = 1 base value of clock is high (SPI Mode3)
//CPHA = 1 data captured on falling edge(SPI Mode3)
SPCR = (1<<SPE)|(1<<MSTR)|(1<<CPOL)|(1<<CPHA)|(1<<SPR1)|(1<<SPR0);

both to no avail…

anybody have any ideas?

sark86: Nick: because I am reading 0xFF, do you have any other ideas what might be going on?

Hmm, 4 Mb eh? Would be nice to have one. If only I could solder SMD devices. :(

Is it possible to solder the 8SOIC package onto an adapter board if you are careful? Or is it throwing money away?

Anyway, getting 0xFF back tends to imply getting no response, since the line is probably pulled high anyway. Without having one in my hands, I would suggest to you to try the "Read Manufacturer and Device ID" (page 27 of spec) to check your comms with the chip are going OK. Then we can move onto programming it.

With the logic level converter, are you using the Tx pins? Or let me put it another way, how exactly did you wire it up?

It is fairly easy with these http://www.sparkfun.com/products/494.

I’ve actually used two of the level converters with all 4 Tx pins. Not using any of the Rx rails.

MISO, MOSI, SCK, CS are all going from the nano to the level converters 4 Tx pins, then to the EEPROM’s SO, SI, SCK, CS. WP and HOLD are both pulled high on the EEPROM. The high voltage side of the level converters are powered by the 5V pin on the nano, and the low voltage side is powered by the 3.3V pin on the nano, as is the EEPROM.

I didn’t even think to try to read the manufacturer and ID…I will update when I’ve tried that.

Well, I know I'm showing my ignorance here, but I'm hoping one of the electronics experts will chime in and explain ...

That Sparkfun level-converter you are using - I looked at that and looked at the circuit. On the Sparkfun page the claim is made that the Tx circuits are bi-directional. Now they are implemented with BSS138 FET transistors. I didn't know transistors could switch "both ways". If someone can explain or give a reference that would be great.

The text on the page says:

A digital one going into the TXI pin on the 3.3V side will show up on the TXO pin on the 5V side as 5V.

And one of the photographs states (with arrows) that the Tx is one-way. So either I am totally wrong (not the first time), or you should not be using the Tx pins for all 4 signals. The way I read their design you should use the voltage-divider resistors for high-to-low, and the BSS138 transistors for low-to-high. Can someone else comment?

This document may explain the design behind the bi-directional level-shifter:

http://www.nxp.com/acrobat_download/applicationnotes/AN10441_1.pdf

After re-reading the document I posted above (about the level shifter) I think I understand it better. But as I read it, it is for I2C and not SPI. In particular this sentence:

The devices of each section have I/Os with supply voltage related logic input levels and an open-drain output configuration.

But SPI is not open-drain (whereas I2C is). This may not matter. But the technical note specifically mentions I2C (and even mentions SDA and SCL), so there may be some subtle "gotcha" when trying to use it for SPI. For example, a timing issue.

It seems the Tx lines are indeed working both ways. Using this code:

//opcodes
#define WREN  6  //write enabled
#define WRDI  4  //write disabled
#define RDSR  5  //read status register
#define WRSR  1
#define READ  11
#define WRITE 2
#define RMDID 159 //Read Manufacturer Device ID

int DATAOUT =  11;//MOSI
int DATAIN =  12;//MISO 
int SPICLOCK =  13;//sck
int SLAVESELECT =  10;//ss

byte eeprom_output_data;
byte clr;

void setup()
{
  
  Serial.begin(9600);
  
  initPins();  //initialize data pins
  
  digitalWrite(SLAVESELECT,HIGH); //disable device
  
  DDRB = (1<<DDB5)|(1<<DDB3)|(1<<DDB2);  // set DDRB register
   
  delay(100);      // delay
  
  // CPOL = 0 base value of clock is zero (SPI Mode0)
  // CPHA = 0 data captured on rising edge(SPI Mode0)
  // Arduino Master Mode
  SPCR = (1<<SPE)|(1<<MSTR)|(1<<SPR1)|(1<<SPR0);
  clr=SPSR;
  clr=SPDR;
  
  delay(1000);    // delay
  
  Serial.print('\n',BYTE);
  Serial.print("Setup Complete");
  Serial.print('\n',BYTE);//debug
}

void loop()
{
  digitalWrite(SLAVESELECT,LOW);
  spi_transfer(RMDID);                             //transmit read device and manf. ID
  eeprom_output_data = spi_transfer(RMDID);
  digitalWrite(SLAVESELECT,HIGH);
  
  delay(500);
  
  Serial.print("Data: ");Serial.print(eeprom_output_data,DEC);
  Serial.print('\n',BYTE);
  delay(500);
  
}

char spi_transfer(char data)
{ 
  SPDR = data;                    // Start the transmission
    
  while (!(SPSR & (1<<SPIF)))     // Wait for the end of the transmission
  {
  };
  
  return SPDR;                    // return the received byte
}

void initPins()
{
  pinMode(DATAOUT, OUTPUT);
  pinMode(DATAIN, INPUT);
  pinMode(SPICLOCK,OUTPUT);
  pinMode(SLAVESELECT,OUTPUT);
}

I successfully get this in return:

Data: 31

Which is the correct manufacturers ID.

So now I just need to figure out what is going on in my code for writing to it. :~

Hey all,

I’ve been using a new memory chip since the last time (still working on same problem). I tried what sark did, as far as reading the manufacturer ID using this code:

#include <SPI.h>

const int SlaveSelect = 10;
const int MOSI = 11;
const int MISO = 12;
const int CLK = 13;
byte myByte;

void setup()
{
  Serial.begin(9600);
    
  pinMode(MISO, INPUT);
  
  SPI.begin();
  
  delay(10);
  
  SPI.setDataMode(SPI_MODE0);
  SPI.setBitOrder(MSBFIRST);
  SPI.setClockDivider(SPI_CLOCK_DIV128);
  
  delay(10);
  
  
  digitalWrite(SlaveSelect,LOW);
  delay(10);
  SPI.transfer(0x06);
  delay(10);
  digitalWrite(SlaveSelect,HIGH);
  
  delay(10);
  
   digitalWrite(SlaveSelect,LOW);
  delay(10);
  SPI.transfer(0x02);
  SPI.transfer(0x00);
  SPI.transfer(0x00);
  SPI.transfer(0x05);
  myByte = SPI.transfer(0x255);
   digitalWrite(SlaveSelect,HIGH);
  
 
  Serial.println("done");
  
  
}


void loop()
{
  
  digitalWrite(SlaveSelect,LOW);
  delay(10);
  SPI.transfer(0x90);
  SPI.transfer(0x00);
  SPI.transfer(0x00);
  SPI.transfer(0x00);
  myByte = SPI.transfer(0x01);
  digitalWrite(SlaveSelect,HIGH);
  
  
  Serial.println(myByte,DEC);
  delay(500);

  
}

with the following output:

done
0
239
0
0
0
239
0
0
0
239
0
0
0
239

239 is the correct ID, but does anyone have an idea why its not continuous and there are 0s in between?

Why the extra transfers?

You didn't say which chip you are using this time, but based on the AT25DF641 data sheet, I would expect you to do something like this:

  digitalWrite(SlaveSelect,LOW);
  SPI.transfer(0x90);   // send "read manufacturer ID" command (or is it 0x9F?)
  delay(1);
  byte man_id = SPI.transfer(0);
  delay(1);
  byte device_id1 = SPI.transfer(0);
  delay(1);
  byte device_id2 = SPI.transfer(0);
  delay(1);
  byte extended_info = SPI.transfer(0);
  digitalWrite(SlaveSelect,HIGH);

The spec says the manufacturer's ID comes first (and it would be surprising if different chips put the manufacturer's ID in different places, that would kind-of defeat the point).

And are you sure that 0x90 is the correct command? The previous post mentioned 159 (0x9F) which is what the AT25DF641 uses. Again, it would be surprising if different manufacturers used a different "read manufacturer ID" command, because you need to know in advance then, which command to send (ie. need to know the manufacturer), in order to find out who the manufacturer is. In which case, again not much point.

You must be using a different chip than the AT25DF641 you originally used if 239 is the ID. Without knowing what you are using I can't check and see if the opcodes you are using are correct.

Also, I think your myByte = SPI.transfer(0x255); is incorrect as that is a hex 255 not a decimal 255. I think you would want myByte = SPI.transfer(0xFF);

Yes, I should have included the memory chip I am using now in my post. Its a winbond: http://www.winbond.com.tw/NR/rdonlyres/591A37FF-007C-4E99-956C-F7EE4A6D9A8F/0/W25Q64BV.pdf

This chip requires three address bytes of B00000000 after the read manufacturer id command.

And thanks sark, I didnt catch that.

Based on the ID you gave (239 = 0b11101111) and looking up this page:

http://www.idhw.com/textual/chip/jedec_spd_man.html

I am guessing you have a NEXCOM chip of some sort. Possibly something like the NX25P40.

Their data sheet does indeed say you get the manufacturer ID with 0x90, you then clock in 3 lots of zero, and on the fourth byte it responds with the manufacturer ID, and then the device ID.

As to why that only sometimes works? Well maybe read out the device ID as well. Maybe the chip is sending it, but you haven't clocked it out, so it is waiting? Just a guess. Try adding in the extra transfer and see what happens.

...

Your more recent post says you are now using the W25Q64BV ... I see you can query the manufacturer ID using 0x9F (as well as 0x90 which requires the 3 extra bytes) so maybe try that.

I got the Atmel AT25DF041A chip today, and after quite a struggle, got it to program. :slight_smile:

Some of the challenges were:

  • Soldering the 8-SOIC SMD device without destroying it :wink:
  • Getting the buffer chip to work
  • Understanding the AT25DF041A documentation
  • Working out how to disable write-protect, and sector protection
  • Reading the status register to know when the chip wasn’t busy any more

Anyway, the code below works. I used the Atmel AT25DF041A “4-megabit 2.3-volt or 2.7-volt Minimum SPI Serial Flash Memory” with the SN54AHC125 “Quadruple Bus Buffer Gates with 3-state outputs” as a 3.3 to 5v buffer.

The buffer and EEPROM chip were powered off the 3.3V Arduino output pin.

I didn’t need to do custom SPI software, the standard library worked fine.

To avoid spurious data on the SPI lines I wired up pin 9 to the buffer chip “3-state enable” pins so that the buffer could be enabled in an orderly way. This is brought low to allow communication with the EEPROM.

// Written by Nick Gammon
// 10th March 2011

#include <SPI.h>

#define CHIP_SELECT 10   // for EEPROM
#define BUFFER_ENABLE 9  // for SN54AHC125 buffer

// AT25DF041A EEPROM commands

// reading
#define ReadArray             0x0B
#define ReadArrayLowFrequency 0x03

// programming
#define BlockErase4Kb       0x20
#define BlockErase32Kb      0x52
#define BlockErase64Kb      0xD8
#define ChipErase           0x60
#define ByteProgram         0x02
#define SequentialProgram   0xAD

// protection
#define WriteEnable           0x06
#define WriteDisable          0x04
#define ProtectSector         0x36
#define UnProtectSector       0x39
#define ReadSectorProtection  0x3C

// status
#define ReadStatus 0x05
#define WriteStatus 0x01

// miscellaneous
#define ReadManufacturer     0x9F
#define DeepPowerDown        0xB9
#define ResumeFromPowerDown  0xAB

// wait until chip not busy
void notBusy ()
{
  digitalWrite (CHIP_SELECT, LOW);
  SPI.transfer (ReadStatus);       
  // wait until busy bit cleared
  while (SPI.transfer (0) & 1) 
     {} 
  digitalWrite (CHIP_SELECT, HIGH);  
}  // end notBusy

// enable writing
void writeEnable ()
{
 notBusy ();
 
 digitalWrite (CHIP_SELECT, LOW);
 SPI.transfer (WriteEnable);       
 digitalWrite (CHIP_SELECT, HIGH);  
}  // end of writeEnable

// read device status
byte readStatus (void)
{
 digitalWrite (CHIP_SELECT, LOW);
 SPI.transfer (ReadStatus);       
 byte status = SPI.transfer (status);       
 digitalWrite (CHIP_SELECT, HIGH);  
  
 return status;
}  // end of readStatus

// write status register
void writeStatus (const byte status)
{
   writeEnable ();
   notBusy ();  // wait until ready
   
   digitalWrite (CHIP_SELECT, LOW);
   SPI.transfer (WriteStatus);       
   SPI.transfer (status);       
   digitalWrite (CHIP_SELECT, HIGH);  
}  // end of writeStatus

// send a command to the EEPROM followed by a 3-byte address
void sendCommandAndAddress (const byte command, const unsigned long addr)
{
  SPI.transfer (command);       
  SPI.transfer ((addr >> 16) & 0xFF);       
  SPI.transfer ((addr >> 8) & 0xFF);       
  SPI.transfer (addr & 0xFF);       
}  // end of sendCommandAndAddress

// write len (max 256) bytes to device

// Note that if writing multiple bytes the address plus
//  length must not cross a 256-byte boundary or it will "wrap"
void writeEEPROM (const unsigned long addr, byte * data, byte len) 
{
  // now write to it
  writeEnable ();
  
  notBusy ();  // wait until ready
  digitalWrite (CHIP_SELECT, LOW);
  sendCommandAndAddress (ByteProgram, addr);
  for ( ; len ; --len)
    SPI.transfer (*data++);       
  digitalWrite (CHIP_SELECT, HIGH);  
  notBusy (); 
} // end of writeEEPROM

// write one byte to device
void writeEEPROM (unsigned long addr, byte data) 
{
  writeEEPROM (addr, &data, 1);
} // end of writeEEPROM

// read len bytes from device
void readEEPROM (const unsigned long addr, byte * data, unsigned int len) 
{
  notBusy ();  // wait until ready
  digitalWrite (CHIP_SELECT, LOW);
  sendCommandAndAddress (ReadArray, addr);

  SPI.transfer (0);  // clock in "don't care" byte
 
  for ( ; len ; --len)
   *data++ = SPI.transfer (0);       
  digitalWrite (CHIP_SELECT, HIGH);  
  
}  // end of readEEPROM

// erase a 4Kb block of bytes which contains addr
void eraseEEPROM (const unsigned long addr)
{
  writeEnable ();

  notBusy ();  // wait until ready
  digitalWrite (CHIP_SELECT, LOW);
  sendCommandAndAddress (BlockErase4Kb, addr);
  digitalWrite (CHIP_SELECT, HIGH);  
  
}  // end of eraseEEPROM

// show device info and status
void info ()
{
  
  notBusy (); // wait until ready
  
  digitalWrite (CHIP_SELECT, LOW);
  SPI.transfer (ReadManufacturer);       
  
  Serial.print ("Manufacturer: ");
  Serial.println (SPI.transfer (0), HEX);
  Serial.print ("Device ID Part 1: ");
  Serial.println (SPI.transfer (0), HEX);
  Serial.print ("Device ID Part 2: ");
  Serial.println (SPI.transfer (0), HEX);
  Serial.print ("Extended Information Length: ");
  Serial.println (SPI.transfer (0),HEX);

  digitalWrite (CHIP_SELECT, HIGH);
  
  Serial.print ("Status: ");
  Serial.println (readStatus (), HEX);

} // end of info

void setup ()
{
  
  Serial.begin (9600);
  SPI.begin ();
   
  // enable the SN54AHC125 output enable peons (more work?)
  pinMode (BUFFER_ENABLE, OUTPUT);  // buffer chip enable
  digitalWrite (BUFFER_ENABLE,LOW);  // enable

  // global unprotect
  writeStatus (0);
  
  Serial.println ("Status:");
  info ();
    
  // test: write a string to address 0x1000

#define TESTADDRESS 0x1000

  eraseEEPROM (TESTADDRESS);
  
  byte hello [] = "Hello, World!";
  
  writeEEPROM (TESTADDRESS, hello, sizeof hello);
  
  // read back to confirm
  byte test [sizeof hello] = { 0 } ;
  readEEPROM (TESTADDRESS, test, sizeof test);

  Serial.println ((char *) test);  // display to confirm
  
}  // end of setup

void loop()
{
 
}  // end of loop

This is basically a demo program, but incorporates routines to write up to 256 bytes and read up to 65536 bytes. There is a lot of complexity in the chip itself which would have obscured the demo if I tried to incorporate it all, like sector protection, writing pages, erasing blocks of various sizes and so on.

One point which wasn’t initially obvious is that you have to keep enabling write-enable. Every write operation cancels it (as a safety precaution no doubt). So to disable software protection you first do a write-enable. Then to erase some memory you have to first do a write-enable again. And then to write to the memory you have to first do a write-enable.

Awesome! Got mine working with your code Nick, thanks A LOT!

Now to get the sequential program mode to work so I don't have to mess with write enabled every single time. :cold_sweat: