Button to Affect Another Variable (FastLED)

Hello Arduino forum!
I a newb here, and the Arduino language of coding is very new to me so I need some guidance.
I am using an altered DemoReel100 sketch (from FastLED), and want the nextPattern variable to be changed not by a given time period, but a press of a button.
Here is the code for reference:

#include "FastLED.h"

FASTLED_USING_NAMESPACE

#if defined(FASTLED_VERSION) && (FASTLED_VERSION < 3001000)
#warning "Requires FastLED 3.1 or later; check github for latest code."
#endif

#define DATA_PIN    4
//#define CLK_PIN   4
#define LED_TYPE    WS2811
#define COLOR_ORDER GRB
#define NUM_LEDS    15
CRGB leds[NUM_LEDS];

#define BRIGHTNESS         200
#define FRAMES_PER_SECOND  120

void setup() {
  delay(3000); // 3 second delay for recovery
  
  // tell FastLED about the LED strip configuration
  FastLED.addLeds<LED_TYPE,DATA_PIN,COLOR_ORDER>(leds, NUM_LEDS).setCorrection(TypicalLEDStrip);
  //FastLED.addLeds<LED_TYPE,DATA_PIN,CLK_PIN,COLOR_ORDER>(leds, NUM_LEDS).setCorrection(TypicalLEDStrip);

  // set master brightness control
  FastLED.setBrightness(BRIGHTNESS);
}


// List of patterns to cycle through.  Each is defined as a separate function below.
typedef void (*SimplePatternList[])();
SimplePatternList gPatterns = { rainbow, sinelon, bpm };

uint8_t gCurrentPatternNumber = 0; // Index number of which pattern is current
uint8_t gHue = 0; // rotating "base color" used by many of the patterns
  
void loop()
{
  // Call the current pattern function once, updating the 'leds' array
  gPatterns[gCurrentPatternNumber]();

  // send the 'leds' array out to the actual LED strip
  FastLED.show();  
  // insert a delay to keep the framerate modest
  FastLED.delay(1000/FRAMES_PER_SECOND); 

  // do some periodic updates
  EVERY_N_MILLISECONDS( 20 ) { gHue++; } // slowly cycle the "base color" through the rainbow
  EVERY_N_SECONDS( 10 ) { nextPattern(); } // change patterns periodically
}

#define ARRAY_SIZE(A) (sizeof(A) / sizeof((A)[0]))

void nextPattern()
{
  // add one to the current pattern number, and wrap around at the end
  gCurrentPatternNumber = (gCurrentPatternNumber + 1) % ARRAY_SIZE( gPatterns);
}

void rainbow() 
{
  // FastLED's built-in rainbow generator
  fill_rainbow( leds, NUM_LEDS, gHue, 7);
}

void sinelon()
{
  // a colored dot sweeping back and forth, with fading trails
  fadeToBlackBy( leds, NUM_LEDS, 20);
  int pos = beatsin16( 13, 0, NUM_LEDS-1 );
  leds[pos] += CHSV( gHue, 255, 192);
}

void bpm()
{
  // colored stripes pulsing at a defined Beats-Per-Minute (BPM)
  uint8_t BeatsPerMinute = 380;
  CRGBPalette16 palette = PartyColors_p;
  uint8_t beat = beatsin8( BeatsPerMinute, 64, 255);
  for( int i = 0; i < NUM_LEDS; i++) { //9948
    leds[i] = ColorFromPalette(palette, gHue+(i*2), beat-gHue+(i*10));
  }
}

I basically want to change the:

EVERY_N_SECONDS( 10 ) { nextPattern(); }

to a statement which instead changes on the press of button.
Advised code and schematics would be greatly appreciated to aid this. I have the basic setup working as shown here:

Thank you in advance!

have a look at Tutorial.DigitalReadSerial

Connect a button between a pin and GND. In setup, use

pinMode (somePin, INPUT_PULLUP);

In loop, replace

 EVERY_N_SECONDS( 10 ) {
    nextPattern();  // change patterns periodically
  }

by

  if (digitalRead(somePin) == LOW)
  {
    delay(500);
    nextPattern();  // change patterns periodically
  }

It needs polishing but this should give you a start. The delay is there to prevent the code from going too fast if you keep the button pressed too long. You should study the state change detection example; if you implement the principle, you don't need the delay.

sterretje:
Connect a button between a pin and GND. In setup, use

pinMode (somePin, INPUT_PULLUP);

In loop, replace

 EVERY_N_SECONDS( 10 ) {

nextPattern();  // change patterns periodically
  }



by


if (digitalRead(somePin) == LOW)
  {
    delay(500);
    nextPattern();  // change patterns periodically
  }



It needs polishing but this should give you a start. The delay is there to prevent the code from going too fast if you keep the button pressed too long. You should study the state change detection example; if you implement the principle, you don't need the delay.

Brilliant! Thanks! Has worked perfectly. Will use the proper 'full code' soon. Thanks for you help!