There are a few more things that need to be in setup(). Try this:
#include <OneWire.h>
OneWire ds(10); // on pin 10 (a 4.7K resistor is necessary)
byte data[12];
byte addr[8];
byte type_s;
void setup(void) {
byte i;
Serial.begin(9600);
// This is done ONCE in setup()
if ( !ds.search(addr)) {
Serial.println("No more addresses.");
Serial.println();
ds.reset_search();
delay(250);
return;
}
Serial.print("ROM =");
for( i = 0; i < 8; i++) {
Serial.write(' ');
Serial.print(addr[i], HEX);
}
if (OneWire::crc8(addr, 7) != addr[7]) {
Serial.println("CRC is not valid!");
return;
}
Serial.println();
// the first ROM byte indicates which chip
switch (addr[0]) {
case 0x10:
Serial.println(" Chip = DS18S20"); // or old DS1820
type_s = 1;
break;
case 0x28:
Serial.println(" Chip = DS18B20");
type_s = 0;
break;
case 0x22:
Serial.println(" Chip = DS1822");
type_s = 0;
break;
default:
Serial.println("Device is not a DS18x20 family device.");
return;
}
// bits
// of
// precision
// 0 - 9
// 1 - 10
// 2 - 11
// 3 - 12
// For 9 bit precision
int t_precision = 0;
ds.select(addr);
ds.write(0x4E);
// write zero into the alarm registers
ds.write(0);
ds.write(0);
// and write t_precision into the configuration register
// to select the precision of the temperature
ds.write(t_precision << 5);
// Write them to the EEPROM
ds.write(0x48);
}
void loop(void) {
byte i;
byte present = 0;
float celsius, fahrenheit;
ds.reset();
ds.select(addr);
ds.write(0x44, 1); // start conversion, with parasite power on at the end
delay(1000); // maybe 750ms is enough, maybe not
// we might do a ds.depower() here, but the reset will take care of it.
present = ds.reset();
ds.select(addr);
ds.write(0xBE); // Read Scratchpad
Serial.print(" Data = ");
Serial.print(present, HEX);
Serial.print(" ");
for ( i = 0; i < 9; i++) { // we need 9 bytes
data[i] = ds.read();
Serial.print(data[i], HEX);
Serial.print(" ");
}
Serial.print(" CRC=");
Serial.print(OneWire::crc8(data, 8), HEX);
Serial.println();
// Convert the data to actual temperature
// because the result is a 16 bit signed integer, it should
// be stored to an "int16_t" type, which is always 16 bits
// even when compiled on a 32 bit processor.
int16_t raw = (data[1] << 8) | data[0];
if (type_s) {
raw = raw << 3; // 9 bit resolution default
if (data[7] == 0x10) {
// "count remain" gives full 12 bit resolution
raw = (raw & 0xFFF0) + 12 - data[6];
}
} else {
byte cfg = (data[4] & 0x60);
// at lower res, the low bits are undefined, so let's zero them
if (cfg == 0x00) raw = raw & ~7; // 9 bit resolution, 93.75 ms
else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
//// default is 12 bit resolution, 750 ms conversion time
}
celsius = (float)raw / 16.0;
fahrenheit = celsius * 1.8 + 32.0;
Serial.print(" Temperature = ");
Serial.print(celsius);
Serial.print(" Celsius, ");
Serial.print(fahrenheit);
Serial.println(" Fahrenheit");
}
On a Teensy 3.0 it prints this:
ROM = 28 1E BD 0 4 0 0 6B
Chip = DS18B20
Data = 1 5C 1 0 0 3F FF 4 10 B9 CRC=B9
Temperature = 21.75 Celsius, 71.15 Fahrenheit
Data = 1 58 1 0 0 3F FF 8 10 E1 CRC=E1
Temperature = 21.50 Celsius, 70.70 Fahrenheit
Data = 1 58 1 0 0 3F FF 8 10 E1 CRC=E1
Temperature = 21.50 Celsius, 70.70 Fahrenheit
Data = 1 58 1 0 0 3F FF 8 10 E1 CRC=E1
Temperature = 21.50 Celsius, 70.70 Fahrenheit
Data = 1 58 1 0 0 3F FF 8 10 E1 CRC=E1
Temperature = 21.50 Celsius, 70.70 Fahrenheit
Data = 1 58 1 0 0 3F FF 8 10 E1 CRC=E1
Temperature = 21.50 Celsius, 70.70 Fahrenheit
Data = 1 58 1 0 0 3F FF 8 10 E1 CRC=E1
Temperature = 21.50 Celsius, 70.70 Fahrenheit
The code in setup() will start an enumeration of the devices on the bus but it will pick the first one that answers (actually, it will find them in numerical order and return the first one). The loop() code will use that first ds18b20. If you want to use more than one ds18b20 you will have to modify the code.
Pete