Audio drop out monitoring project - ways to trigger a .wav file.

Hi everyone,

At work I have been tasked with a project to help with a department's 'quality issues'. We have several video sources, all with audio, being monitored. We want to have a device that would trigger a sound when audio is lost from these video source...

I looked into the Arduino UNO with WaveShield and got to work (had a fair amount of fun doing it, too! Well, until now!).

The idea was that our monitoring system uses GPO''s... So, in that software, I configured it to send out a GPO's signal to my arduino board. The arduino then plays out specific .wav files from an SD card when the signal of that input is grounded. It worked and I was happy... Until...

I realised that the GPO being output from our monitoring system is not a 'grounded' signal. It is actually a drop in voltage. Therefore, I pose this question...

Am I able to code this to read the voltage of an input, and then when it drops from the high (5v) to the low (just over 0v) it will trigger the sound like a button?
I have had a look around and found this http://arduino.cc/en/Reference/AttachInterrupt - Am I right in guessing that this could be used for the job?

Apologies if I've missed information out, I'm totally new to the whole thing. If anyone is able to help I will try and supply as much information as possible..
I've attached my code below.. It's a blend of a few examples I found.

Many thanks,
Luke

#include <FatReader.h>
#include <SdReader.h>
#include <avr/pgmspace.h>
#include "WaveUtil.h"
#include "WaveHC.h"


SdReader card;    // This object holds the information for the card
FatVolume vol;    // This holds the information for the partition on the card
FatReader root;   // This holds the information for the filesystem on the card
FatReader f;      // This holds the information for the file we're play

WaveHC wave;      // This is the only wave (audio) object, since we will only play one at a time

#define DEBOUNCE 5  // button debouncer

// here is where we define the buttons that we'll use. button "1" is the first, button "6" is the 6th, etc
byte buttons[] = {14, 15, 16, 17, 18, 19};
// This handy macro lets us determine how big the array up above is, by checking the size
#define NUMBUTTONS sizeof(buttons)
// we will track if a button is just pressed, just released, or 'pressed' (the current state
volatile byte pressed[NUMBUTTONS], justpressed[NUMBUTTONS], justreleased[NUMBUTTONS];

// this handy function will return the number of bytes currently free in RAM, great for debugging!   
int freeRam(void)
{
  extern int  __bss_end; 
  extern int  *__brkval; 
  int free_memory; 
  if((int)__brkval == 0) {
    free_memory = ((int)&free_memory) - ((int)&__bss_end); 
  }
  else {
    free_memory = ((int)&free_memory) - ((int)__brkval); 
  }
  return free_memory; 
} 

void sdErrorCheck(void)
{
  if (!card.errorCode()) return;
  putstring("\n\rSD I/O error: ");
  Serial.print(card.errorCode(), HEX);
  putstring(", ");
  Serial.println(card.errorData(), HEX);
  while(1);
}

void setup() {
  byte i;
  
  // set up serial port
  Serial.begin(9600);
  putstring_nl("WaveHC with ");
  Serial.print(NUMBUTTONS, DEC);
  putstring_nl("buttons");
  
  putstring("Free RAM: ");       // This can help with debugging, running out of RAM is bad
  Serial.println(freeRam());      // if this is under 150 bytes it may spell trouble!
  
  // Set the output pins for the DAC control. This pins are defined in the library
  pinMode(2, OUTPUT);
  pinMode(3, OUTPUT);
  pinMode(4, OUTPUT);
  pinMode(5, OUTPUT);

  // pin13 LED
  pinMode(13, OUTPUT);

  // Make input & enable pull-up resistors on switch pins
  for (i=0; i< NUMBUTTONS; i++) {
    pinMode(buttons[i], INPUT);
    digitalWrite(buttons[i], HIGH);
  }
  
  //  if (!card.init(true)) { //play with 4 MHz spi if 8MHz isn't working for you
  if (!card.init()) {         //play with 8 MHz spi (default faster!)  
    putstring_nl("Card init. failed!");  // Something went wrong, lets print out why
    sdErrorCheck();
    while(1);                            // then 'halt' - do nothing!
  }
  
  // enable optimize read - some cards may timeout. Disable if you're having problems
  card.partialBlockRead(true);

// Now we will look for a FAT partition!
  uint8_t part;
  for (part = 0; part < 5; part++) {     // we have up to 5 slots to look in
    if (vol.init(card, part)) 
      break;                             // we found one, lets bail
  }
  if (part == 5) {                       // if we ended up not finding one  :(
    putstring_nl("No valid FAT partition!");
    sdErrorCheck();      // Something went wrong, lets print out why
    while(1);                            // then 'halt' - do nothing!
  }
  
  // Lets tell the user about what we found
  putstring("Using partition ");
  Serial.print(part, DEC);
  putstring(", type is FAT");
  Serial.println(vol.fatType(),DEC);     // FAT16 or FAT32?
  
  // Try to open the root directory
  if (!root.openRoot(vol)) {
    putstring_nl("Can't open root dir!"); // Something went wrong,
    while(1);                             // then 'halt' - do nothing!
  }
  
  // Whew! We got past the tough parts.
  putstring_nl("Ready!");
  
  TCCR2A = 0;
  TCCR2B = 1<<CS22 | 1<<CS21 | 1<<CS20;

  //Timer2 Overflow Interrupt Enable
  TIMSK2 |= 1<<TOIE2;


}

SIGNAL(TIMER2_OVF_vect) {
  check_switches();
}

void check_switches()
{
  static byte previousstate[NUMBUTTONS];
  static byte currentstate[NUMBUTTONS];
  byte index;

  for (index = 0; index < NUMBUTTONS; index++) {
    currentstate[index] = digitalRead(buttons[index]);   // read the button
    
    /*     
    Serial.print(index, DEC);
    Serial.print(": cstate=");
    Serial.print(currentstate[index], DEC);
    Serial.print(", pstate=");
    Serial.print(previousstate[index], DEC);
    Serial.print(", press=");
    */
    
    if (currentstate[index] == previousstate[index]) {
      if ((pressed[index] == LOW) && (currentstate[index] == LOW)) {
          // just pressed
          justpressed[index] = 1;
      }
      else if ((pressed[index] == HIGH) && (currentstate[index] == HIGH)) {
          // just released
          justreleased[index] = 1;
      }
      pressed[index] = !currentstate[index];  // remember, digital HIGH means NOT pressed
    }
    //Serial.println(pressed[index], DEC);
    previousstate[index] = currentstate[index];   // keep a running tally of the buttons
  }
}


void loop() {
  byte i;

  if (justpressed[0]) {
    justpressed[0] = 0;
    playfile("BABEL.WAV");
    while (wave.isplaying && pressed[0]) {
      //Serial.print(".");
    }
    wave.stop();    
  }
  if (justpressed[1]) {
    justpressed[1] = 0;
    playfile("RE.WAV");
    while (wave.isplaying && pressed[1]) {
      //Serial.print(".");
    }
    wave.stop();    
  }
  if (justpressed[2]) {
    justpressed[2] = 0;
    playfile("MI.WAV");
    while (wave.isplaying && pressed[2]) {
      //Serial.print(".");
    }
    wave.stop();    
  }
  if (justpressed[3]) {
    justpressed[3] = 0;
    playfile("FA.WAV");
    while (wave.isplaying && pressed[3]) {
      //Serial.print(".");
    }
    wave.stop();    
  }
  if (justpressed[4]) {
    justpressed[4] = 0;
    playfile("SO.WAV");
    while (wave.isplaying && pressed[4]) {
      //Serial.print(".");
    }
    wave.stop();    
  }
  if (justpressed[5]) {
    justpressed[5] = 0;
    playfile("LA.WAV");
    while (wave.isplaying && pressed[5]) {
      //Serial.print(".");
    }
    wave.stop();    
  }
}



// Plays a full file from beginning to end with no pause.
void playcomplete(char *name) {
  // call our helper to find and play this name
  playfile(name);
  while (wave.isplaying) {
  // do nothing while its playing
  }
  // now its done playing
}

void playfile(char *name) {
  // see if the wave object is currently doing something
  if (wave.isplaying) {// already playing something, so stop it!
    wave.stop(); // stop it
  }
  // look in the root directory and open the file
  if (!f.open(root, name)) {
    putstring("Couldn't open file "); Serial.print(name); return;
  }
  // OK read the file and turn it into a wave object
  if (!wave.create(f)) {
    putstring_nl("Not a valid WAV"); return;
  }
  
  // ok time to play! start playback
  wave.play();
}

from high to low... (falling edge)

attach an interrupt to pin 2/3 on the falling edge, then play the sound out...

http://arduino.cc/en/Reference/AttachInterrupt

Hi there,

Firstly, thanks for your input!

I shall have a play around with your suggestion.

Can you elaborate on what you mean by 'falling edge'?

Many thanks

Never mind, you already explained and I miss-read.

I will give this a go and let you know the outcome :slight_smile:

Hi,

What output from your system are you using? When you say "Drop in voltage" is that the audio signal itself? Or some digital output?

How many sources do you need to monitor?

For 20 years or so, (long ago now) I had an AM radio I had modified to buzz an alarm any time the audio signal stopped for more than 10 seconds. It also had a big Red light labelled "Dead Air".. I was Chief Engineer of some radio stations back then, and although I usually listened to the programs, there were times, like a quiet dinner with friends, where I wanted the audio off.

terryking228:
Hi,

What output from your system are you using? When you say "Drop in voltage" is that the audio signal itself? Or some digital output?

How many sources do you need to monitor?

For 20 years or so, (long ago now) I had an AM radio I had modified to buzz an alarm any time the audio signal stopped for more than 10 seconds. It also had a big Red light labelled "Dead Air".. I was Chief Engineer of some radio stations back then, and although I usually listened to the programs, there were times, like a quiet dinner with friends, where I wanted the audio off.

Hey there,

The scenario you mentioned is basically the same as mine :), though we are a TV station.
The signal is not the audio, it's a GPO from our monitoring system. I did the wrong thing and presumed that it would just kick out a grounded signal, which the GPO had been assigned to a a video source with embedded audio.
What the GPO actually does is kick out a 5V at all times, until the GPO is triggered. Then it drops in voltage to around 0.07V.

After some more digging around, it seems I can just solder my signal onto a digital i/p and use attachinterrupt :slight_smile:

We'll see! I'll let you guys know.