Error message skatechbook "exit status 1"

I am trying to create an Arduino sketchbook for my MKR FOX 1200 that I have connected to a humidity sensor aswell and I want to use SigFox as my network. I am trying the following code and get error messages “Set binary mode” “Send auto-baud” “Set binary mode” :

#include <SigFox.h>

int sensorPin = A0;
int sensorValue;
int limit = 300;

void setup() {
if (!SigFox.begin()) {
Serial.println(“Unable to init the Atmel ATA8520 Sigfox chipset”);
return;

Serial.begin(9600);
pinMode(13, OUTPUT);
}

SigFox.debug();
// if analog input pin 0 is unconnected, random analog
// noise will cause the call to randomSeed() to generate
// different seed numbers each time the sketch runs.
// randomSeed() will then shuffle the random function.
randomSeed(analogRead(0));

}

void loop(){
sensorValue = analogRead(sensorPin);
Serial.println("Analog Value : ");
Serial.println(sensorValue);

if (sensorValue<limit) {
digitalWrite(13, HIGH);
}
else {
digitalWrite(13, LOW);
}
SigFox.beginPacket();
SigFox.write(sensorValue);
SigFox.endPacket();

delay(1000 * 15);

}

gasse:
I am trying the following code and get error messages "Set binary mode" "Send auto-baud" "Set binary mode" :

Sound like it is having trouble uploading the sketch to your board.

If you return from setup(), you will go almost directly to loop().

Perhaps you intended

while (1) ;

or something else.

void setup() {
  if (!SigFox.begin()) {
    Serial.println("Unable to init the Atmel ATA8520 Sigfox chipset");
    return;
    
  Serial.begin(9600);
  pinMode(13, OUTPUT);
}

You should put Serial.begin() BEFORE your first use of Serial.print(). If the initialization fails the serial output trying to tell you so will probably also fail.

Maybe it will work better after a little clean-up:

#include <SigFox.h>


const int sensorPin = A0;
const int limit = 300;


#if !defined(LED_BUILTIN)
#define LED_BUILTIN 13
#endif


void setup()
{
  Serial.begin(9600);


  if (!SigFox.begin())
  {
    Serial.println("Unable to init the Atmel ATA8520 Sigfox chipset");
    while (1);
  }


  pinMode(LED_BUILTIN, OUTPUT);


  SigFox.debug();
  // if analog input pin 0 is unconnected, random analog
  // noise will cause the call to randomSeed() to generate
  // different seed numbers each time the sketch runs.
  // randomSeed() will then shuffle the random function.
  randomSeed(analogRead(0));
}


void loop()
{
  int sensorValue = analogRead(sensorPin);
  
  Serial.print("Analog Value : ");
  Serial.println(sensorValue);


  if (sensorValue < limit)
  {
    digitalWrite(LED_BUILTIN, HIGH);
  }
  else
  {
    digitalWrite(LED_BUILTIN, LOW);
  }
  
  SigFox.beginPacket();
  SigFox.write(sensorValue);
  SigFox.endPacket();


  delay(1000 * 15);
}