Enum Frage für Dummies

ipeco85 · October 16, 2022, 4:36pm

Hallo Wissende,
Für kleine Steuerungsaufgaben verwende ich gerne den Arduino Nano. Da das allerdings nur mit längeren Pausen stattfindet, fange ich leider immer wieder von Neuem an ;-(

Diesmal hätte ich eine Aufgabe zu Frequenzvervielfachung im Bereich von wenigen Hertz bis zu ca. 200Hz. Ein passendes Programm habe Dank des Fleißes Anderer schon gefunden und erfolgreich getestet.
Diese Programm verwendet zur Deklaration der Frequenzvervielfachung einen "enum" Wert.
enum { MULTIPLIER = 6 }; // Zahlenwert ist der halbe Vervielfacher, den ich gerne als Variable hätte, durch externe Schalter, einstellbar,
Das ist mir leider bisher nicht gelungen, weil ich offenbar die Funktion nicht richtig verstehe.
Die Multiplier-Funktion läuft in einer Interrupt-Routine ab, im Loop wird der Prozessor schlafen geschickt und wacht mit dem nächsten Eingangsimpuls wieder auf.
Hier der von mir bereits veränderte Code:


// Name: FrequencyMultiplier.ino
// Date: 2016-11-29
// Uses: Digitla frequency multiplier example.
// Author: Andrew Que (http://www.DrQue.net)
//
//                                (C) Copyright 2016 by Andrew Que
//                                       http://www.bb7.com/
//=================================================================================================
#include <avr/sleep.h>

// Pin for multiplied output.
// NOTE: Fixed to the output for OCR1A.
enum { OUTPUT_PIN = 9 };

// Pin for input frequency.
// NOTE: Fixed to the input capture pin.
enum { INPUT_PIN = 8 };

// How many divisions to break the rotation into.
// This is basically the multiplication factor for the incoming frequency. 
enum { MULTIPLIER = 6 };
/ /int MULTIPLIER = 8 ;   Versuch - nicht gelungen ...

// Timer count when the most recent input pulse arrived.
static unsigned volatile currentTime;

// Timer count when the previous input pulse arrived.
static unsigned volatile lastTime;

// Width of the incoming input pulse (in timer counts).
static unsigned volatile inputPulseWidth;

// Period of a sub-division of the input pulse.
static unsigned volatile divisionPeriod;

// Current subdivision.
static unsigned volatile divisionCount = 0;

// constants won't change. They're used here to set pin numbers:
const int buttonPin = 2;  // the number of the pushbutton pin
const int ledPin = 13;    // the number of the LED pin

// variables will change:
int buttonState = 0;  // variable for reading the pushbutton status


//-------------------------------------------------------------------------------------------------
// USES:
//   Interrupt for timer 1 compare A.  Used to set new compare value to toggle output pin.
//-------------------------------------------------------------------------------------------------
ISR( TIMER1_COMPA_vect )
{
  // Lag factor.  Used to correct phase once each rotation.  Typically zero.
  int lag = 0;

  // Count this division.
  divisionCount += 1;

  // If half way through the cycle calculate a correction factor for phase.
  if ( ( MULTIPLIER / 2 ) == divisionCount )
    lag = OCR1A - ( currentTime + ( inputPulseWidth / 2 ) );

  // Rollover at pulse count.
  if ( MULTIPLIER == divisionCount )
    divisionCount = 0;

  // Set new next compare value.
  OCR1A += ( divisionPeriod / 2 ) - lag;
}

//-------------------------------------------------------------------------------------------------
// USES:
//   Interrupt for timer 1 capture event.  Used to measure the width of the input pin
// pulse and calculate the division period.
//-------------------------------------------------------------------------------------------------
ISR( TIMER1_CAPT_vect )
{
  // Disable interrupts.
  cli();

  // Grab input capture.
  // This is the time at which the input pulse had a rising edge.
  currentTime = ICR1;

  // Measure the time between this pulse and the previous pulse.
  inputPulseWidth = currentTime - lastTime;

  // Make the last time the current time for next measurement.
  lastTime = currentTime;

  // Calculate period of divisions.
  // Include long and short divisions.
  divisionPeriod = inputPulseWidth / ( MULTIPLIER / 2);

  // Enable compare output.
  TCCR1A |= 1 << COM1A0;

  // Enable interrupts.
  sei();
}

//-------------------------------------------------------------------------------------------------
// USES:
//   Setup I/O and timers for operation.
//-------------------------------------------------------------------------------------------------
void setup()
{
  // Set sleep mode for main loop--interrupts will do all the work.
  set_sleep_mode( SLEEP_MODE_IDLE );
  sleep_enable();

  // Setup outputs.
  pinMode( OUTPUT_PIN,  OUTPUT );
 // initialize the LED pin as an output:
  pinMode(ledPin, OUTPUT);
  // initialize the pushbutton pin as an input:
  pinMode(buttonPin, INPUT_PULLUP);
  
  //---------------------------------
  // Setup timer 1 for input capture.
  //---------------------------------

  // Disable timer for setup.
  TCCR1B = 0x00;

  // Reset timer count.
  TCNT1 = 0x00;

  // Clear interrupt flags.
  TIFR1 = 0x00;

  // Enable interrupts.
  TIMSK1 =
      ( 1 << ICIE1 )   // Timer/Counter1, Input Capture Interrupt Enable.
    | ( 1 << OCIE1A ); // Timer/Counter1, Output Compare A Match Interrupt Enable.

  // Timer/Counter1 Control Register A to default normal operation.
  // (There were changed by the Arduino startup code.)
  TCCR1A = 0;
  TCCR1B = 0;

  // Setup Input Capture and clock divide rate.
  TCCR1B =
      ( 1 << ICNC1 ) // Enable Input Capture Noise Canceler.
    | ( 1 << ICES1 ) // Set Input Capture Edge Select to rising edge.
    | ( 1 << CS11 ) | ( 1 << CS10 );  // Clock Select to clk/64.
}

//-------------------------------------------------------------------------------------------------
// USES:
//   Main loop.  Just sleeps and allows interrupts to do the work.
//-------------------------------------------------------------------------------------------------
void loop()
{  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);

  // check if the pushbutton is pressed. If it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    // Schalter "ein" Signal x2:
   int MULTIPLIER = 2;
    // turn LED on:
   digitalWrite(ledPin, HIGH);
  } else {
    // Schalter "aus" Signal geht durch:
   int MULTIPLIER = 4;
    // turn LED off:
    //digitalWrite(ledPin, LOW); 
  }
  {
  // Put the device to sleep:
  sleep_mode();
  }
}

Ich habe probiert, im loop den Schalter auszulesen, das funktioniert ja, aber ich habe leider keine Idee, wie und wo im Programm man den Wert "MULTIPLIER" im Betrieb verändern kann.
Die Verwendung von "enum" ist ja für mich nicht zwingend erforderlich, aber wenn der Code schon wie gewünscht funktioniert, würde ich ihn gerne im wesentlichen belassen ...

Vielen Dank für eure Zeit und Hilfestellung
Peter

UKHeliBob · October 16, 2022, 4:40pm

Im englischen Teil des Forum müssen die Beiträge und Diskussionen in englischer Sprache verfasst werden. Deswegen wurde diese Diskussion in den deutschen Teil des Forums verschoben.

mfg ein Moderator.

noiasca · October 16, 2022, 5:04pm

mir entzieht sich, warum da jemand eine enum (=Aufzählung) mit einem Wert macht. Ändere die mal von

enum { MULTIPLIER = 6 };

auf

byte  MULTIPLIER =6;

also eine ganz normale Variablen.

Aufpassen, unten im Loop hast wieder lokale Variablen die auch so heißen ...

agmue · October 16, 2022, 5:06pm

Das ist die Lösung!

Mit enum wird eine Konstante gebildet, Du benötigst aber eine Variable:

byte multiplier = 6;

Mit ausschließlichem Augenmerk auf Deine Frage:

// Name: FrequencyMultiplier.ino
// Date: 2016-11-29
// Uses: Digitla frequency multiplier example.
// Author: Andrew Que (http://www.DrQue.net)
//
//                                (C) Copyright 2016 by Andrew Que
//                                       http://www.bb7.com/
//=================================================================================================
#include <avr/sleep.h>

// Pin for multiplied output.
// NOTE: Fixed to the output for OCR1A.
enum { OUTPUT_PIN = 9 };

// Pin for input frequency.
// NOTE: Fixed to the input capture pin.
enum { INPUT_PIN = 8 };

// How many divisions to break the rotation into.
// This is basically the multiplication factor for the incoming frequency. 
byte multiplier = 6;

// Timer count when the most recent input pulse arrived.
static unsigned volatile currentTime;

// Timer count when the previous input pulse arrived.
static unsigned volatile lastTime;

// Width of the incoming input pulse (in timer counts).
static unsigned volatile inputPulseWidth;

// Period of a sub-division of the input pulse.
static unsigned volatile divisionPeriod;

// Current subdivision.
static unsigned volatile divisionCount = 0;

// constants won't change. They're used here to set pin numbers:
const int buttonPin = 2;  // the number of the pushbutton pin
const int ledPin = 13;    // the number of the LED pin

// variables will change:
int buttonState = 0;  // variable for reading the pushbutton status


//-------------------------------------------------------------------------------------------------
// USES:
//   Interrupt for timer 1 compare A.  Used to set new compare value to toggle output pin.
//-------------------------------------------------------------------------------------------------
ISR( TIMER1_COMPA_vect )
{
  // Lag factor.  Used to correct phase once each rotation.  Typically zero.
  int lag = 0;

  // Count this division.
  divisionCount += 1;

  // If half way through the cycle calculate a correction factor for phase.
  if ( ( multiplier / 2 ) == divisionCount )
    lag = OCR1A - ( currentTime + ( inputPulseWidth / 2 ) );

  // Rollover at pulse count.
  if ( multiplier == divisionCount )
    divisionCount = 0;

  // Set new next compare value.
  OCR1A += ( divisionPeriod / 2 ) - lag;
}

//-------------------------------------------------------------------------------------------------
// USES:
//   Interrupt for timer 1 capture event.  Used to measure the width of the input pin
// pulse and calculate the division period.
//-------------------------------------------------------------------------------------------------
ISR( TIMER1_CAPT_vect )
{
  // Disable interrupts.
  cli();

  // Grab input capture.
  // This is the time at which the input pulse had a rising edge.
  currentTime = ICR1;

  // Measure the time between this pulse and the previous pulse.
  inputPulseWidth = currentTime - lastTime;

  // Make the last time the current time for next measurement.
  lastTime = currentTime;

  // Calculate period of divisions.
  // Include long and short divisions.
  divisionPeriod = inputPulseWidth / ( multiplier / 2);

  // Enable compare output.
  TCCR1A |= 1 << COM1A0;

  // Enable interrupts.
  sei();
}

//-------------------------------------------------------------------------------------------------
// USES:
//   Setup I/O and timers for operation.
//-------------------------------------------------------------------------------------------------
void setup()
{
  // Set sleep mode for main loop--interrupts will do all the work.
  set_sleep_mode( SLEEP_MODE_IDLE );
  sleep_enable();

  // Setup outputs.
  pinMode( OUTPUT_PIN,  OUTPUT );
 // initialize the LED pin as an output:
  pinMode(ledPin, OUTPUT);
  // initialize the pushbutton pin as an input:
  pinMode(buttonPin, INPUT_PULLUP);
  
  //---------------------------------
  // Setup timer 1 for input capture.
  //---------------------------------

  // Disable timer for setup.
  TCCR1B = 0x00;

  // Reset timer count.
  TCNT1 = 0x00;

  // Clear interrupt flags.
  TIFR1 = 0x00;

  // Enable interrupts.
  TIMSK1 =
      ( 1 << ICIE1 )   // Timer/Counter1, Input Capture Interrupt Enable.
    | ( 1 << OCIE1A ); // Timer/Counter1, Output Compare A Match Interrupt Enable.

  // Timer/Counter1 Control Register A to default normal operation.
  // (There were changed by the Arduino startup code.)
  TCCR1A = 0;
  TCCR1B = 0;

  // Setup Input Capture and clock divide rate.
  TCCR1B =
      ( 1 << ICNC1 ) // Enable Input Capture Noise Canceler.
    | ( 1 << ICES1 ) // Set Input Capture Edge Select to rising edge.
    | ( 1 << CS11 ) | ( 1 << CS10 );  // Clock Select to clk/64.
}

//-------------------------------------------------------------------------------------------------
// USES:
//   Main loop.  Just sleeps and allows interrupts to do the work.
//-------------------------------------------------------------------------------------------------
void loop()
{  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);

  // check if the pushbutton is pressed. If it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    // Schalter "ein" Signal x2:
   multiplier = 2;
    // turn LED on:
   digitalWrite(ledPin, HIGH);
  } else {
    // Schalter "aus" Signal geht durch:
   multiplier = 4;
    // turn LED off:
    //digitalWrite(ledPin, LOW); 
  }
  {
  // Put the device to sleep:
  sleep_mode();
  }
}

my_xy_projekt · October 16, 2022, 5:34pm

Weil Du den neu beschreibst:

und

Wenn Du da das int vorne weg nimmst, könnte es was werden.

Kai-R · October 16, 2022, 5:37pm

Und wenn man if (buttonState == HIGH) in if (buttonState == LOW) ändert. Am buttonPin ist der interne Pullup aktiv.

combie · October 16, 2022, 5:43pm

Nichts gegen Aufzählungen.
Sie machen richtig Sinn, wenn nicht nur ein Element.....

enum class Federvieh:byte {Ente,Huhn,Gans} biest;

ipeco85 · October 16, 2022, 7:10pm

Vielen Dank einmal für die vielen konstruktiven Antworten
Hab' mir schon gedacht, dass enum (MULTIPLIER ) eine Konstante ist. Leider ist mein C -Wortschatz noch sehr klein, sodass ich mich halt von "fertigen" Programmschnipseln weiterhanteln muss.
Heute mag ich nichts mehr probieren, aber ich gebe gerne Rückmeldung, was dann funktioniert hat.
Nochmals DANKE und einen schönen Abend!

combie · October 16, 2022, 7:20pm

Hmm ...
Du befindest dich in einer C++ Welt.

Tipp:
Nutze es.

system · April 14, 2023, 7:20pm

This topic was automatically closed 180 days after the last reply. New replies are no longer allowed.

Topic		Replies	Views
String in einem enum suchen Deutsch	24	1615	November 6, 2022
static enum question Programming	21	3625	May 5, 2021
Para qué sirve un enum? Software	3	19077	May 7, 2021
Fréquencemètre Français	12	7082	May 6, 2021
erweiterte Funktionsparameter Übergabe Deutsch	19	5511	May 6, 2021

Enum Frage für Dummies

Related topics