Comment utiliser le shield wifi esp8266 ?

International Français
1

Bonjour a tous, j'ai récemment acquis un shield wifi esp8266 et j'ai du mal a l'utiliser .
Je possède une arduino uno et j'ai essayé de la configurer avec la librairie ESP8266wifi trouvée au lien ci-dessous mais a chaque fois il ce produit l’erreur suivante :

"C:\Program Files (x86)\Arduino\libraries\ESP8266WiFi\src/ESP8266WiFiGeneric.h:27:22: fatal error: functional: No such file or directory

#include

^"

voici le lien que j'ai utilisé: Arduino/doc/esp8266wifi at master · esp8266/Arduino · GitHub

Le code :

#include <ESP8266WiFi.h>
const char* ssid = "your-ssid";
const char* password = "your-password";

// Create an instance of the server
// specify the port to listen on as an argument
WiFiServer server(80);

void setup() {
  Serial.begin(115200);
  delay(10);

  // prepare GPIO2
  pinMode(2, OUTPUT);
  digitalWrite(2, 0);
  
  // Connect to WiFi network
  Serial.println();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  
  WiFi.begin(ssid, password);
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  
  // Start the server
  server.begin();
  Serial.println("Server started");

  // Print the IP address
  Serial.println(WiFi.localIP());
}

void loop() {
  // Check if a client has connected
  WiFiClient client = server.available();
  if (!client) {
    return;
  }
  
  // Wait until the client sends some data
  Serial.println("new client");
  while(!client.available()){
    delay(1);
  }
  
  // Read the first line of the request
  String req = client.readStringUntil('\r');
  Serial.println(req);
  client.flush();
  
  // Match the request
  int val;
  if (req.indexOf("/gpio/0") != -1)
    val = 0;
  else if (req.indexOf("/gpio/1") != -1)
    val = 1;
  else {
    Serial.println("invalid request");
    client.stop();
    return;
  }

  // Set GPIO2 according to the request
  digitalWrite(2, val);
  
  client.flush();

  // Prepare the response
  String s = "HTTP/1.1 200 OK\r\nContent-Type: text/html\r\n\r\n<!DOCTYPE HTML>\r\n<html>\r\nGPIO is now ";
  s += (val)?"high":"low";
  s += "</html>\n";

  // Send the response to the client
  client.print(s);
  delay(1);
  Serial.println("Client disonnected");

  // The client will actually be disconnected 
  // when the function returns and 'client' object is detroyed
}
2

Quand on utilise une librairie, il faut l'installer avant.

Le lien que tu donnes c'est pour utiliser directement les ESP avec l'IDE arduino, sans passer par une uno. Sinon c'est plutôt les commandes AT qui sont utilisées (même si d'autre options sont possibles).

Par contre, c'est quoi un shield wifi esp8266, tu as un lien, une référence?