Can't upload sketch!

So I’m trying to upload this sketch to my Arduino Nano and it won’t work it says: “having trouble uploading to Arduino Nano”! Then I switched to another Nano and still didn’t work. Then I switched to a Arduino Mega and STIILL didn’t work! Please help I have to upload this code!

Code:

[code]
#include <PID_v1.h>
#include <LMotorController.h>
#include "I2Cdev.h"
#include "MPU6050_6Axis_MotionApps20.h"

#if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
    #include "Wire.h"
#endif

#define MIN_ABS_SPEED 20

MPU6050 mpu;

// MPU control/status vars
bool dmpReady = false;  // set true if DMP init was successful
uint8_t mpuIntStatus;   // holds actual interrupt status byte from MPU
uint8_t devStatus;      // return status after each device operation (0 = success, !0 = error)
uint16_t packetSize;    // expected DMP packet size (default is 42 bytes)
uint16_t fifoCount;     // count of all bytes currently in FIFO
uint8_t fifoBuffer[64]; // FIFO storage buffer

// orientation/motion vars
Quaternion q;           // [w, x, y, z]         quaternion container
VectorFloat gravity;    // [x, y, z]            gravity vector
float ypr[3];           // [yaw, pitch, roll]   yaw/pitch/roll container and gravity vector

//PID
double originalSetpoint = 175.8;
double setpoint = originalSetpoint;
double movingAngleOffset = 0.1;
double input, output;
int moveState=0; //0 = balance; 1 = back; 2 = forth
double Kp = 50;
double Kd = 1.4;
double Ki = 60;
PID pid(&input, &output, &setpoint, Kp, Ki, Kd, DIRECT);

double motorSpeedFactorLeft = 0.6;
double motorSpeedFactorRight = 0.5;
//MOTOR CONTROLLER
int ENA = 5;
int IN1 = 6;
int IN2 = 7;
int IN3 = 8;
int IN4 = 9;
int ENB = 10;
LMotorController motorController(ENA, IN1, IN2, ENB, IN3, IN4, motorSpeedFactorLeft, motorSpeedFactorRight);

//timers
long time1Hz = 0;
long time5Hz = 0;

volatile bool mpuInterrupt = false;     // indicates whether MPU interrupt pin has gone high
void dmpDataReady()
{
    mpuInterrupt = true;
}


void setup()
{
    // join I2C bus (I2Cdev library doesn't do this automatically)
    #if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
        Wire.begin();
        TWBR = 24; // 400kHz I2C clock (200kHz if CPU is 8MHz)
    #elif I2CDEV_IMPLEMENTATION == I2CDEV_BUILTIN_FASTWIRE
        Fastwire::setup(400, true);
    #endif

    // initialize serial communication
    // (115200 chosen because it is required for Teapot Demo output, but it's
    // really up to you depending on your project)
    Serial.begin(115200);
    while (!Serial); // wait for Leonardo enumeration, others continue immediately

    // initialize device
    Serial.println(F("Initializing I2C devices..."));
    mpu.initialize();

    // verify connection
    Serial.println(F("Testing device connections..."));
    Serial.println(mpu.testConnection() ? F("MPU6050 connection successful") : F("MPU6050 connection failed"));

    // load and configure the DMP
    Serial.println(F("Initializing DMP..."));
    devStatus = mpu.dmpInitialize();

    // supply your own gyro offsets here, scaled for min sensitivity
    mpu.setXGyroOffset(220);
    mpu.setYGyroOffset(76);
    mpu.setZGyroOffset(-85);
    mpu.setZAccelOffset(1788); // 1688 factory default for my test chip

    // make sure it worked (returns 0 if so)
    if (devStatus == 0)
    {
        // turn on the DMP, now that it's ready
        Serial.println(F("Enabling DMP..."));
        mpu.setDMPEnabled(true);

        // enable Arduino interrupt detection
        Serial.println(F("Enabling interrupt detection (Arduino external interrupt 0)..."));
        attachInterrupt(0, dmpDataReady, RISING);
        mpuIntStatus = mpu.getIntStatus();

        // set our DMP Ready flag so the main loop() function knows it's okay to use it
        Serial.println(F("DMP ready! Waiting for first interrupt..."));
        dmpReady = true;

        // get expected DMP packet size for later comparison
        packetSize = mpu.dmpGetFIFOPacketSize();
        
        //setup PID
        
        pid.SetMode(AUTOMATIC);
        pid.SetSampleTime(10);
        pid.SetOutputLimits(-255, 255);  
    }
    else
    {
        // ERROR!
        // 1 = initial memory load failed
        // 2 = DMP configuration updates failed
        // (if it's going to break, usually the code will be 1)
        Serial.print(F("DMP Initialization failed (code "));
        Serial.print(devStatus);
        Serial.println(F(")"));
    }
}


void loop()
{
    // if programming failed, don't try to do anything
    if (!dmpReady) return;

    // wait for MPU interrupt or extra packet(s) available
    while (!mpuInterrupt && fifoCount < packetSize)
    {
        //no mpu data - performing PID calculations and output to motors
        
        pid.Compute();
        motorController.move(output, MIN_ABS_SPEED);
        
    }

    // reset interrupt flag and get INT_STATUS byte
    mpuInterrupt = false;
    mpuIntStatus = mpu.getIntStatus();

    // get current FIFO count
    fifoCount = mpu.getFIFOCount();

    // check for overflow (this should never happen unless our code is too inefficient)
    if ((mpuIntStatus & 0x10) || fifoCount == 1024)
    {
        // reset so we can continue cleanly
        mpu.resetFIFO();
        Serial.println(F("FIFO overflow!"));

    // otherwise, check for DMP data ready interrupt (this should happen frequently)
    }
    else if (mpuIntStatus & 0x02)
    {
        // wait for correct available data length, should be a VERY short wait
        while (fifoCount < packetSize) fifoCount = mpu.getFIFOCount();

        // read a packet from FIFO
        mpu.getFIFOBytes(fifoBuffer, packetSize);
        
        // track FIFO count here in case there is > 1 packet available
        // (this lets us immediately read more without waiting for an interrupt)
        fifoCount -= packetSize;

        mpu.dmpGetQuaternion(&q, fifoBuffer);
        mpu.dmpGetGravity(&gravity, &q);
        mpu.dmpGetYawPitchRoll(ypr, &q, &gravity);
        #if LOG_INPUT
            Serial.print("ypr\t");
            Serial.print(ypr[0] * 180/M_PI);
            Serial.print("\t");
            Serial.print(ypr[1] * 180/M_PI);
            Serial.print("\t");
            Serial.println(ypr[2] * 180/M_PI);
        #endif
        input = ypr[1] * 180/M_PI + 180;
   }
}

[/code]

Please do this:

  • (In the Arduino IDE) File > Preferences
  • Uncheck the checkbox next to “Show verbose output during: compilation”
  • Check the checkbox next to "Show verbose output during: upload
  • Click “OK”
  • Sketch > Upload
  • After the upload fails, you’ll see a button on the right side of the orange bar “Copy error messages” (or the icon that looks like two pieces of paper at the top right corner of the black console window in the Arduino Web Editor). Click that button.
  • In a forum reply here, click on the reply field.
  • Click the </> button on the forum toolbar. This will add the forum’s code tags markup to your reply.
  • Press “Ctrl + V”. This will paste the upload output between the code tags.
  • Move the cursor outside of the code tags before you add any additional text to your reply.

Arduino: 1.8.13 (Windows 10), Board: "Arduino Nano, ATmega328P (Old Bootloader)"

C:\Users\Burak-as-user\Documents\Arduino\libraries\arduino-self-balancing-robot-master\PID_v1.cpp:45:6: error: prototype for 'void PID::Compute()' does not match any in class 'PID'

void PID::Compute()

^~~

In file included from C:\Users\Burak-as-user\Documents\Arduino\libraries\arduino-self-balancing-robot-master\PID_v1.cpp:14:0:

C:\Users\Burak-as-user\Documents\Arduino\libraries\Arduino-PID-Library-master/PID_v1.h:29:10: error: candidate is: bool PID::Compute()

bool Compute(); // * performs the PID calculation. it should be

^~~~~~~

C:\Users\Burak-as-user\Documents\Arduino\libraries\arduino-self-balancing-robot-master\PID_v1.cpp: In member function 'void PID::SetOutputLimits(double, double)':

C:\Users\Burak-as-user\Documents\Arduino\libraries\arduino-self-balancing-robot-master\PID_v1.cpp:132:8: error: 'ITerm' was not declared in this scope

if(ITerm > outMax) ITerm= outMax;

^~~~~

C:\Users\Burak-as-user\Documents\Arduino\libraries\arduino-self-balancing-robot-master\PID_v1.cpp: In member function 'void PID::Initialize()':

C:\Users\Burak-as-user\Documents\Arduino\libraries\arduino-self-balancing-robot-master\PID_v1.cpp:158:4: error: 'ITerm' was not declared in this scope

ITerm = *myOutput;

^~~~~

Multiple libraries were found for "PID_v1.h"

Used: C:\Users\Burak-as-user\Documents\Arduino\libraries\Arduino-PID-Library-master

Not used: C:\Users\Burak-as-user\Documents\Arduino\libraries\arduino-self-balancing-robot-master

Multiple libraries were found for "Wire.h"

Used: C:\Program Files (x86)\Arduino\hardware\arduino\avr\libraries\Wire

Not used: C:\Users\Burak-as-user\Documents\Arduino\libraries\Wire-master

exit status 1

Error compiling for board Arduino Nano.

This report would have more information with
"Show verbose output during compilation"
option enabled in File -> Preferences.

buavts:
Multiple libraries were found for "PID_v1.h"

Used: C:\Users\Burak-as-user\Documents\Arduino\libraries\Arduino-PID-Library-master

Not used: C:\Users\Burak-as-user\Documents\Arduino\libraries\arduino-self-balancing-robot-master

Multiple libraries were found for "Wire.h"

Used: C:\Program Files (x86)\Arduino\hardware\arduino\avr\libraries\Wire

Not used: C:\Users\Burak-as-user\Documents\Arduino\libraries\Wire-master

It looks like maybe you've been taking the "shotgun" approach to installing libraries, which rarely ends well. The error you're getting is likely caused by the author of your sketch having written it for a different library than the one the Arduino IDE is using. You might try deleting this folder:
C:\Users\Burak-as-user\Documents\Arduino\libraries\Arduino-PID-Library-master

But this is a compilation error. You originally reported an uploading error, but if compilation fails then the upload will never even start. So you might still have another problem after you get the compilation to pass, but you just have to work away at it and fix one problem at a time until you achieve success with your project.

Okay thanks.

You're welcome. I'm glad if I was able to be of assistance. Enjoy!
Per

This topic was automatically closed 120 days after the last reply. New replies are no longer allowed.