Arduino Web Control Help

I am looking for some assistance, and forgive me I am pretty new to the arduino world.

I am using an arduino sketch that sets up a webserver. The webserver basically looks for the URL to include /9/LOW/ after the boards ip address and port. The 9 refers to the output pin and LOW refers to the state. So if I typed in http:/10.10.10.10/80/9/HIGH/ into the browser it will turn Digital pin #9 to the ON state on the arduino board. Here is the issue I am running into:

I have created a website that I want to use to control the board. So when I created a button that links to http:/10.10.10.10/80/9/HIGH/ as an example it turns on that pin but it ALSO sends me to that page. My question is does anyone have an idea how I could create a button on my html webpage that would not take me to that link but just simply send the information to board?

Some simple server control code that includes iframe capabilities if needed.

//zoomkat 12-8-11
//simple button GET with iframe code
//for use with IDE 1.0
//open serial monitor to see what the arduino receives
//use the \ slash to escape the " in the html 
//address will look like http://192.168.1.102:84 when submited
//for use with W5100 based ethernet shields

#include <SPI.h>
#include <Ethernet.h>

#include <Servo.h> 
Servo myservo;  // create servo object to control a servo 

byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED }; //physical mac address
byte ip[] = { 192, 168, 1, 102 }; // ip in lan
byte gateway[] = { 192, 168, 1, 1 }; // internet access via router
byte subnet[] = { 255, 255, 255, 0 }; //subnet mask
EthernetServer server(84); //server port

String readString; 

//////////////////////

void setup(){

  pinMode(5, OUTPUT); //pin selected to control
  //start Ethernet
  Ethernet.begin(mac, ip, gateway, subnet);
  server.begin();

  myservo.write(0); //set initial servo position if desired
  myservo.attach(7);  //the pin for the servo co
  //enable serial data print 
  Serial.begin(9600); 
  Serial.println("server LED test 1.0"); // so I can keep track of what is loaded
}

void loop(){
  // Create a client connection
  EthernetClient client = server.available();
  if (client) {
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();

        //read char by char HTTP request
        if (readString.length() < 100) {

          //store characters to string 
          readString += c; 
          //Serial.print(c);
        } 

        //if HTTP request has ended
        if (c == '\n') {

          ///////////////
          Serial.println(readString); //print to serial monitor for debuging 

          //now output HTML data header
             if(readString.indexOf('?') >=0) { //don't send new page
               client.println("HTTP/1.1 204 Zoomkat");
               client.println();
               client.println();  
             }
             else {
          client.println("HTTP/1.1 200 OK"); //send new page
          client.println("Content-Type: text/html");
          client.println();

          client.println("<HTML>");
          client.println("<HEAD>");
          client.println("<TITLE>Arduino GET test page</TITLE>");
          client.println("</HEAD>");
          client.println("<BODY>");

          client.println("<H1>Zoomkat's simple Arduino button</H1>");
          
          client.println("<a href=\"/?on\" target=\"inlineframe\">ON</a>"); 
          client.println("<a href=\"/?off\" target=\"inlineframe\">OFF</a>"); 

          //client.println("<IFRAME name=inlineframe src=\"res://D:/WINDOWS/dnserror.htm\" width=1 height=1\">");
          client.println("<IFRAME name=inlineframe style=\"display:none\" >");          
          client.println("</IFRAME>");

          client.println("</BODY>");
          client.println("</HTML>");
             }

          delay(1);
          //stopping client
          client.stop();

          ///////////////////// control arduino pin
          if(readString.indexOf("on") >0)//checks for on
          {
            myservo.write(20);
            digitalWrite(5, HIGH);    // set pin 4 high
            Serial.println("Led On");
          }
          if(readString.indexOf("off") >0)//checks for off
          {
            myservo.write(160);
            digitalWrite(5, LOW);    // set pin 4 low
            Serial.println("Led Off");
          }
          //clearing string for next read
          readString="";

        }
      }
    }
  }
}

An HTTP 204 response from your Arduino should result in no change of view in the client.

@zoomkat- What happened to the buttons in your code? You don't like them? Every browser has Javascript if you enable it.

An HTTP 204 response from your Arduino should result in no change of view in the client.

That seemed to be what the OP requested when he said this:

My question is does anyone have an idea how I could create a button on my html webpage that would not take me to that link but just simply send the information to board?

The iframe comes in handy when refreshing a pix justing javascript in a setup like below (haven't figured out how to write an applet or use possibly ajax).

http://web.comporium.net/~shb/wc2000-PT-script.htm

What happened to the buttons in your code? You don't like them? Every browser has Javascript if you enable it.

I took the iframe code out of the multibutton code just to keep it simple to just the buttons. Lots of clickable stuff, like the very old page below with dropdowns that controlled servos and a parallel port video switcher. The video frames were pulled via an applet, so the iframe wasn't needed.

http://web.comporium.net/~shb/ppswitcher-demo1.htm