ATtiny 85 with I2C

Other Hardware 3rd Party Boards
4

TinyWireM should be able to do what you want. Here's a short demonstration sketch that hooks two I2C devices (DS3231 and a 4X 7-segment display) to an ATTiny85 chip. I programmed the tiny85 with the same programmer you have, the Sparkfun Tiny Programmer.

/***********************************************
  Minutes and seconds
  A demonstration using TinyWireM on an
  ATTiny 85 with I2C input and output devices

  Tiny 85, 8MHz internal
    Adafruit 7-segment, I2C, LED backpack display
    DS3231 breakout board
  d2 (physical pin 7) -> I2C clk
  d0 (physical pin 5) -> I2C sda

  042618 clh 1376/71 show minutes and seconds of the real time


************************************************/

#include "TinyWireM.h" // https://github.com/adafruit/TinyWireM
#include "Adafruit_GFX.h"
#include "Adafruit_LEDBackpack.h"

Adafruit_7segment matrix = Adafruit_7segment();

#define rtcAddress 0x68  // DS3231

unsigned long previousSecondMillis = millis();
long oneSecond = 1000L;

boolean isColonOn = true;

void setup() {
  TinyWireM.begin();
  matrix.begin(0x70);
}

void loop() {

  // --------- Run this code every second ------------------
  if (millis() - previousSecondMillis >= oneSecond) {
    previousSecondMillis += oneSecond;

    // get data (in bcd format) directly from the rtc
    TinyWireM.beginTransmission(rtcAddress); // 0x68 is DS3231 device address
    TinyWireM.write((byte)0); // start at register 0
    TinyWireM.endTransmission();
    TinyWireM.requestFrom(rtcAddress, 2); // request just seconds and minutes

    while (TinyWireM.available())
    {
      byte seconds = TinyWireM.read(); // get seconds
      byte minutes = TinyWireM.read(); // get minutes

      // convert BCD to decimal
      minutes = (((minutes & 0b11110000) >> 4) * 10 + (minutes & 0b00001111));
      seconds = (((seconds & 0b11110000) >> 4) * 10 + (seconds & 0b00001111));

      // write to the display via I2C using a library
      // show the minuts:seconds on 7 segment display
      matrix.writeDigitNum(0, (minutes / 10));
      matrix.writeDigitNum(1, (minutes % 10));
      matrix.writeDigitNum(3, (seconds / 10));
      matrix.writeDigitNum(4, (seconds % 10));
      matrix.drawColon(isColonOn);
      matrix.writeDisplay();
      
      isColonOn = !isColonOn;  // flash the colon on and off
    }
  }
  
}

Here's a picture showing the hookup:

This should let you get going with the stuff you have now.