Compilation terminated problem

Hi all, im new to Arduino so pardon if I sound a bit lost here.

I have an error when I tried to verify any sketch

Arduino: 1.8.2 (Windows 8.1), Board: "Arduino Due (Programming Port)"
C:\Users\Ambrose\Desktop\Micro\Micro_Digital_Thermometer\Micro_Digital_Thermometer.ino:29:27: fatal error: Grove_LED_Bar.h: No such file or directory
#include <Grove_LED_Bar.h>
** ^**
compilation terminated.
exit status 1
Error compiling for board Arduino Due (Programming Port).

Here is the code I am using:

#include <Adafruit_CircuitPlayground.h>

//Defines (Machine States) - Begin
//Define and label the number of states in the FSM
#define mSTATE_1  1     //T1
#define mSTATE_2  2     //T2
#define mSTATE_3  3     //T3
//Defines (Machine States) - End

//Define (GPIO Labels) - Begin
//Define and label all GPIOs with meaningful names.
#define BUZZER_PIN       2                 // GPIO2 (Output) for Fan control
#define TMP_SENSOR_PIN   A0                // A0 (Input) for LM35 Temperature Sensor Analog Signal
#define LED_CLK_PIN      5
#define LED_DATA_PIN     4 
//Define (GPIO Labels) - End

//Define (Signals and Messages) - Begin
//Define and label control signals and messages.
#define ON  1                                   // Turn on buzzer (Buzzer On)
#define OFF 0                                   // Turn of buzzer (Buzzer Off)

#define DISPLAY_TMP    DisplayTemperature(TMP)  // Function to Display Temperature

//Define (Signals and Messages) - End

//Includes - Begin
//Place all include files (preprocessor directives, datatypes, etc) here.
#include <Grove_LED_Bar.h>
#include <math.h>
//Includes - End

//External Peripherals Resources Initialization - Begin 
//Place all declarations and codes related to external peripherals initializations here.
//External Perihperals: Keypad, LCD Module, etc.
Grove_LED_Bar bar(LED_CLK_PIN, LED_DATA_PIN, 1);      // Clock pin, Data pin, Orientation
//External Peripherals Resources Initialization - End   

//Global Variables - Begin
//Declare global variables for use by application here.
unsigned int MACHINE_STATE;               // Variable to hold current machine state
       float TMP;                         // Variable to hold Measured Temperature
       bool  BUZZER;                      // Variable to control buzer ON / OFF             

const int    B=4275;                      // B value of the thermistor
const int    R0 = 100000;                 // R0 = 100k
//Global Variables - End

void setup()  // put your setup code here, to run once.
{
  Serial.begin(9600);                     // Initialize serial port for debug
  analogReadResolution(10);               // Set ADC resolution to 10-bit
  pinMode(BUZZER_PIN, OUTPUT);
  bar.begin();
 
  //Initial State Initialization - Begin
  //Set Initial State Transition and Action
  MACHINE_STATE = mSTATE_1; 
  BUZZER = OFF;
  //Initial State Initialization - End
}

void loop()  // put your main code here, to run repeatedly.
{
  //Sample Input - Begin
  //Read (or process) and update information from input device at a periodic interval
  TMP = MeasureTemperature();                   // Measure Temperature and update TMP with latest temperature
  digitalWrite(BUZZER_PIN , BUZZER);            // Update Buzzer Pin Status (Buzzer On / Off)
  //Sample Input - End

  //Finite State Machine - Begin  
  switch(MACHINE_STATE)
  {
    case mSTATE_1:  //State 1
     Serial.print("STATE_1:T1 TMP=");       // Debug message. 
     Serial.println(TMP);                   // Debug message.                          
     if(TMP < 45)                           // Transition: Check for condition (or rule). 
     {
        MACHINE_STATE = mSTATE_1;           // Transition: Loop back to current state. 
        DISPLAY_TMP;                        // Transition: Set Action (Output).
     }
     else if((TMP >=45) && (TMP < 50))      // Transition: Check for condition (or rule).
     {
        MACHINE_STATE = mSTATE_2;           // Transition: Jump to Next State (mSTATE_2) if condition is valid. 
        DISPLAY_TMP;                        // Transition: Set Action (Output).
        BUZZER = ON;                        // Transition: Set Action (Output).
     }
     else if(TMP >=50)                      // Transition: Check for condition (or rule).
     {
        MACHINE_STATE = mSTATE_3;           // Transition: Jump to Next State (mSTATE_3) if condition is valid. 
        DISPLAY_TMP;                        // Transition: Set Action (Output).
        BUZZER = ON;                        // Transition: Set Action (Output).
     }     
     else
     {}
     break;

   case mSTATE_2:  //State 2
     Serial.print("STATE_2:T2 TMP=");       // Debug message.  
     Serial.println(TMP);                   // Debug message.                                                  
     if((TMP >=45) && (TMP < 50))           // Transition: Check for condition (or rule). 
     {
        MACHINE_STATE = mSTATE_2;           // Transition: Loop back to current state.  
        DISPLAY_TMP;                        // Transition: Set Action (Output).
        BUZZER = !BUZZER;                   // Transition: Set Action (Output).
     }
     else if((TMP < 45) || (TMP >=50))      // Transition: Check for condition (or rule).
     {
        MACHINE_STATE = mSTATE_1;           // Transition: Jump to Next State (mSTATE_1) if condition is valid.
        DISPLAY_TMP;                        // Transition: Set Action (Output).
        BUZZER = OFF;                       // Transition: Set Action (Output).        
     }
     else
     {}
     break;     
     
    case mSTATE_3:  //State 3
     Serial.print("STATE_2:T3 TMP=");       // Debug message. 
     Serial.println(TMP);                   // Debug message.                              
     if(TMP >= 50)                          // Transition: Check condition (or rule) for next state.
     {
        MACHINE_STATE = mSTATE_3;           // Transition: Loop back to current state.  
        DISPLAY_TMP;                        // Transition: Set Action (Output).
     }
     else if(TMP < 50)                      // Transition: Check condition (or rule) for next state. 
     {
        MACHINE_STATE = mSTATE_1;           // Transition: Jump to Next State (mSTATE_1) if condition is valid.
        DISPLAY_TMP;                        // Transition: Set Action (Output).
        BUZZER = OFF;                       // Transition: Set Action (Output).               
     }
     else
     {}
     break;

    default:                                // 
      MACHINE_STATE = mSTATE_1;             // Set the Initial State.
  }
  //Finite State Machine - End 

  delay(200);                               // Set Loop Refresh (Refresh rate of the Finite State Machine).
}

//Functions to measure and display Ambient Temperature
//This last section is user defined for the purpose of adding custom supporting functions. 
//(In this example, a function to measure room temperature is added to the section).  
float MeasureTemperature()
{
    int a = analogRead(TMP_SENSOR_PIN);

    float R = 1023.0/((float)a)-1.0;
    R = 100000.0*R;

    float temperature=1.0/(log(R/100000.0)/B+1/298.15)-273.15;//convert to temperature via datasheet ;
    return temperature;
}

void DisplayTemperature(float temperature)
{
   unsigned int value = (unsigned int) temperature / 5;
   unsigned int x;

   for(x = 1; x <= 10; x++)
   {
      bar.setLed(x, 0); 
   }

   for(x = 1; x <= value; x++)
   {
      bar.setLed(x, 1); 
   }
}

I have created a folder called Micro on my desktop. I created a subfolder called libraries inside it. Libraries subfolder is blank. The code I have is a unzipped code downloaded from my school’s website and located in the Micro folder.

My preference is set to C:\Users\User_459\Desktop\Micro

Anyone can help? I tried looking through for solutions but cant find any. Thanks.

You need to install the library that contains Grove_LED_Bar.h. For more information on installing libraries see: https://www.arduino.cc/en/Guide/Libraries

Please use code tags (</> button on the toolbar) when you post code or warning/error messages. The reason is that the forum software can interpret parts of your code as markup, leading to confusion, wasted time, and a reduced chance for you to get help with your problem. This will also make it easier to read your code and to copy it to the IDE or editor. If your browser doesn’t show the posting toolbar then you can just manually add the code tags:
[code]`` [color=blue]// your code is here[/color] ``[/code]
Using code tags and other important information is explained in the How to use this forum post. Please read it.

It might be because you don't have your libraries in the standard location.

Update: Solved

Moved all folders holding containing .cpp files of LED , buzzer etc into Micro>libraries

File>Preferences>Sketchbook Location>C:\Users\User_459\Desktop\Micro