change i2C pins for 7 segment display

hello, Im a bit of a noob. I want to display the time from a DS1307 RTC on a .56" 7 segment display with an i2c backpack. The problem is that both libraries utilize analog pins 4 & 5. How can I modify either the RTC library I got from here http://www.pjrc.com/teensy/td_libs_DS1307RTC.html or the Adafruit_LedBackpack library to use different pins?

Also, I would really appreciate it if someone could explain this to me. It from adafruit’s instructions.

These displays use I2C to communicate, 2 pins are required to
interface. There are multiple selectable I2C addresses. For backpacks
with 2 Address Select pins: 0x70, 0x71, 0x72 or 0x73.

Does 0x70 correspond to an analog pin or something?

You need to look up !2C bus. You connect many peripherals in parallel to the bus. A4 is SDA so connect SDA on backpack and RTC to A4. Connect SCL of the backpack and RTC to A5. 0x70 (or 0x71, 0x72 or 0x73 depending on what its set at) is the ADDRESS, on the bus, of the backpack.

Here is Mr. Gammon's tutorial on I2C.

http://www.gammon.com.au/forum/?id=10896

Okay so they both use a4 as long as they have different addresses? Anyways Ive got other problems now, the 7 segment from adafruit is not responding. It only dimly lights the top 4 segments.

First, do you have the pull up resistors installed?
Second, here is Nick Gammon’s I2C scanner.

// I2C Scanner
// Written by Nick Gammon
// Date: 20th April 2011

#include <Wire.h>

void setup() {
  Serial.begin (115200);

  // Leonardo: wait for serial port to connect
  while (!Serial) 
    {
    }

  Serial.println ();
  Serial.println ("I2C scanner. Scanning ...");
  byte count = 0;
  
  Wire.begin();
  for (byte i = 1; i < 120; i++)
  {
    Wire.beginTransmission (i);
    if (Wire.endTransmission () == 0)
      {
      Serial.print ("Found address: ");
      Serial.print (i, DEC);
      Serial.print (" (0x");
      Serial.print (i, HEX);
      Serial.println (")");
      count++;
      delay (1);  // maybe unneeded?
      } // end of good response
  } // end of for loop
  Serial.println ("Done.");
  Serial.print ("Found ");
  Serial.print (count, DEC);
  Serial.println (" device(s).");
}  // end of setup

void loop() {}

Upload this to your Arduino and observe the results. Make sure Serial Monitor baud rate is set to 115200. The code will find devices attached to the bus and report their addresses. That way you will, at least know that the backpack is on the bus and can communicate.