Erreur de compilation non comprise

Bonjour aujourd'hui je viens vous trouver pour vous demandez votre aide sur une erreur que je ne comprend pas : "C:\Users\AppData\Local\Temp\buildb8c9fb49fbb943d67d4e6eb2c86063ae.tmp/core\core.a(Tone.cpp.o): In function `__vector_7':

C:\Program Files (x86)\Arduino\hardware\arduino\avr\cores\arduino/Tone.cpp:539: multiple definition of `__vector_7'

sketch\Capteur_Seuil.ino.cpp.o:G:\Capteur_Seuil_Temperature\Capteur_Seuil/Interrupt.ino:24: first defined here

collect2.exe: error: ld returned 1 exit status"

Voila donc l'erreur qui nous bloque et que nous ne comprenons pas. Merci de votre aide !

Voila également le programme dans son entièreté nous avons mis les “tone” en commentaire car visiblement c’est cela qui pose le problème:

#include "Thermistor.h"
#include <Wire.h>
#include "rgb_lcd.h"

#define PROCESSING_VISUALIZER 1
#define SERIAL_PLOTTER  2

#define ECHOPIN 7                            
#define TRIGPIN 8                         
#define LEDLED 13
#define BUZZPIN 9
#define BPALERT 5
#define BPACQ 11

//*******CORENTIN*******//
#include <SPI.h>
#include <Ethernet.h>

int carteValue = 1;

byte mac[] = { 0x90, 0xA2, 0xDA, 0x00, 0x7D, 0x1C };
IPAddress ip(10, 129, 7, 135); 
EthernetServer server(80); 
//*******
int distance;// = pulseIn(ECHOPIN, HIGH); 
boolean etatBouton = true;
boolean etatBoutons = true;

//  Variables-> Déclaration des variables
#define pulsePin 0             
#define blinkPin 12             
#define fadePin 10                
//#define fadeRate 6               
#define LedSeuilPouls 4
#define LedSeuilTemp 3
#define Vibration 2
int Temperature = analogRead(A1);
Thermistor temp(0);

rgb_lcd lcd;
int fadeRate =6; 

// Volatile Variables-> Variables utilisé dans la routine Interrupt
volatile int BPM;                   
volatile int Signal;               
volatile int IBI = 600;           
volatile boolean Pulse = false;    
volatile boolean QS = false;       

static int outputType = SERIAL_PLOTTER;


void setup(){ //Début de l'exécution
  pinMode(LedSeuilPouls, OUTPUT);
  pinMode(blinkPin,OUTPUT);        
  pinMode(fadePin,OUTPUT);         
  Serial.begin(115200);                          //Vitesse de transfert utilisé pour le capteur de pouls           
  //Serial2.begin(9600);                           //Vitesse de transfert utilisé par la thermistance
  pinMode(Vibration, OUTPUT);
  pinMode(LedSeuilTemp, OUTPUT);
  interruptSetup();   

    pinMode(ECHOPIN, INPUT);
  pinMode(TRIGPIN, OUTPUT);
  pinMode(LEDLED, OUTPUT);
  pinMode(BUZZPIN, OUTPUT);
  pinMode(BPALERT, INPUT_PULLUP);
  pinMode(BPACQ, INPUT_PULLUP);
  
  lcd.begin(16, 2); 

   Ethernet.begin(mac, ip); 
    server.begin();
}


//  Where the Magic Happens
void loop(){

distance = pulseIn(ECHOPIN, HIGH); 
//boolean etatBouton = true;
//boolean etatBoutons = true;
    digitalWrite(BUZZPIN, LOW);
    etatBouton = digitalRead(BPALERT);
    etatBoutons = digitalRead(BPACQ);
    affichage(distance);
 if (distance >45)
  {
   digitalWrite(LEDLED, HIGH);
  delay(100);
  digitalWrite(LEDLED, LOW);
//  tone(BUZZPIN,500);
  delay(500);
 // tone(BUZZPIN,1000);
  }
 else if (etatBouton == 0)
{
  while(!etatBouton)
  {
    digitalWrite(13, HIGH);
  delay(100);
  digitalWrite(13, LOW);
//  tone(BUZZPIN,500);
  delay(500);
  tone(9,1000);
  etatBoutons = digitalRead(BPACQ);
  if (etatBoutons ==0)
  {
    etatBouton=1;
  }
  }
}




  /******************************/
    serialOutput() ;

  if (QS == true){     // Un rythme cardiaque détecté
                       // BPM et IBI déterminé
                       
        fadeRate = 255;         
                                
        serialOutputWhenBeatHappens();   
        QS = false;                      
        
  }
  int seuil = analogRead(A0);
    Serial.println(seuil);
  delay(500);

  digitalWrite(LedSeuilPouls, LOW);
  
  if (seuil<60 || seuil>100)                  //Définition du seuil pour le pouls
  {
    digitalWrite(LedSeuilPouls, HIGH);
    delay (1000);
    digitalWrite(LedSeuilPouls, LOW);
    delay (1000);
    digitalWrite(Vibration, HIGH);
    delay(1000);
    digitalWrite(Vibration, LOW);
    delay(1000);
    
  } 
  else
  {
    digitalWrite(blinkPin, LOW);
    digitalWrite(Vibration, LOW);
  }
    ledFadeToBeat();                      // Makes the LED Fade Effect Happen
  delay(2000);                             //  take a break
    int temperature=temp.getTemp();
  Serial.print("The sensor temperature is: ");
  Serial.print(temperature);
  Serial.println("*C");
  delay(1000);
  seuil = analogRead(A1);
  Serial.println(seuil);
  delay(500);

  digitalWrite(LedSeuilTemp, LOW);

  if (seuil<22 || seuil>32){
    digitalWrite(LedSeuilTemp, HIGH);                    //Définition du seuil pour la température
    delay(500);
    digitalWrite(LedSeuilTemp, LOW);
    delay(500);
  
  }
  else{
    digitalWrite(LedSeuilTemp, LOW);
  }

  ethernet();
}

void ledFadeToBeat(){
    fadeRate -= 15;                         //  set LED fade value
    fadeRate = constrain(fadeRate,0,255);   //  keep LED fade value from going into negative numbers!
    analogWrite(fadePin,fadeRate);          //  fade LED
  }
  void affichage(int d){
        lcd.clear();
      lcd.home(); // Replace le curseur en haut à gauche
      char message[16] = "";
      sprintf(message, " Dist : %4d cm", d);
      lcd.print(message);
      lcd.setCursor(0,1);
      lcd.setCursor(0,1);
      sprintf(message," Temp:24C");
      lcd.print(message);
      lcd.print(char(223)); 
  }


void ethernet(){
    EthernetClient client = server.available();  

    if (client) { 
        boolean currentLineIsBlank = true;
        while (client.connected()) {
            if (client.available()) {   
                char c = client.read(); 
                if (c == '\n' && currentLineIsBlank) {

                    client.println("HTTP/1.1 200 OK");
                    client.println("Content-Type: text/html");
                    client.println("Connection: close");
                    client.println();
                    // send web page
                    client.println("<!DOCTYPE html>");
                    client.println("<html>");
                    client.println("<head>");
                    client.println("<title>SSMedical</title>");
                    client.println("<META CHARSET='UTF-8'>");
                    client.println("</head>");
                    client.println("<body>");
                    client.println("<h1>Donnees Capteurs</h1>
");
                    client.print("<p>Numéro de la carte: ");
                    client.print(carteValue);
                    client.println("</p><p>Rythme Cardiaque: ");
                    client.print(pulsePin);
                    client.print("bpm</p>");
                    client.print("<p>température: ");
                    client.print(Temperature);
                    client.print("°C</p>");
                    client.print("<p>position: ");
                    client.print(distance);
                    client.print("cm</p>");
                    client.print("<p>Alerte Automatique: ");
                    client.print(etatBouton);
                    client.print("</p>
<p>Erreur:</p>");
                    if(pulsePin < 60){
                    client.print("<p><font color='red'>Rythme Cardiaque bas</font></p>");
                    }else if(pulsePin > 100){
                    client.print("<p><font color='red'>Rythme Cardiaque élevé</font></p>");
                    }
                    if(Temperature < 36){
                    client.print("<p><font color='red'>Température basse</font></p>");
                    }else if(Temperature > 39){
                    client.print("<p><font color='red'>Température élevée</font></p>");
                    }
                    if(distance > 40){
                    client.print("<p><font color='red'>Position Anormale</font><p>");
                    }
                    if(etatBouton==1){
                    client.print("<p><font color='red'>Alerte déclanchée par le patient</font></p>");
                    }
                    
                    client.println("</body>");
                    client.println("</html>");
                    break;
                }
                }
            } 
        } 
        delay(1);      
        client.stop();
    }

Bonjour, Apparemment le problème ne vient pas de tone car cela passe à la compilation (IDE1.8.1). Par contre il nous manque les lib "Thermistor.h" et "rgb_lcd.h"

Tu ne nous as pas donné le bon code... le problème semble se situer dans ton fichier tone.cpp.

Donc en effet, si tu commentes tes appels à tone() tu n'as plus d'erreur

Re, Un peu de sérieux mon gars. Tu écris

int Temperature = analogRead(A1);

en dehors du setup ou du loop pas très propre mais ce n'est pas une erreur de compilation.

L'instanciation

Thermistor temp(0);

est fausse. Tu devrais regarder l'exemple de la bibliothèque car il faut les paramètres, par ex:

Thermistor temp(3.3501, 0.5899, 0.0104, 3000.0, 3003.0);

Les instructions suivantes correspondent à quoi:

interruptSetup;
serialOutput();
serialOutputWhenBeatHappens();

Pour la mesure de temperature:

int temperature=temp.getTemp();

get.temp() n'existe pas dans la bibliothèque voir thermistor.h Regarde si

int temperature=temp.readTemperature();

ne serait pas mieux Comme, je le disais précédemment les tone() passent Au travail

Re,

bigben99: Tu ne nous as pas donné le bon code... le problème semble se situer dans ton fichier tone.cpp.

Donc en effet, si tu commentes tes appels à tone() tu n'as plus d'erreur

C'est bien plus inquiétant que ça

En effet, il semble y avoir plus de problèmes :)

Mais le message d'erreur indique bien que le problème est dans tone.cpp (ligne 539). A priori, je suspecte une déclaration en double d'une fonction (mais sans le fichier tone.cpp, difficile de valider...)

Re,

bigben99: En effet, il semble y avoir plus de problèmes :)

Mais le message d'erreur indique bien que le problème est dans tone.cpp (ligne 539). A priori, je suspecte une déclaration en double d'une fonction (mais sans le fichier tone.cpp, difficile de valider...)

Oui mais j'ai l'impression que les messages d'erreur ne correspondent pas au logiciel publié.

Voici les 2 autres parties du programme car j’ai préféré espacer les différents onglets:

void serialOutput(){   
  switch(outputType){
    case PROCESSING_VISUALIZER:
      sendDataToSerial('S', Signal);    
      break;
    case SERIAL_PLOTTER: 
      Serial.print(BPM);
      Serial.print(",");
      Serial.print(IBI);
      Serial.print(",");
      Serial.println(Signal);
      break;
    default:
      break;
  }

}


void serialOutputWhenBeatHappens(){
  switch(outputType){
    case PROCESSING_VISUALIZER:   
      sendDataToSerial('B',BPM);   
      sendDataToSerial('Q',IBI);  
      break;

    default:
      break;
  }
}

void sendDataToSerial(char symbol, int data ){
    Serial.print(symbol);
    Serial.println(data);
  }
volatile int rate[10];                    // array to hold last ten IBI values
volatile unsigned long sampleCounter = 0;          // used to determine pulse timing
volatile unsigned long lastBeatTime = 0;           // used to find IBI
volatile int P =512;                      // used to find peak in pulse wave, seeded
volatile int T = 512;                     // used to find trough in pulse wave, seeded
volatile int thresh = 530;                // used to find instant moment of heart beat, seeded
volatile int amp = 0;                   // used to hold amplitude of pulse waveform, seeded
volatile boolean firstBeat = true;        // used to seed rate array so we startup with reasonable BPM
volatile boolean secondBeat = false;      // used to seed rate array so we startup with reasonable BPM


void interruptSetup(){  // CHECK OUT THE Timer_Interrupt_Notes TAB FOR MORE ON INTERRUPTS 
  // Initializes Timer2 to throw an interrupt every 2mS.
  TCCR2A = 0x02;     // DISABLE PWM ON DIGITAL PINS 3 AND 11, AND GO INTO CTC MODE
  TCCR2B = 0x06;     // DON'T FORCE COMPARE, 256 PRESCALER
  OCR2A = 0X7C;      // SET THE TOP OF THE COUNT TO 124 FOR 500Hz SAMPLE RATE
  TIMSK2 = 0x02;     // ENABLE INTERRUPT ON MATCH BETWEEN TIMER2 AND OCR2A
  sei();             // MAKE SURE GLOBAL INTERRUPTS ARE ENABLED
}


// THIS IS THE TIMER 2 INTERRUPT SERVICE ROUTINE.
// Timer 2 makes sure that we take a reading every 2 miliseconds
ISR(TIMER2_COMPA_vect){                         // triggered when Timer2 counts to 124
  cli();                                      // disable interrupts while we do this
  Signal = analogRead(pulsePin);              // read the Pulse Sensor
  sampleCounter += 2;                         // keep track of the time in mS with this variable
  int N = sampleCounter - lastBeatTime;       // monitor the time since the last beat to avoid noise

    //  find the peak and trough of the pulse wave
  if(Signal < thresh && N > (IBI/5)*3){       // avoid dichrotic noise by waiting 3/5 of last IBI
    if (Signal < T){                        // T is the trough
      T = Signal;                         // keep track of lowest point in pulse wave
    }
  }

  if(Signal > thresh && Signal > P){          // thresh condition helps avoid noise
    P = Signal;                             // P is the peak
  }                                        // keep track of highest point in pulse wave

  //  NOW IT'S TIME TO LOOK FOR THE HEART BEAT
  // signal surges up in value every time there is a pulse
  if (N > 250){                                   // avoid high frequency noise
    if ( (Signal > thresh) && (Pulse == false) && (N > (IBI/5)*3) ){
      Pulse = true;                               // set the Pulse flag when we think there is a pulse
      digitalWrite(blinkPin,HIGH);                // turn on pin 13 LED
      IBI = sampleCounter - lastBeatTime;         // measure time between beats in mS
      lastBeatTime = sampleCounter;               // keep track of time for next pulse

      if(secondBeat){                        // if this is the second beat, if secondBeat == TRUE
        secondBeat = false;                  // clear secondBeat flag
        for(int i=0; i<=9; i++){             // seed the running total to get a realisitic BPM at startup
          rate[i] = IBI;
        }
      }

      if(firstBeat){                         // if it's the first time we found a beat, if firstBeat == TRUE
        firstBeat = false;                   // clear firstBeat flag
        secondBeat = true;                   // set the second beat flag
        sei();                               // enable interrupts again
        return;                              // IBI value is unreliable so discard it
      }


      // keep a running total of the last 10 IBI values
      word runningTotal = 0;                  // clear the runningTotal variable

      for(int i=0; i<=8; i++){                // shift data in the rate array
        rate[i] = rate[i+1];                  // and drop the oldest IBI value
        runningTotal += rate[i];              // add up the 9 oldest IBI values
      }

      rate[9] = IBI;                          // add the latest IBI to the rate array
      runningTotal += rate[9];                // add the latest IBI to runningTotal
      runningTotal /= 10;                     // average the last 10 IBI values
      BPM = 60000/runningTotal;               // how many beats can fit into a minute? that's BPM!
      QS = true;                              // set Quantified Self flag
      // QS FLAG IS NOT CLEARED INSIDE THIS ISR
    }
  }

  if (Signal < thresh && Pulse == true){   // when the values are going down, the beat is over
    digitalWrite(blinkPin,LOW);            // turn off pin 13 LED
    Pulse = false;                         // reset the Pulse flag so we can do it again
    amp = P - T;                           // get amplitude of the pulse wave
    thresh = amp/2 + T;                    // set thresh at 50% of the amplitude
    P = thresh;                            // reset these for next time
    T = thresh;
  }

  if (N > 2500){                           // if 2.5 seconds go by without a beat
    thresh = 530;                          // set thresh default
    P = 512;                               // set P default
    T = 512;                               // set T default
    lastBeatTime = sampleCounter;          // bring the lastBeatTime up to date
    firstBeat = true;                      // set these to avoid noise
    secondBeat = false;                    // when we get the heartbeat back
  }

  sei();                                   // enable interrupts when youre done!
}// end isr

Voila le code C de la fonction j'ai modifié les "vect", en "vecte" mais cela n'a rien changé au problème, voila donc le lien du code C: https://github.com/arduino/Arduino/blob/master/hardware/arduino/avr/cores/arduino/Tone.cpp

tone.cpp faisant partie du core arduino, il n’y a à priori aucune raison pour aller modifier le fichier…

le code que tu as posté me semble toujours incomplet.

si il y a plusieurs fichiers peut-être serait-il plus simple de poster un .zip contenant le dossier complet, ça évitera de se perdre en conjectures

Voila le code complet avec les librairies utilisées plus celle comprises dans Arduino comme “Wire.h”
j’espère que cela vous aidera.

programme.zip (28.7 KB)

Bonjour,

QuentinPs68: Voila le code complet avec les librairies utilisées plus celle comprises dans Arduino comme "Wire.h" j’espère que cela vous aidera.

Je te rassure on n'a pas de problèmes, celui qui apparemment à besoin d'aide c'est toi ;) Pour que les choses soient claires, ton fichier joint n'est pas un code complet, c'est juste ... Je t'ai posé des questions dans le #5. Sans réponse de ta part tu dévermines seul @+

si si il y a bien tout dans le .zip

Il y a beaucoup à dire sans doute sur le contenu des fichiers et la propreté relative du code, mais en l’occurrence le problème n'est pas là...

dans le dossier Capteur_Seuil il y a les trois .ino correspondant au programme qui a été posté, les deux autres dossiers ce sont les librairies.

je viens d'essayer de compiler les .ino (sans rien modifier) et effectivement même erreur avec tone().

du coup j'essaye d'utiliser tone dans un autre sketch --> OK

du coup je reprends le morceau du programme qui semble poser soucis vu le message d'erreur, soir le contenu de Interupt.ino --> bingo, la même erreur. redefinition, redefinition... tilt ! ben oui, ce fichier utilise des interruptions sur le timer2, et donc definit un vecteur d'interruption :

ISR(TIMER2_COMPA_vect){

fort bien, sauf que Tone.cpp utilise aussi le même timer, et définit donc aussi le même vecteur :

#ifdef USE_TIMER2
ISR(TIMER2_COMPA_vect)
{

résultat : deux choses identiques définies à deux endroits = erreur lors du link. Il n'est donc pas possible en l'état d'utiliser à la fois tone() et le timer 2.

en revanche il semblerait que tone puisse utiliser un autre timer, mais les détails des règles qui vont déterminer comment me dépassent, je laisse le soin à qqn de plus pointu que moi sur la question de se torturer les méninges là dessus...

il y a d'autres librairies alternatives à tone() pour régler le problème du timer2